Datei wird beim erstellen gelöscht

[RavenIV]

ich benutze TFileStream, um einen text in eine datei zu schreiben.
jedesmal, wenn ich TFielStream.create aufrufe, wird die datei aber gelöscht.

mein System: delphi7 mit WinXP.

hier der code:

Delphi-Quellcode:

procedure TFoRemotetest.IBSQLMonitorSQL (EventText: string; EventTime: TDateTime);
var
  FileName: string;
  EventStream: TStringStream;
  FileObj: TFileStream;
begin
  FileName := 'D:\db_i.log';
  EventStream := TStringStream.Create(EventText);
  FileObj := TFileStream.Create (FileName, fmCreate);
  FileObj.CopyFrom(EventStream,0);
   FileObj.Free;
end;

irgendeine lösung?

gruessle

[Sprint]

Zitat von RavenIV:

jedesmal, wenn ich TFielStream.create aufrufe, wird die datei aber gelöscht.

Dann solltest du mal die Delphi Hilfe aufschlagen und die Bedeutung von fmCreate lesen.

[RavenIV]

die OH sagt für fmCreate:

Zitat:

Es wird eine Datei mit dem angegebenen Namen angelegt. Ist eine Datei mit diesem Namen bereits vorhanden, wird die Datei zum Schreiben geöffnet.

also sollte die datei doch nicht jedesmal neu erstellt werden.

[Sprint]

Zitat von RavenIV:

also sollte die datei doch nicht jedesmal neu erstellt werden.

Aber so wie es aussieht, bist du zu einem anderem Ergebnis gekommen.

Delphi-Quellcode:

procedure TFoRemotetest.IBSQLMonitorSQL (EventText: string; EventTime: TDateTime);
var
  FileName: String;
  Handle: Integer;
begin

  FileName := 'D:\db_i.log';

  if FileExists(FileName) then
    Handle := FileOpen(FileName, fmOpenReadWrite)
  else
    Handle := FileCreate(FileName);

  if Handle <> -1 then
  begin
    FileSeek(Handle, 0, 2);
    FileWrite(Handle, EventText[1], Length(EventText));
    FileClose(Handle);
  end;

end;

[RavenIV]

servus Sprint

deine Lösung ist auch schön.
aber ich liebe streams und ich liebe objekte und ich liebe exceptions.

jedem das seine, mir das meiste...


P.S. die lösung meines problems:

Delphi-Quellcode:

procedure TFoRemotetest.IBSQLMonitorSQL (EventText: string; EventTime: TDateTime);
var
  FileName: string;
  EventStream: TStringStream;
  FileObj: TFileStream;
begin
  FileName := 'D:\db_i.log';
  EventStream := TStringStream.Create (EventText);
  try
    FileObj := TFileStream.Create (FileName, fmOpenReadWrite or fmShareDenyNone);
  except
    FileObj := TFileStream.Create (FileName, fmCreate or fmShareDenyNone);
  end;
  FileObj.Seek (FileObj.Size, soFromBeginning);
  FileObj.CopyFrom (EventStream, 0);
  FileObj.Free;
end;

gruessle

[Sprint]

Sollte die Datei nicht existieren, dann wird FileObj zweimal erstellt, aber nur einmal freigegeben.

[Binärbaum]

Zitat von Sprint:

Sollte die Datei nicht existieren, dann wird FileObj zweimal erstellt, aber nur einmal freigegeben.

Mindestens genauso schlimm ist, dass EventStream nur mit Create erzeugt wird und danach nicht mehr freigegeben wird.

MfG
Binärbaum

[RavenIV]

hier nun eine mischung aus allen vorschlägen:

Delphi-Quellcode:

procedure TFoRemotetest.IBSQLMonitorSQL (EventText: string; EventTime: TDateTime);
var
  FileName: string;
  EventStream: TStringStream;
  FileObj: TFileStream;
begin
  FileName := 'D:\db_i.log';
  EventStream := TStringStream.Create (DateTimeToStr (EventTime) + EventText + ''#13#10'');
  if FileExists (FileName) then
    FileObj := TFileStream.Create (FileName, fmOpenReadWrite or fmShareDenyNone)
  else
    FileObj := TFileStream.Create (FileName, fmCreate or fmShareDenyNone);
  try
    FileObj.Seek (FileObj.Size, soFromBeginning);
    FileObj.CopyFrom (EventStream, 0);
  finally
    FileObj.Free;
  end;
  EventStream.Free;
end;

hier dürfte alles OK sein...

[Binärbaum]

Zitat von RavenIV:

hier dürfte alles OK sein...

Ja, ist schon viiiiiel besser als der Code vom Anfang