Constructor from Instance

[Stefan1286b]

Guten Tag.
Weiß jemand wie man einen Constructor von einer Instanz aufruft?
Zum verstehen eine Kleines Beispiel:

Code:

type
TAnimal = class
public
 Name:String;
end;

TDog = class(TAnimal)
public
Hairs:Integer;
end;

TCat = class(Tanimal)
public
Color:Integer;
end;




var
 Animal1,Animal2:TAnimal;
begin
 Animal1 := TDog.Create;

 //Some Code

 Animal2 := Animal1.Create;  // << Das funktioniert nicht. Animal1 wird überschrieben.
 Animal2 := Animal1.Class.Create; // << Auch das funktioniert nicht. Wird dann ein TObject.

Die eigentliche Klasse ist von TPersistent abgeleitet und hat schon funktionstüchtig AssignTo mittels RTTI implementiert.

Und gelegentlich muss ich von einer Instanz erstellen.

Ich an folgendes gedacht:

Code:

type
TAnimal = class
public
 Name:String;
 procedure New:TAnimal; virtual; abstract;
end;

TDog = class(TAnimal)
public
Hairs:Integer;
procedure New:TAnimal; override;
end;

TCat = class(Tanimal)
public
Color:Integer;
procedure New:TAnimal; override;
end;

procedure TDogNew:TAnimal;
begin
 Result := TDog.Create;
end;


var
 Animal1,Animal2:TAnimal;
begin
 Animal1 := TDog.Create;

 //Some Code

 Animal2 := Animal1.New;

Aber denke das geht vielleicht auch einfacher.

Vielen Dank im vorraus.

[uligerhardt]

Als erstes würde ich TAnimal mal einen virtuellen Konstruktor verpassen.

Und die Variante mit Class müsste prinzipiell funktionieren, wenn du etwas ergänzt:

Delphi-Quellcode:

type
  TAnimalCLass = class of TAnimal; // Stichwort "Class reference" oder "Metaklasse"
Animal2 := TAnimalCLass(Animal1.Class).Create;

(freihändig hingetippt)

[TiGü]

Jetzt noch ClassType statt Class und dann geht's!

Delphi-Quellcode:

type
    TAnimal = class
    public
        Name: String;
    end;

    TDog = class(TAnimal)
    public
        Hairs: Integer;
    end;

    TCat = class(TAnimal)
    public
        Color: Integer;
    end;

    TAnimalClass = class of TAnimal;

var
    Animal1, Animal2: TAnimal;

begin

    try
        Animal1 := TDog.Create;

        Animal2 := TAnimalClass(Animal1.ClassType).Create;
    except
        on E: Exception do
            Writeln(E.ClassName, ': ', E.Message);
    end;

end.

[uligerhardt]

Zitat von TiGü:

Jetzt noch ClassType statt Class

Äh, ja

Zitat von TiGü:

und dann geht's!

... und sogar ohne virtuellen Konstruktor

[himitsu]

Zitat:

Animal1.Create; // << Das funktioniert nicht. Animal1 wird überschrieben.

Natürlich, weil du hier den Constructor als Funktion/Methode aufrufst, auf einer bestehenden Objekt-Instanz.

Man benutzt zum Erstellen NIEMALS keine Variable, sondern immer den Typ.

ALSO

Delphi-Quellcode:

//Animal2 := Animal1.Create; {NEIN}
Animal2 := TAnimal.Create;

denn sowas will und sollte man, nach Möglichkeit, nicht machen:

Delphi-Quellcode:

Animal2 := TAnimal(TAnimal.NewInstance);
Animal2.Create;

Zitat:

Jetzt noch ClassType ...

Ja, Ob jun direkt den Klassentyp verwenden, oder über eine KlassenTyp-Varialbe (TClass) ... Hauptsache eine Klasse und nicht das Objekt.


Dass es dir das Objekt in Variable Animal1 überschrieben hat, ist korrekt.
Mehr Spaß hättest du mit Animal2 := Animal2.Create; , denn diese Variable war noch nicht initialisiert und es hätte hoffentlich eine schöne Exception gegeben.

Zitat:

Animal2 := TAnimalClass(Animal1.ClassType).Create;

Und nun nur nochmal aus Spaß, auch hier geht es mit getrennter Initialisierung/Speicherreservierung und nachträglichem Constructor.

Delphi-Quellcode:

Animal2 := TAnimal(Animal1.NewInstance);
Animal2.Create;

[Stefan1286b]

Animal2 := TAnimalClass(Animal1.ClassType).Create; Das funktioniert einwandfrei. Vielen Dank