In ShellListView Navigieren (Ordner öffnen)

[jfheins]

Ich sehe gerade, dass dort ein Bug ist. hier der richtige Quellcode:

Delphi-Quellcode:

unit ShellListView1;

interface

uses
  SysUtils, Classes, Controls, ComCtrls, ShellCtrls, ShellAPI;

type
  TShellListView1 = class(TShellListView)
  private
    FAutoExecuteFiles: Boolean;
  protected
    procedure DblClick; override;
  public
    constructor Create(AOwner: TComponent); override;
  published
    property AutoExecuteFiles: Boolean read FAutoExecuteFiles write FAutoExecuteFiles;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Eigene Komponenten', [TShellListView1]);
end;

{ TShellListView1 }

constructor TShellListView1.Create(AOwner: TComponent);
begin
  inherited;

  FAutoExecuteFiles := True;
end;

procedure TShellListView1.DblClick;
var
  OldAutoNavigate: Boolean;
begin
  OldAutoNavigate := AutoNavigate;

  if Selected <> nil then
    AutoNavigate := AutoNavigate and (Folders[Selected.Index].IsFolder or FAutoExecuteFiles);

  inherited;

  AutoNavigate := OldAutoNavigate;
end;

end.

[Newcomer91]

Hey, ist dass noch aktuell? Habe das selbe problem dass die Prozesse alle Hide sind (0) wenn ich sie Doppelklicke.

[jfheins]

Die Lösung habe ich doch damals gepostet?

ShellListView ableiten, verändern, benutzen.

Mit der Orginal-Kompo ist es leider so, wie Borland es programmiert hat. Ich konnte damals keine Shell* Komponente benutzen ohne sie abzuleiten und das Verhalten anzupassen.

[Newcomer91]

Gut.

[Newcomer91]

Gut, also deine Lösung funktioniert, und falls jemand das hier lesen sollte und ne andere Lösung sucht:

Man hat noch die Möglichkeit im Objektinspektor Das Ereignis OnDblClick zu benutzen.
So hab ichs jetzt gelöst.