Windows 2003 mit Konsolenanwendung neustarten

[Luckie]

Warum debuggst du das nicht einfach mal und guckst dir die Rückgabewerte der API Funktionen an? natürlcih it der Fehler schwer zu finden, wenn man von vorneherein keinerlei Überprüfung der Rückgabewerte vornimmt.

So sieht es zum beispiel besser aus:

Delphi-Quellcode:

function EnablePrivilege(const Privilege: string; fEnable: Boolean; out
  PreviousState: Boolean): DWORD;
var
  Token        : THandle;
  NewState     : TTokenPrivileges;
  Luid         : TLargeInteger;
  PrevState    : TTokenPrivileges;
  Return       : DWORD;
begin
  PreviousState := True;
  if (GetVersion() > $80000000) then
    // Win9x
    Result := ERROR_SUCCESS
  else
  begin
    // WinNT
    if not OpenProcessToken(GetCurrentProcess(), MAXIMUM_ALLOWED, Token) then
      Result := GetLastError()
    else
    try
      if not LookupPrivilegeValue(nil, PChar(Privilege), Luid) then
        Result := GetLastError()
      else
      begin
        NewState.PrivilegeCount := 1;
        NewState.Privileges[0].Luid := Luid;
        if fEnable then
          NewState.Privileges[0].Attributes := SE_PRIVILEGE_ENABLED
        else
          NewState.Privileges[0].Attributes := 0;
        if not AdjustTokenPrivileges(Token, False, NewState,
          SizeOf(TTokenPrivileges), PrevState, Return) then
          Result := GetLastError()
        else
        begin
          Result := ERROR_SUCCESS;
          PreviousState :=
            (PrevState.Privileges[0].Attributes and SE_PRIVILEGE_ENABLED <> 0);
        end;
      end;
    finally
      CloseHandle(Token);
    end;
  end;
end;

Da kann man wunderschön den Rückgabewert abfragen und gucken, was eventuell schiefgelaufen ist.