Letztes Verzeichnis im String ermitteln

[DieDolly]

Dieser Code hier ist vermutlich schon seit 10 Jahren in meiner pas-Datei und wurde seitdem auch nicht verändert.
Ich würde euch gerne fragen, ob dieses Vorhaben besser umsetzbar ist.

Bitte nicht hauen, der Code ist uralt und echt nicht gut.

Delphi-Quellcode:

function GetLastDirectory(Directory: string): string;
var
 tmpSrcPath: string;
begin
 Directory := Trim(Directory);

 if Directory = '' then
  Exit;

 tmpSrcPath := Directory;

 if EndsStr('\', tmpSrcPath) then
  tmpSrcPath := Copy(tmpSrcPath, 1, Length(tmpSrcPath) - 1);

 if Pos(':', tmpSrcPath) > 0 then
  tmpSrcPath := StringReplace(tmpSrcPath, ':', '', [rfReplaceAll]);

 if Trim(tmpSrcPath) <> '' then
  Result := Copy(tmpSrcPath, LastDelimiter('\', tmpSrcPath) + 1, Length(tmpSrcPath))
 else
  Result := '';
end;

[Uwe Raabe]

Würde ich heute so schreiben:

Delphi-Quellcode:

  
uses
  System.SysUtils, System.IOUtils;

...
 
function GetLastDirectory(const Directory: string): string;
begin
  Result := TPath.GetFileName(ExcludeTrailingPathDelimiter(Directory))
end;

Müsste man vielleicht noch mit den realen Randbedingungen testen (z.B. Pfade mit Punkten, nur Laufwerk usw.)

[himitsu]

TPath.GetFullPath

[DieDolly]

https://learn.microsoft.com/de-de/do...h?view=net-8.0

Was hat GetFullPath damit zu tun, wenn man das letzte Verzeichnis ermitteln möchte?

[himitsu]

Zitat von Uwe Raabe:

Müsste man vielleicht noch mit den realen Randbedingungen testen (z.B. Pfade mit Punkten, nur Laufwerk usw.)

[DieDolly]

Ich weiß nicht warum, aber deine Antworten werfen immer mehr Fragen auf als dass sie helfen. Irgendwo natürlich schön, weil man ja auch nachdenken soll.
Das ist natürlich in einem Forum hilfreich (zu einem gewissen Maße).

Ich verstehe aber nicht, was TPath.GetFullPath mit irgendwelchen Tests zu tun haben soll. Oder soll es nicht?
Wenn ich das testen möchte, schreibe ich einfach TestFunktionXYZ('F:\') usw.

[Delphi.Narium]

Bestimmt nicht die beste Lösung, aber scheint zu funktionieren:

Delphi-Quellcode:

function GetLetztesVerzeichnis(s : String) : String;
begin
  s := ExcludeTrailingPathDelimiter(ExtractFilePath(s));
  s := ReverseString(s);
  s := Copy(s,1,Pos('\',s) - 1);
  Result := ReverseString(s);
end;

[himitsu]

Es gibt z.B. Probleme mit relativen Pfaden, bei solchem Vorgehen.

Zitat von Delphi.Narium:

ReverseString

Hatte ich auch schonmal so gemacht, aber im Grunde ist es nur eine Krücke, um mit POS, einer Funktion, welche das Erste sucht, das Letzte zu suchen, anstatt etwas zu verwenden, was das Letzte sucht.
Pos/PosEx in einer Schleife (immer noch schneller, als ein/zwei mal ReverseString)

Wobei das zweite ReverseString garnicht nötig ist, wenn man die gefundene Position mit Length verrechnet, um direkt aus dem originalen String zu kopieren,

aber
string.LastIndexOf
string.LastDelimiter


oder, wie es Uwe bereits zeigte, also Pfadnamenfunktionen, zum Extrahieren des letzten Namen.

[Uwe Raabe]

Auch eine Alternative:

Delphi-Quellcode:

  var arr := tmpSrcPath.Split(['\', ':']); // oder auch SplitString
  Result := arr[High(arr)];

[Christian Seehase]

Da unter Windows als Pfadtrenner Slash (/) und Backslash (\) zulässig sind
und das auch in beliebiger Anzahl hintereinander habe ich mir sowas erstellt:

Delphi-Quellcode:

function csExcludeTrailingPathDelimiterWin(const AsInput : string) : string;

var
  i : integer;

begin
  Result := AsInput;
  i      := length(AsInput);
  if i = 0 then exit;
  while CharInSet(AsInput[i],['\','/']) do dec(i);
  Result := Copy(AsInput,1,I);
end;

Im Explorer funktioniert das mit den gemischten und mehreren Pfadtrennern
zwar nicht, aber in der Console.