Laufwerke finden und erkennen

[sakura]

Hi DP-ler,

immer wieder kommt die Frage nach dem Finden und erkennen von Laufwerken. Die folgenden Prozeduren helfen Euch bei diesen Aufgaben.

Delphi-Quellcode:

function DriveExists(DriveByte: Byte): Boolean;
begin
  Result := GetLogicalDrives and (1 shl DriveByte) <> 0;
end;

function DriveType(DriveByte: Byte): String;
begin
  case GetDriveType(PChar(Chr(DriveByte + Ord('A')) + ':\')) of
    DRIVE_UNKNOWN: Result := 'unbekannt';
    DRIVE_NO_ROOT_DIR: Result := 'Laufwerk existiert nicht';
    DRIVE_REMOVABLE: Result := 'Wechselmedium';
    DRIVE_FIXED: Result := 'Festplatte';
    DRIVE_REMOTE: Result := 'Netzwerk';
    DRIVE_CDROM: Result := 'CD-ROM/DVD';
    DRIVE_RAMDISK: Result := 'RAM Disk';
  else
    Result := 'anderer Laufwerkstyp';
  end;
end;

Zum Testen der Prozeduren, startet ein neues Projekt, kopiert diese Prozeduren in die Unit des Formulars und fügt eine Listbox und einen Button auf das Formular ein. In den Button_OnClick Event Handler kopiert den folgenden Code.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to 25 do
    if DriveExists(I) then
      ListBox1.Items.Add(Chr(I + Ord('A')) + ':\  (' + DriveType(I) + ')');
end;

Viel Erfolg,


[edit=r_kerber]Code- durch Delphi-Tags ersetzt. Mfg, r_kerber[/edit]

Neues Stichwort: Datenträger

[sakura]

Als Erweiterung eine andere Methode, alle Laufwerke auf einen Ritt in eine Stringliste zu laden. Basiert auf dem Vorschlag von Christian S. die Funktion GetLogicalDriveStrings zu nutzen. Einziges Problem dieser Funktion ist, dass diese eine Stringliste mit null-terminierten Strings und doppel #00#00 am Ende zurückliefert. Ein klein wenig Pointer Verbiegungen helfen uns aber schnell weiter.

Delphi-Quellcode:

procedure LoadLogicalDrives(Strings: TStrings); 
var 
  S: DWORD; 
  AllStrings, CurrentString: PChar; 
begin 
  S := 255; 
  GetMem(AllStrings, Succ(S)); 
  GetLogicalDriveStrings(S, AllStrings); 
  try 
    if AllStrings <> nil then 
    begin 
      CurrentString := AllStrings; 
      while True do 
      begin 
        Strings.Add(StrPas(CurrentString)); 
        Inc(CurrentString, Succ(StrLen(CurrentString))); 
        if CurrentString[0] = #0 then 
          Break; 
      end; 
    end; 
  finally 
    FreeMem(AllStrings); 
  end; 
end;

[edit=r_kerber]Code- durch Delphi-Tags ersetzt. Mfg, r_kerber[/edit]