AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Thema durchsuchen
Ansicht
Themen-Optionen

Constructor von abgeleiteter Klasse wird ignoriert

Ein Thema von angos · begonnen am 16. Apr 2025 · letzter Beitrag vom 16. Apr 2025
Antwort Antwort
angos

Registriert seit: 26. Mai 2004
Ort: Rheine
551 Beiträge
 
Delphi 11 Alexandria
 
#1

Constructor von abgeleiteter Klasse wird ignoriert

  Alt 16. Apr 2025, 09:06
Hi zusammen,

ich frage mich, warum das hier so ist, wie es ist

Ich hatte mich in meinem Hauptprojekt gewundert, warum die Konstruktoren meiner abgeleiteten Klassen ignoriert wurden.
Mein Problem habe ich dann in eine Konsolenanwendung ausgelagert und erhalte dort folgendes Phänomen

Die Ausgabe meiner Konsolenanwendung
Code:
Warum wird bei Test2 und Test3 der Konstruktor von TDerivedClass ignoriert?

Test 1 (funktioniert)
TBaseClass.Create
TDerivedClass.Create

Test 2 (funktioniert nicht)
TBaseClass.Create

Test 3 (funktioniert nicht)
TBaseClass.Create

Der Sourecode meiner Konsolenanwendung
Code:
program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

type
  TBaseClass = class
  public
    constructor Create;
  end;

  TDerivedClass = class(TBaseClass)
  public
    constructor Create;
  end;

  TClassType = type of TBaseClass;


constructor TBaseClass.Create;
begin
  Writeln('TBaseClass.Create');
end;

constructor TDerivedClass.Create;
begin
  inherited;
  Writeln('TDerivedClass.Create');
end;

procedure Test1;
begin
  Writeln('Test 1 (funktioniert)');
  var ClassType := TDerivedClass;
  var Obj := ClassType.Create;
  Writeln('');
end;

procedure Test2;
begin
  Writeln('Test 2 (funktioniert nicht)');
  var ClassType: TClassType := TDerivedClass;
  var Obj: TBaseClass := ClassType.Create;
  Writeln('');
end;

procedure Test3;
var
  ClassType: TClassType;
  Obj: TBaseClass;
begin
  Writeln('Test 3 (funktioniert nicht)');
  ClassType := TDerivedClass;
  Obj := ClassType.Create;
  Writeln('');
end;


begin
  try
    WriteLn('Warum wird bei Test2 und Test3 der Konstruktor von TDerivedClass ignoriert?');
    WriteLn('');
    Test1;
    Test2;
    Test3;

    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.
Ansgar
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.199 Beiträge
 
Delphi 10 Seattle Enterprise
 
#2

AW: Constructor von abgeleiteter Klasse wird ignoriert

  Alt 16. Apr 2025, 09:12
In Delphi verhält sich der Konstruktor hier genauso, wie jede andere "normale" Methode auch: Sie ist nicht virtuell. Also wird auch nur die aus der Basisklasse aufgerufen.

Machst du dein TBaseClass::Create halt virtual und dein TDerivedClass::Create dann override und gut ist 😎
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
44.373 Beiträge
 
Delphi 12 Athens
 
#3

AW: Constructor von abgeleiteter Klasse wird ignoriert

  Alt 16. Apr 2025, 11:32
Es wird immer der Constructor des ClassType verwendet.

Ist das eine TClass-Variable (class of ...), dann immer nur DESSEN, es sei denn der Constructor ist override (virtual), dann von dem Typ, welcher in dieser Variable gepspeichert ist.
Denn es kann den neuen Constructor ja sonst nicht kennen.
Ein Therapeut entspricht 1024 Gigapeut.
  Mit Zitat antworten Zitat
angos

Registriert seit: 26. Mai 2004
Ort: Rheine
551 Beiträge
 
Delphi 11 Alexandria
 
#4

AW: Constructor von abgeleiteter Klasse wird ignoriert

  Alt 16. Apr 2025, 12:59
Besten Dank für die Erklärungen!
Ansgar
  Mit Zitat antworten Zitat
Antwort Antwort

 

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 05:25 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz