Scrollbox - Balken vergössern sich nicht

[Karl20001]

Hi, folgendes.
Ich habe eine Form mit einer Scrollbox und möchte in dieser weitere Fenster darstellen.

So z.b. packe ich eine Form in meine Scrollbox.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
begin
  Form2 := TForm2.CreateParented(Scrollbox1.Handle);
  Form2.parent := Scrollbox1;
  Form2.Show;
  SendMessage(Form2.Handle, WM_NCACTIVATE, Ord(True), 0);
end;

Problem ist nur, wenn ich diese Form innerhalb der Scrollbox bewegen, aus dem sichtbaren Bereich heraus,
vergössern sich die Scrollbalken nicht, bzw. erscheinen nicht.
Wenn ich die Form gleich beim Erzeugen an irgendeine Pos in der Scrollbox setze, habe ich Scrollbalken,
aber diese sind nur fähig sich zu verkleinern!

[Jens Schumann]

Hallo,
ich habe mak in den VCL Source geforscht und folgende adhoc Lösung gefunden.

Delphi-Quellcode:

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm2 = class(TForm)
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private-Deklarationen }
    procedure WMMOVE(var MSG : TWMMove); message WM_MOVE;
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action:=caFree;
end;

procedure TForm2.WMMOVE(var MSG: TWMMove);
begin
  inherited;
  If Parent is TScrollbox then
    begin
    TScrollBox(Parent).DisableAutoRange;
    TScrollBox(Parent).EnableAutoRange;
    end;
end;

end.

[Karl20001]

Hi, funzt - vielen Dank.