TOLEEnum Umwandlung aus String

[Humbucker]

Hallo Uwe,

Hintergrund der ganzen Geschichte ist die Verwendung eines COM Interface. Der Ländercode aus dem TOLEEnum CountryCode2 (definiert im Interface) wird dem Property Country des Interface eiAdrr zugewiesen.

eiAddr.Country := TEnumUtils.GetCountryCode2FromString<TCountryCode>('CountryCode_DE'))); //TOLEEnum;

Zur Kontrolle der Datenaufbereitung wird CodeSite verwendet. Hierbei soll der Wert von eiAdr.Country wieder in einen lesbaren String umgewandelt werden.

CodeSite.Send(csmInfo, 'Country: ' + TCountryCode(eiAddr.Country).AsString); Mit "casten" meine ich diesen Vorgang: TCountryCode(eiAddr.Country). Nutze ich eine falsche Vokabel?

Nachdem ich diese Zeilen geschrieben habe, hat es Klick gemacht und ich habe verstanden, warum es nicht funktioniert. Daraufhin habe ich noch eine Funktion geschrieben, die den Index von CountryCode2 bestimmt. Der Aufruf zur Umwandlung sieht dementsprechend jetzt wie folgt aus:

CodeSite.Send(csmInfo, 'Country: ' + TEnumUtils.GetStringfromCountryCode2(eiAddr.Country));

Delphi-Quellcode:

class function TEnumUtils.GetStringfromCountryCode2(aValue: cardinal) : string;
  begin
    Result := 'CountryCode_unk';
    for var idx := Low(TCountryCode.cCountryEnums) to High(TCountryCode.cCountryEnums) do begin
      if TCountryCode.cCountryEnums[idx] = aValue then begin
        Result := TCountryCode(idx).AsString;
        break;
      end;
    end;
  end;

... und kaum macht man es richtig, schon funktioniert es.
Nochmal Danke für deine Unterstützung.

VG Michael

[Uwe Raabe]

Das korrekte Vorgehen wäre die Deklaration einer TCountyCode-Variable:

Delphi-Quellcode:

var countryCode: TCountryCode;

countryCode.AsOleEnum := eiAddr.Country;
CodeSite.Send(csmInfo, 'Country: ' + countryCode.AsString);

Will man es bei einem Einzeiler belassen, dann könnte man im record helper passende class functions ergänzen:

Delphi-Quellcode:

  TCountryCodeHelper = record helper for TCountryCode
  ...
  public
    class function Create(AOleEnum: Cardinal): TCountryCode; overload; static;
    class function Create(const AString: string): TCountryCode; overload; static;
  ...
  end;
...

class function TCountryCodeHelper.Create(AOleEnum: Cardinal): TCountryCode;
begin
  Result.AsOleEnum := AOleEnum;
end;

class function TCountryCodeHelper.Create(const AString: string): TCountryCode;
begin
  Result.AsString := AString;
end;

Damit ließe sich der CodeSite-Aufruf wieder so gestalten:

Delphi-Quellcode:

CodeSite.Send(csmInfo, 'Country: ' + TCountryCode.Create(eiAddr.Country).AsString);

Damit kann man analog auch den anderen Aufruf hiermit ersetzen:

Delphi-Quellcode:

eiAddr.Country := TCountryCode.Create('DE').AsOleEnum;