TProgressbar - Farbe definieren

[FriedrichAT]

Hallo!

Geht auch ohne Shape.

Delphi-Quellcode:

Uses   Winapi.CommCtrl, Winapi.UxTheme, // ergänzen

type
  TForm1 = class(TForm)
    ProgressBar1: TProgressBar;
    ProgressBar2: TProgressBar;
    TrackBar1: TTrackBar;
    procedure FormShow(Sender: TObject);
    procedure TrackBar1Change(Sender: TObject);
  private    { Private-Deklarationen }
  public     { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormShow(Sender: TObject);
begin
  Winapi.UxTheme.SetwindowTheme(ProgressBar1.Handle, '', '');
  // Setzen der Hintergrundfarbe
  SendMessage(ProgressBar1.Handle, PBM_SETBKCOLOR, 0, clRed);
  // Setzen der Balkenfarbe
  SendMessage(ProgressBar1.Handle, PBM_SETBARCOLOR, 0, clNavy);

  Winapi.UxTheme.SetwindowTheme(ProgressBar2.Handle, '', '');
  // Setzen der Hintergrundfarbe
  SendMessage(ProgressBar2.Handle, PBM_SETBKCOLOR, 0, clNavy);
  // Setzen der Balkenfarbe
  SendMessage(ProgressBar2.Handle, PBM_SETBARCOLOR, 0, clRed);
end;

procedure TForm1.TrackBar1Change(Sender: TObject);
begin
  ProgressBar1.Position:= Trackbar1.Position;
  ProgressBar2.Position:= Trackbar1.Position;
end;

[Arnoldmmings]

Ich glaube, das funktioniert nur, wenn die Laufzeit-Themes deaktiviert sind. Wenn die Themes aktiviert sind, kann man den Balken zum Beispiel in Rot anzeigen, indem man `ProgressBar.State := pbsError;` setzt. Damit hat man jedoch nur begrenzte Möglichkeiten, da es nur drei Zustände gibt: `pbsNormal`, `pbsError` und `pbsPaused`.

[jaenicke]

Zitat von Arnoldmmings:

Ich glaube, das funktioniert nur, wenn die Laufzeit-Themes deaktiviert sind.

Deshalb deaktiviert FriedrichATs Quelltext die Themes ja auch für die Komponenten, bevor die Farben gesetzt werden.

[Arnoldmmings]

Zitat von jaenicke:

Zitat von Arnoldmmings:

Ich glaube, das funktioniert nur, wenn die Laufzeit-Themes deaktiviert sind.

Deshalb deaktiviert FriedrichATs Quelltext die Themes ja auch für die Komponenten, bevor die Farben gesetzt werden.

Danke schön!