If-Anweisung mit "in"

[Helmi]

Hallo,

ich habe folgende If-Anweisung:

Code:

If DateiEndung in ['jpg', 'jpeg', 'bmp', 'ico', 'emf', 'wmf'] then
{ ... }

Die Variable "DateiEndung" ist vom Typ String;

Wenn ich das compilieren will, bekomm ich folgende Meldung:
[Fehler] Viewer.pas(233): Inkompatible Typen: 'Integer' und 'String'


Ich will prüfen ob der Inhalt der Variablen "DateiEndung" sich in der Liste befindet.

Was hab ich falsch gemacht, bzw. wie kann man das machen ohne

Code:

If (DateiEndung = 'jpg') or (DateiEndung = 'jpeg') or .....

[alcaeus]

Hallo Helmi,

zeig doch bitte mal ein bisschen mehr Code. Die Zeile die du da hast passt, evtl. funktioniert es sonst irgendwo nicht.

Greetz
alcaeus

[Helmi]

Also ich weiss zwar nicht was es bringen soll aber bitte hier hast du die zeilen die drüber liegen:

Code:

      //Datei aus der Ordnerliste auslesen
      Datei := Ordnerliste.Strings[neuesBild];

      DateiEndung := StringReplace(ExtractFileExt(Datei), '.', '', [rfReplaceAll]);

      showmessage(Dateiendung);

      If DateiEndung in ['jpg', 'jpeg', 'bmp', 'ico', 'emf', 'wmf'] then
        begin
          //ausgewähltes Image laden
          Image.Picture.LoadFromFile(Ordner + Datei);
        end;

Trotzdem hängt der an der If-Anweisung mit dem Integer und String - Fehler

genauer gesagt am ersten Komma nach 'jpg'.

[sakura]

Zitat von alcaeus:

Die Zeile die du da hast passt,

Nein, in [set...] geht nicht mit Strings.

......

[Helmi]

oki - Danke Sakura

muss ich es doch mit Or machen!!

[Binärbaum]

Ich hätte da eine Idee, wie man es ohne or hinkriegt. Dafür braucht man aber eine zusätzliche Funktion, die folgendermaßen aussieht:

Delphi-Quellcode:

function StrIdx(aStr: string; strArr: array of string): Integer;
var i: Integer;
begin
 Result:= -1;
 for i:= 0 to High(strArr) do
  if (aStr=strArr[i]) then 
  begin
   Result:= i; 
   Break; 
  end;
end;

Die Funktion liefert den Index von aStr, wenn es im Array strArr enthalten ist, sonst -1. Damit könnte man statt
If (DateiEndung = 'jpg') or (DateiEndung = 'jpeg') or ..... Folgendes schreiben:

Delphi-Quellcode:

 
If (StrIdx(DateiEndung, Endungen)>=0) then begin
  //mache irgendwas
  ...
end;

Die Variable Endungen muss in diesem Fall ein Array of string sein, indem die Dateiendungen, nach denen gesucht werden soll, enthalten sind.

[sakura]

Wenn wir schon mal dabei sind, dann trage ich auch gerne meine Lösung vor, wie ich die gerne nutze. In diesem Fall erweitert, da z.B. JPEGs verschiedene Endungen haben können.

Delphi-Quellcode:

type
  // bekannte Dateitypen
  TFileType = (ftUnknown, ftJpg, ftGif, ftBmp);

type
  // Assoziation zw. Dateiendung und Dateitype
  TFileExt = record
    Ext: String[5];
    FileType: TFileType;
  end;

const
  // Liste bekannter Assoziationen
  FILE_TYPES: array[0..4] of TFileExt = (
    (Ext: 'jpg';   FileType: ftJpg),
    (Ext: 'jpe';   FileType: ftJpg),
    (Ext: 'jpeg';  FileType: ftJpg),
    (Ext: 'gif';   FileType: ftGif),
    (Ext: 'bmp';   FileType: ftBmp)
  );

function GetFileType(FileName: String): TFileType;
var
  lExt: String;
  I: Integer;
  Res: TFileType;
begin
  Res := ftUnknown;
  lExt := AnsiLowerCase(ExtractFileExt(FileName));
  for I := Low(FILE_TYPES) to High(FILE_TYPES) do
    if FILE_TYPES[I].Ext = lExt then
    begin
      Res := FILE_TYPES[I].FileType;
      Break;
    end;
  Result := Res;
end;

......

[Binärbaum]

Die Vorgehensweise von sakura ist auch nicht schlecht, vielleicht sogar besser als mein Vorschlag.
Bei meiner Lösung kann man allerding auch die Dateitypen herausbekommen, da man an Hand des Ergebnisses der Funktion StrIdx ja die Position des Suchstrings im Array erhält und somit auch die Dateiendung.
Welche Variante man nimmt ist also Geschmackssache.

MfG
Binärbaum