Unbegrenzt viele Nachkommastellen

[negaH]

Hi Dano,

ich habe mich mal des NRoot() Problemes angenommen. Du hast natürlich Recht gehabt, NRoot() berechnet unter bestimmten Umständen den Rest falsch.

Hier mal der korregierte Source für NRoot() aus meiner Lib.

Delphi-Quellcode:

function NRoot(var A,R: IInteger; const B: IInteger; E: Integer): Boolean;
// A = B^(1/E), R = B - B^(1/E)^E, returns R == 0 if B is a perfect power of E
//         NRoot(1MBit, 3) = 31.6 seconds
// TBigNum.NRoot(1MBit, 3) = 44.9 seconds
// @A, @R can be nil, if both are nil we can check for PerfectPower
// todo: apply a recursive karatsuba newton method, equal to NSqrt()
resourcestring
  sNRoot = 'NRoot(), B must be > 0 and E > 0';
var
  X,Y,T: IInteger;
  I: Integer;
begin
  Result := True;
  if E <= 0 then NRaise(@sNRoot);
  I := NSgn(B, True);
  if I <= 0 then NRaise(@sNRoot);
  if (E = 1) or (I = 1) then
  begin
    if @A <> nil then NSet(A, B);
    if @R <> nil then NSet(R, 0);
  end else
    if E = 2 then
      Result := NSqrt(A, R, B)
    else
      begin
        NBit(Y, (NSize(B) + E -1) div E, True);
        Dec(E);
        repeat
          NSet(X, Y);
          NPow(T, Y, E);
          NMul(Y, T, E);
          NAdd(T, Y);            // now here ->  T = Y^E * (E +1)
          NMul(Y, X);
          NAdd(Y, B);
          NDivRem(Y, T, Y, T);
          I := NCmp(Y, X);
        until I >= 0;
 // HR, BugFIX!, we have to recompute on some circumstances the remainder
 // Thanks to Dano to pointing me out this.
        if I <> 0 then
        begin
          NPow(T, X, E +1);
          NSub(T, B, T);
        end;
        Result := NSgn(T) = 0;
        if @A <> nil then NSwp(A, X);
        if @R <> nil then NSwp(R, T);
      end;
end;

Gruß hagen