wm_dropfiles an Anwendung senden (SendMessage)

[SirThornberry]

Ich versuche Krampfhaft ein WM_DropFiles an eine andere Anwendung zu schicken. Die message kommt bei dem anderen Programm auch an, allerdings ist dann die Fileliste nil welche ich gesendet hab.

Als Referenzquelltext hab ich http://groups.google.de/groups?hl=de...gbl%26rnum%3D2

irgendwie schein ich den aber falsch übersetzt zu haben (ich denk der knackpunkt liegt in dem globalLock)

Mein bisheriger Quelltext

Delphi-Quellcode:

var LInfo: PDragInfoA;
    LStr: String;
    LRes: Integer;
    LAlloc: Pointer;
    LHGlobal: Cardinal;
begin
  LStr := 'F:\';
  LHGlobal := GlobalAlloc(GMEM_MOVEABLE, SizeOf(TDragInfoA) + length(LStr) + 2);
  LAlloc := GlobalLock(LHGlobal);
  //
  LInfo := LAlloc;
  LInfo.uSize := SizeOf(TDragInfoA);
  LInfo.pt := Point(0, 0);
  LInfo.fNC := False;
  LInfo.grfKeyState := 0;
  LInfo.lpFileList := nil;
  LInfo.lpFileList := Pointer(Cardinal(LAlloc) + SizeOf(TDragInfoA));
  Move(LStr[1], LInfo.lpFileList^, length(LStr));
  LInfo.lpFileList[length(LStr)] := #0;
  LInfo.lpFileList[length(LStr) + 1] := #0;
  //a.lpFileList := Pointer(SizeOf(TDragInfoA));
  GlobalUnlock(LHGlobal);
  SendMessage(FindWindow(nil, PChar(Edit2.Text)), WM_DROPFILES, LHGlobal, 0);
  //GlobalFree(LHGlobal);

GlobalFree ist bewusst auskommentiert um auszuschließen das der Fehler am zu frühen Freigeben des speichers etc. scheitert.

[Christian Seehase]

Moin Sir Thornberry,

schau Dir mal die Funktionen VirtualAllocEx, VirtualLock an.

[SirThornberry]

VirtualLock hab ich mir schon angeschaut und auch im Quelltext verwendet. Bei GlobalAlloc hab ich auch als ersten Parameter "GMEM_MOVEABLE" verwendet womit der Speicher auch für andere Anwendungen verfügbar sein sollte. Und bei der übergabe mit Sendmessage hab ich auch bereits versucht den Pointer von GlobalAlloc zu übergeben als auch den Pointer den mit VirtualLock zurück gibt, aber beide varianten wollen nicht so recht funktionieren.

[SirThornberry]

Habs jetzt hinnbekommen:

Delphi-Quellcode:

function DropFilesOnWnd(AWnd: HWND; AFiles: String): Boolean; overload;
var LInfo: PDragInfoA;
    LRes: Boolean;
    LHGlobal: Cardinal;
begin
  LRes := False;
  if copy(AFiles, length(AFiles), 1) <> #0 then
    AFiles := AFiles + #0;
  LHGlobal := GlobalAlloc(GMEM_SHARE or GMEM_MOVEABLE or GMEM_ZEROINIT, SizeOf(TDragInfoA) + length(AFiles) + 1);
  if LHGlobal <> 0 then
  begin
    LInfo := GlobalLock(LHGlobal);
    if LInfo <> nil then
    begin
      LInfo.uSize := SizeOf(TDragInfoA);
      Move(AFiles[1], PChar(Cardinal(LInfo) + LInfo.uSize)^, length(AFiles));
      GlobalUnlock(LHGlobal);
      LRes := PostMessage(AWnd, WM_DROPFILES, LHGlobal, 0);
    end;
    if not(LRes) then
      GlobalFree(LHGlobal);
  end;
  result := LRes;
end;

function DropFilesOnWnd(AWnd: HWnd; AFiles: TStringlist): Boolean; overload;
begin
  result := DropFilesOnWnd(AWnd, StringReplace(AFiles.Text, #13#10, #0, [rfReplaceAll]));
end;

Allerdings funktioniert das ganze nur mit PostMessage. Sobald ich PostMessage durch SendMessage ersetze kommt bei der Ziel-Anwendung -1 als Dateianzahl an.