Dialog vom verhalten her wie TOpenDialog schreiben??

[phlux]

Hi!
Ich sitz jetzt schon den ganzen Tag daran und tüftel wie ich einen Dialog schreiben kann. Vom verhalten her soll er wie ein TOpenDialog sich verhalten, also man droppt einfach nur ein Komponentenkästchen auf die Form und kann dann mit DialogName.Execute den Dialog aufrufen.
Wie stell ich das an?

Danke im Vorraus,

phlux

[Captnemo]

Was soll den der Dialog machen? Das gleiche wie der TOpenDialog? Willst du den komplett neu entwickeln oder den vorhandenen nur weiterentwickeln?

[phlux]

Ich will einen komplett neuen Dialog erstellen!

[Jens Schumann]

Hallo,
das Erste ist, dass Du einen neuen Nachfahren von TComponent erzeugst.
Am Besten in einem eigenen Verzeichnis.
Dann erstellst Du eine neue Anwendung. Füge dieser Anwendung ein zweites Formular hinzu. Speichere dieses Formular in dem Verzeichnis der Komponente. Jetzt entferne das Formular aus dem Projekt.
Nehme die Formular-Unit in die uses Anweisung im Implementation-Abschnitt der Komponente auf.
Die Komponenten-Source könnte so aussehen:

Delphi-Quellcode:

unit JsCustomDialog;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs;

type
  TJsCustomDialog = class(TComponent)
  private
    { Private-Deklarationen }
  protected
    { Protected-Deklarationen }
  public
    { Public-Deklarationen }
    function Execute : Boolean;
  published
    { Published-Deklarationen }
  end;

procedure Register;

implementation

uses Js_Dialog_frm;

procedure Register;
begin
  RegisterComponents('Mycomps', [TJsCustomDialog]);
end;

{ TJsCustomDialog }

function TJsCustomDialog.Execute: Boolean;
begin
  With TFormCustomDialog.Create(Self) do
    begin
    Try
      Result:=ShowModal=mrOk;
    Finally
      Release;
      end;
    end;
end;

end.

Der Source für das Formular sieht dann so aus. Bzw kann von Dir angepasst werden:

Delphi-Quellcode:

unit Js_Dialog_frm;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;

type
  TFormCustomDialog = class(TForm)
    Button1: TButton;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  FormCustomDialog: TFormCustomDialog;

implementation

{$R *.DFM}

procedure TFormCustomDialog.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action:=caHide;
end;

procedure TFormCustomDialog.Button1Click(Sender: TObject);
begin
  ModalResult:=mrOk;
end;

end.