Api's von VB auf Delphi

[Christian Seehase]

Moin magicshadow,

bei mir sehen die Deklarationen so aus:

Delphi-Quellcode:

// aus RAS.H
const
  RAS_MaxDeviceType = 16;
  RAS_MaxEntryName  = 256;
  RAS_MaxDeviceName = 128; 

  // aus RASERROR.H
  RASBASE                = 600;
  ERROR_BUFFER_TOO_SMALL = RASBASE+3;

type
  {$IFNDEF UNICODE}
    TCHAR = type Char;
  {$ELSE}
    TCHAR = type WideChar;
  {$ENDIF}

  PRAS_STATS = ^RAS_STATS;
  RAS_STATS = packed record
   dwSize                : DWORD;
   dwBytesXmited         : DWORD;
   dwBytesRcved          : DWORD;
   dwFramesXmited        : DWORD;
   dwFramesRcved         : DWORD;
   dwCrcErr              : DWORD;
   dwTimeoutErr          : DWORD;
   dwAlignmentErr        : DWORD;
   dwHardwareOverrunErr  : DWORD;
   dwFramingErr          : DWORD;
   dwBufferOverrunErr    : DWORD;
   dwCompressionRatioIn  : DWORD;
   dwCompressionRatioOut : DWORD;
   dwBps                 : DWORD;
   dwConnectDuration     : DWORD;
  end;

  PRASCONN = ^RASCONN;
  RASCONN = record
    dwSize       : DWORD;
    hrasconn     : DWORD;
    szEntryName  : array [1..RAS_MaxEntryName+1]  of TCHAR;
    szDeviceType : array [1..RAS_MaxDeviceType+1] of TCHAR;
    szDeviceName : array [1..RAS_MaxDeviceName+1] of TCHAR;
    szPhonebook  : array [1..MAX_PATH] of TCHAR;
    dwSubEntry   : DWORD;
    guidEntry    : TGUID;
 end;

  function RasGetConnectionStatistics(const hRasConn : DWORD;const lpStatistics : PRAS_STATS) : DWORD; stdcall; external 'RasApi32.dll';

  function RasEnumConnectionsA(const lprasconn : PRASCONN;const lpcb : PDWORD;const lpcconnections : PDWORD) : DWORD; stdcall; external 'RasApi32.dll';
  function RasEnumConnectionsW(const lprasconn : PRASCONN;const lpcb : PDWORD;const lpcconnections : PDWORD) : DWORD; stdcall; external 'RasApi32.dll';

  {$IFNDEF UNICODE}
    function RasEnumConnections(const lprasconn : PRASCONN;const lpcb : PDWORD;const lpcconnections : PDWORD) : DWORD; stdcall; external 'RasApi32.dll' name 'RasEnumConnectionsA';
  {$ELSE}
    function RasEnumConnections(const lprasconn : PRASCONN;const lpcb : PDWORD;const lpcconnections : PDWORD) : DWORD; stdcall; external 'RasApi32.dll' name 'RasEnumConnectionsW';
  {$ENDIF}

Und, zum Testen hab' ich das dann so verwendet:

Delphi-Quellcode:

var
  prcWork       : PRASCONN;
  dwResult      : DWORD;
  dwSize        : DWORD;
  dwConnections : DWORD;

begin
  dwSize  := SizeOf(RASCONN);
  prcWork := AllocMem(SizeOf(RASCONN));
  try
    dwConnections  := 0;
    prcWork.dwSize := SizeOf(RASCONN);
    dwResult       := RasEnumConnections(prcWork,@dwSize,@dwConnections);
    if (dwResult = ERROR_BUFFER_TOO_SMALL) or (dwResult = ERROR_NOT_ENOUGH_MEMORY) then
    begin
      MessageBox(0,'Buffer reicht nicht','RasEnumConnections',MB_ICONERROR);
      exit;
    end;
    if dwResult <> ERROR_SUCCESS then
    begin
      MessageBox(0,PChar('RAS Fehler: '+IntToStr(dwResult)+' aufgetreten'),'RasEnumConnections',MB_ICONERROR);
      exit;
    end;
    // Ab hier kann weiterverarbeitet werden
  finally
    FreeMem(prcWork,SizeOf(RASCONN));
  end;

In Ermangelung einer RAS Verbindung bekomme ich zwar leider auch keine Verbindungen aufgezählt (was den Test von RasGetConnectionStatistics doch leicht erschwert ), aber der Return Code ist 0, hat also geklappt.

Die Hauptunterschiede:
RAS_MaxDeviceName hat die Länge 128, nicht 32.
Ausserdem stimmt die Struktur für RASCONN nicht, diese muss unter W2K länger sein.