ich möchte einen string aus meinem thread an mein hauptformular übergeben und dort weiterarbeiten.

THREAD:

markieren

Delphi-Quellcode:

var temp_string_ptr : ^string;
    text : String;

GetMem(temp_string_ptr, SizeOf(text));
temp_string_ptr^ := text;
PostMessage(MainForm.Handle, TH_MESSAGE, integer(temp_string_ptr), GetCurrentThreadID);

MAINFORM:

markieren

Delphi-Quellcode:

procedure TMainForm.ThreadMessage(var Message: TMessage);
var temp_string_ptr : ^string;
begin
  temp_string_ptr := Pointer(Message.WParam);
end;

was ist daran falsch? bekomme ab und zu eine Zugriffsverletzung... oder liegt der fehler eventuell auch wo anders?

Vielen Dank schonmal

hab jetzt statt einem string ein array ein record genommen, dass den string enthält. und jetzt funktionierts. was hab ich falsch gemacht?

Zitat von mumu:

ich möchte einen string aus meinem thread an mein hauptformular übergeben und dort weiterarbeiten.

zusammenfalten · markieren

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

const
  WM_USER_THREADMESSAGE = WM_USER + $101;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure WMUserThreadMessage(var Message: TMessage); message WM_USER_THREADMESSAGE;
  public
    { Public-Deklarationen }
  end;

  TMyThread = class(TThread)
  private
    FMainFormHandle: HWND;
  protected
    procedure Execute; override;
  public
    property MainFormHandle: HWND read FMainFormHandle write FMainFormHandle;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{--------------------------------------------------------------------------------------------------}

{ TMyThread }

procedure TMyThread.Execute;
var
  S: String;
begin
  S := 'Hello World!';
  SendMessage(FMainFormHandle, WM_USER_THREADMESSAGE, Length(S), LPARAM(PChar(S)));
end;

{--------------------------------------------------------------------------------------------------}

{ TForm1 }

procedure TForm1.WMUserThreadMessage(var Message: TMessage);
var
  S: String;
begin
  SetLength(S, Message.WParam);
  StrLCopy(PChar(S), PChar(Message.LParam), Message.WParam);
  ShowMessage(S);
end;

{--------------------------------------------------------------------------------------------------}

procedure TForm1.Button1Click(Sender: TObject);
begin
  with TMyThread.Create(True) do
  begin
    FreeOnTerminate := True;
    MainFormHandle := Self.Handle;
    Resume;
  end;
end;

{--------------------------------------------------------------------------------------------------}

end.

Das:

markieren

Delphi-Quellcode:

procedure TForm1.WMUserThreadMessage(var Message: TMessage);
var
  S: String;
begin
  SetLength(S, Message.WParam);
  StrLCopy(PChar(S), PChar(Message.LParam), Message.WParam);
  ShowMessage(S);
end;

geht auch mit einem einfachen Typecast:
  ShowMessage(PChar(Message.WParam));

ok, erstmal vielen dank für die lösung. aber irgendwie bekomm ich dabei auch ne zugriffsverletzung?! jedoch nur wenn ich postmessage verwende. wenn ich dagegeben sendmessage verwende funktionierts.

woran liegt das und wie kann ich das verhindern?

naja liegt wahrscheinlich daran, dass sendmessage wartet bis die message bearbeitet wurde. und der string zu diesem zeitpunkt noch nicht freigegeben wurde. das möchte ich jedoch auf jeden fall vermeiden. gibt es eine möglichkeit postmessage zu verwenden?

Warum umbedingt PostMessage? das kann zu Problemen fürheren, weil dein Thread weitermacht, da PostMessage sofort zurückkehrt, wärend bei SendMessage gewartet wird bis SendMessage zurückkehrt.

naja, da ich mir durch postmessage einen schnelleren ablauf erhoffe. wenn nicht drauf gewartet werden muss, bis die message verarbeitet wurde

Hat aber zur Folge, dass die Anzeige des Status nuicht mehr unbedingt synchron zum tatsächlichen Ablauf ist. Und das Verarbieten sollte auch nicht all zu lange dauern.

ja gut, vielleicht ist es auch übertrieben. wird wohl nicht viel bringen. ich denk mal meine lösung oben hat auch nur nicht funktioniert, weil ich da postmessage verwendet habe.