Optimierte Optionen

[Christian Seehase]

Moin adecke,

ich dachte mir das so:

Ein Settings Objekt:

Delphi-Quellcode:

type
  TadSettings = class(TObject)
  private
    Fini : TIniFile;
    function GetMyOption: string;
    procedure SetMyOption(const Value: string);
  public
    constructor Create(const AsIniPath : string);
    destructor Destroy; override;
    property MyOption : string read GetMyOption write SetMyOption;
  end;

implementation
 
constructor TadSettings.Create(const AsIniPath: string);
begin
  inherited Create;
  Fini := TIniFile.Create(AsIniPath);
end;

destructor TadSettings.Destroy;
begin
  FreeAndNil(Fini);
  inherited;
end;

function TadSettings.GetMyOption: string;
begin
  Result := Fini.ReadString('Options','MyOption','<NIX>');
end;

procedure TadSettings.SetMyOption(const Value: string);
begin
  Fini.WriteString('Options','MyOption',Value);
  Fini.UpdateFile;
end;

das dann, z.B. im Hauptformular deklariert wird, und dann überall zur Verfügung steht.

Delphi-Quellcode:

 type
  TForm1 = class(TForm)
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private-Deklarationen }
    FSettings : TadSettings;
  public
    { Public-Deklarationen }
    property Settings : TadSettings read FSettings;
  end;

implementation

procedure TForm1.FormCreate(Sender: TObject);
begin
  FSettings := TadSettings.Create(ExtractFilePath(paramstr(0))+'\MySettings.ini');
  Edit1.Text := FSettings.MyOption;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FreeAndNil(FSettings);
end;