Verkette Liste mit verschiedenen records/objekten

[Pseudemys Nelsoni]

hi,

ich habe folgende klasse mit den methoden Ban/Unban/IsBanned... geschrieben:

Delphi-Quellcode:

unit banlist;

interface

uses
  SysUtils, Classes;

type
  PChannelBan = ^TChannelBan;
  TChannelBan = record
    Nickname: string;
    Next: PChannelBan;
  end;
  TChannelBanList = class(TObject)
  private
    FChannelBanNode: PChannelBan;
  public
    function IsBanned(const ANickname: string): Boolean;
    procedure GetBanList(var ChannelBanList: TStringList);
    procedure Ban(const ANickname: string);
    procedure Unban(const ANickname: string);
  end;

implementation

function TChannelBanList.IsBanned(const ANickname: string): Boolean;
var
  ChannelBan: PChannelBan;
begin
  Result := False;
  ChannelBan := FChannelBanNode;
  while (ChannelBan <> nil) and (not Result) do
  begin
    if Lowercase(ANickname) = Lowercase(ChannelBan^.Nickname) then
      Result := True;
    ChannelBan := ChannelBan^.Next;
  end;
end;

procedure TChannelBanList.GetBanList(var ChannelBanList: TStringList);
var
  ChannelBan: PChannelBan;
begin
  ChannelBan := FChannelBanNode;
  while ChannelBan <> nil do
  begin
    ChannelBanList.Add(ChannelBan^.Nickname);
    ChannelBan := ChannelBan^.Next;
  end;
end;

procedure TChannelBanList.Ban(const ANickname: string);
var                                                  
  ChannelBan, TempPtr: PChannelBan;
begin
  if not IsBanned(ANickname) then
  begin
    New(ChannelBan);
    ChannelBan^.Next := nil;
    ChannelBan^.Nickname := ANickname;
    if FChannelBanNode = nil then
      FChannelBanNode := ChannelBan
    else
    begin
      TempPtr := FChannelBanNode;
      while TempPtr^.Next <> nil do
        TempPtr := TempPtr^.Next;
      TempPtr^.Next := ChannelBan;
    end;
  end;
end;

procedure TChannelBanList.Unban(const ANickname: string);
var
  TempPtr, TempPtr2: PChannelBan;
begin
  if IsBanned(ANickname) then
  begin
    TempPtr := FChannelBanNode;
    if FChannelBanNode^.Nickname = ANickname then
    begin
      FChannelBanNode := TempPtr^.Next;
      Dispose(TempPtr);
    end else
    begin
      while not (TempPtr^.Next^.Nickname = ANickname) do
        TempPtr := TempPtr^.Next;
      TempPtr2 := TempPtr^.Next;
      TempPtr^.Next := TempPtr^.Next^.Next;
      Dispose(TempPtr2);
    end;
  end;
end;

so, nun brauch ich aber eine weitere Liste wo der record (hier "TChannelBan") ein feld mehr hat, also z.b "IP"(string)....nur wie mache ich das? muss ich für jede liste meine 4 methoden immer wieder neu schreiben obwohl sie haargenau gleich sind (bis auf die felder) ?

[Muetze1]

Moin!

Kurze Frage: warum machst du es dir so kompliziert anstatt einfach und schnell eine TList Instanz zu nutzen zur Verwaltung?

MfG
Muetze1

[Pseudemys Nelsoni]

hi mütze,

weil soweit chewie das schon immer erwähnt hat TList keine wirklich verkettete Liste ist.
Aber ich muss es genau mit so einer machen, ich möchte nur nicht jedes mal die selben methoden neu schreiben müssen nur weil der rekord anders aussieht

[GuenterS]

Wieso machst du dann nicht eine Klasse anstatt einem Record?

Da kannst Du die entsprechenden Methoden ja vererben.

[Muetze1]

Moin!

Gut, im Normalfall würde ich keine verkettete Liste mehr nutzen, aber es scheint bei dir als Aufgabenstellung wohl vorgegeben zu sein. Und um nicht für jeden Type einen neue Implementation zu bauen, empfehle ich dir eine Klasse für die verkettete Liste zu schreiben oder einfach eine verkettete Liste die nicht direkt mit den Daten arbeitet sondern einen untypirisierten Zeiger auf die Daten hält. Damit ist die verkettete Liste Datentyp unabhängig.

MfG
Muetze1

[bttb930]

warum arbeiten eigentlich noch soviele mit zeigern wie unter TP5? mach einfach klassen:

Delphi-Quellcode:

type
  TChannelBan = class
  private
    FNickname: string;
    FNext: PChannelBan;
  public
    property Nickname: string read FNickName write FNickName;
    property Next: PChannelBan read FNext write FNext;
  end;

  TChannelBan2 = class(TChannelBan)
  private
    FIP: string;
  public
    IP: string read FIP write FIP;
  end;

  TChannelBanList = class(TObject)
  private
    FChannelBanNode: TChannelBan;
  public
    function IsBanned(const ANickname: string): Boolean;
    procedure GetBanList(var ChannelBanList: TStringList);
    procedure Ban(const ANickname: string);
    procedure Unban(const ANickname: string);
  end;

Da TChannelBan2 von TChannelBan abgeleitet ist, kann man ein TChannelBan2 an FChannelBanNode zuweisen.