Programme beim Shutdown des PC's ausführen.

[MathiasSimmack]

Guten Morgen.

1. Wenn du diese Funktion einbindest:

Code:

function fileexists(const szFilename: string): boolean;
var
  Handle   : THandle;
  FindData : TWin32FindData;
begin
  Handle := FindFirstFile(pchar(szFilename),FindData);
  Result := (Handle <> INVALID_HANDLE_VALUE);

  if(Result) then Windows.FindClose(Handle);
end;

kannst du auf die "SysUtils.pas" verzichten, und dein Programm reduziert sich von 43,5k auf 19k.

2. Anstelle von "GetSystemTime" würde ich "GetLocalTime" vorschlagen.

3. Die Anweisung "sleep(150)" dient wofür? Um die Bearbeitung zu verzögern, damit man die Protokollierung ausführen kann? Hm, bei mir hat´s auch ohne geklappt. Aber ich lasse mich da gern belehren.


<Edit>

Machen wir doch noch folgendes:

Code:

function inttostr(const i : integer): string;
begin
  Result := ''; str(i,Result);
end;

// zu finden im EDH -->
function GetWindowsUpTime: String;
const
  DAYS    : Integer = 1000 * 60 * 60 * 24;
  HOURS   : Integer = 1000 * 60 * 60;
  MINUTES : Integer = 1000 * 60;
  SECONDS : Integer = 1000;
var
  Ticks : Integer;
  day, hour, min, sec : Integer;
begin
 Ticks := GetTickCount;
   //GetTickCount gibt die Zeit nach einem Windowstart an

 day := Ticks div DAYS; //Tage
 dec(Ticks, day * DAYS);

 hour := Ticks div HOURS; //Stunden
 dec(Ticks, hour * HOURS);

 min := Ticks div MINUTES; //Minuten
 dec(Ticks, min * MINUTES);

 sec := Ticks div SECONDS; //Sekunden

 Result := IntToStr(day)  + ' days, '+
           IntToStr(hour) + ' hours, '+
           IntToStr(min)  + ' min, '+
           IntToStr(sec)  + ' sec';
end;

Und dann erweitern wir WM_CREATE:

Code:

WM_CREATE:
  begin
    AssignFile(f, 'log.txt');
    if (FileExists('log.txt')) then
      Append(f)
    else
      Rewrite(f);

    GetLocalTime(SystemTime);
    WriteLn(f, 'ShutdownSpy launched at ',
               LeadingZero(SystemTime.wYear), '/',
               LeadingZero(SystemTime.wMonth), '/',
               LeadingZero(SystemTime.wDay), ' ',
               LeadingZero(SystemTime.wHour), ':',
               LeadingZero(SystemTime.wMinute), ':',
               LeadingZero(SystemTime.wSecond), '.');

    WriteLn(f, 'OS is running since ' + GetWindowsUpTime);
    CloseFile(f);

    ...
  end;

Fertig, bei 20k Größe.

</Edit>

Gruß,
Mathias,