statisch eingebundene C-DLL soll dynamisch geladen werden

[Garfield]

Hallo,

in meinem Programm benutze ich die in C geschriebene DLL MediaInfo.DLL (siehe auch hier). In der zur DLL gehörenden unit MediaInfoDLL.pas wird die DLL wie folgt eingebunden:

Delphi-Quellcode:

unit MediaInfoDll;

interface

uses

{$IFDEF WIN32}
  Windows;
{$ELSE}
  Wintypes, WinProcs;
{$ENDIF}

function MediaInfo_Open(File__: PChar): Cardinal cdecl  {$IFDEF WIN32} stdcall {$ENDIF};
procedure MediaInfo_Close(Handle: Cardinal) cdecl  {$IFDEF WIN32} stdcall {$ENDIF};
function MediaInfo_Get(Handle: Cardinal;
                       StreamKind: Integer;
                       StreamNumber: Integer;
                       Parameter: PChar;
                       KindOfInfo: Integer;
                       KindOfSearch: Integer): PChar cdecl  {$IFDEF WIN32} stdcall {$ENDIF};

implementation

function MediaInfo_Open; external 'MediaInfo.Dll';
procedure MediaInfo_Close; external 'MediaInfo.Dll';
function MediaInfo_Get; external 'MediaInfo.Dll';

end.

Die Unit ist auf die für mich wichtigen Teile Öffnen, Infos abholen und Schließen reduziert. Da die Benutzung der DLL nicht zwingend ist, würde ich sie gern dynamisch laden. Leider verstehe ich nicht, was ich ändern muss. Oder kann ich da nichts ändern, sondern muss aus dieser Unit eine DLL machen, welche dann dynamisch geladen wird?

Nachtrag:

Der Aufruf der Funktionen der DLL erfolgt einerhalb TRY EXCEPT END. Mir würde also reichen, wenn mein Programm auch startet, wenn die MediaInfo.DLL nicht vorhanden ist. Im Moment bricht der Startvorgang mit einer Fehlermeldung ab.

[Luckie]

Du musst eben die Funktionen dynamisch laden. WEie das geht kannst du im DLL Tutorial von Assarbad nach lesen: http://www.luckie-online.de/Delphi/Importe/Assarbad/
Es wird daraufhinauslaufen, dass du die Unit komplett neu schreiben musst.

[Garfield]

Danke Luckie,

ich habe schon einige Anleitungen gelesen, unter anderem auch die von Dir hier verlinkte. Da ich damit nicht ans Ziel gekommen bin, habe ich sie beiseite gelegt.

Nun habe ich sie mir noch einmal vorgenommen und nun ist der Groschen endlich gefallen.

Meine MediaInfoDLL.pas sieht jetzt so aus:

Delphi-Quellcode:

unit MediaInfoDll;

interface

uses

{$IFDEF WIN32}
  Windows, Messages;
{$ELSE}
  Wintypes, Messages, WinProcs;
{$ENDIF}

Const
  szNameDLL             = 'MediaInfo.DLL';
  szNameMediaInfo_Open  = 'MediaInfo_Open';
  szNameMediaInfo_Get   = 'MediaInfo_Get';
  szNameMediaInfo_Close = 'MediaInfo_Close';
  dll_notloaded         = 'DLL nicht geladen.';
  noentry               = 'Keinen Eintrittspunkt für die Funktion gefunden!';

Type
  TFNMediaInfo_Open  = function (File__: PChar): Cardinal cdecl  {$IFDEF WIN32} stdcall {$ENDIF};
  TFNMediaInfo_Get   = function (Handle: Cardinal;
                                 StreamKind: Integer;
                                 StreamNumber: Integer;
                                 Parameter: PChar;
                                 KindOfInfo: Integer;
                                 KindOfSearch: Integer): PChar cdecl  {$IFDEF WIN32} stdcall {$ENDIF};
  TFNMediaInfo_Close = procedure (Handle: Cardinal) cdecl  {$IFDEF WIN32} stdcall {$ENDIF};

var
  MediaInfo_Open  : TFNMediaInfo_Open;
  MediaInfo_Get   : TFNMediaInfo_Get;
  MediaInfo_Close : TFNMediaInfo_Close;
  hDlg: HWND;
  Procedure GetEntryPoints;

implementation

Function WhatIfNoEntry: Integer;
begin
  MessageBox(hDlg, @NoEntry[1], nil, 0);
end;

Procedure GetEntryPoints;
var
  lib:THandle;
begin
  lib := LoadLibrary(@szNameDLL[1]);
  case lib = 0 of
    TRUE:
      begin
        @MediaInfo_Open  := @whatifnoentry;
        @MediaInfo_Get   := @whatifnoentry;
        @MediaInfo_Close := @whatifnoentry;
        messagebox(0, @dll_notloaded[1], nil, 0);
      end;
    else
    begin
      @MediaInfo_Open         := GetProcAddress(lib, @szNameMediaInfo_Open[1]);
      if not Assigned(MediaInfo_Open)
        then @MediaInfo_Open  := @whatifnoentry;
      @MediaInfo_Get          := GetProcAddress(lib, @szNameMediaInfo_Get[1]);
      if not Assigned(MediaInfo_Get)
        then @MediaInfo_Get   := @whatifnoentry;
      @MediaInfo_close        := GetProcAddress(lib, @szNameMediaInfo_Close[1]);
      if not Assigned(MediaInfo_Close)
        then @MediaInfo_Close := @whatifnoentry;
    end;
  end;
end;

end.

Und dem Aufruf der Funktionen habe ich den Aufruf
GetEntryPoints; vorangestellt.

Vielen Dank für Deine Hilfe.