Interfaces und Delegation durch "implements"

[stoxx]

Ich wollte nochmal auf das Beispiel hinweisen.
Mir hatte das damals nicht gefallen, da man im Aufruf ein doppelte Create hatte.
Aber es geht doch viel einfacher *an den Kopf greif*

jedenfalls kann man jetzt die Klasse TSomeClass mit einem Interface verwenden, obwohl diese Klasse selber nicht vom Typ TInterfacedObject abgeleitet ist. Und das ist ja schonmal perfekt!!

Und man merkt keinen Unterschied. Perfekt für Objektorientiertes Programmieren.
Und vor allen Dingen braucht man sich nicht selber um die Freigabe des objektes kümmern, wird einfach freigegeben, sobald es nicht merh benutzt wird ...

Man würde sich wünschen, dass Delphi Win32 das auch mal von Haus aus kann, ohne dass man den Wrapper benutzen muss. Sollte eigentlich, wenn man will, für den Compiler kein problem sein.
(Wenn es Codegear denn integriert)


Verwendung einfach:

Delphi-Quellcode:

var
  SomeInt: ISomeInterface;
begin
  SomeInt := TSomeWrapper.Create;
  SomeInt.Method1;

http://www.dummzeuch.de/delphi/objec...2/deutsch.html

Delphi-Quellcode:

unit frmMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;


type
  ISomeInterface = interface
    procedure Method1;
    procedure Method2;
  end;

//==============================================================================
type
  TSomeClass = class(TObject)
    procedure Method1;
    procedure Method2;
  end;

//==============================================================================
type
  TSomeWrapper = class(TInterfacedObject, ISomeInterface)
  protected
    fSomeClass: TSomeClass;
    property SomeClass: TSomeClass read fSomeClass implements ISomeInterface;
  public
    constructor Create;
    destructor Destroy; override;
  end;


//==============================================================================
type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;


//==============================================================================
implementation
//==============================================================================

{$R *.dfm}


{ TSomeClass }

//==============================================================================

procedure TSomeClass.Method1;
begin
    showmessage('Test Method1');
end;

//==============================================================================
procedure TSomeClass.Method2;
begin

end;

//==============================================================================
//==============================================================================
//==============================================================================

constructor TSomeWrapper.Create;
begin
  inherited Create;
  fSomeClass := TSomeClass.Create;
end;
//==============================================================================

destructor TSomeWrapper.Destroy;
begin
  fSomeClass.Free;
  inherited;
end;

//==============================================================================



procedure TForm1.Button1Click(Sender: TObject);
var
  SomeInt: ISomeInterface;
begin
  SomeInt := TSomeWrapper.Create;
  SomeInt.Method1;
end;



end.