Wert eines Defines merken und wiederherstellen

[TurboMagic]

Hallo,

ein Nutzer der DEC (Delphi Encryption Compendium) hat einen Bug gemeldet,
der zu einem Integer Overflow führen kann.

Details siehe hier: https://github.com/MHumm/DelphiEncry...dium/issues/59

Mit dem dort skizzierten Testprogramm und einer > 600 MB Datei bekomme ich das in D12.0 nachvollzogen
und finde, dass es in TDECHash.Increment8 in DECHashBase.pas in der Unterprozedur AddC hier knallt:

Delphi-Quellcode:

  procedure AddC(var Value: UInt32; const Add: UInt32; var Carry: Boolean);
  begin
    if Carry then
    begin
      Value := Value + 1;
      Carry := (Value = 0); // we might cause another overflow by adding the carry bit
    end
    else
      Carry := False;

    Value := Value + Add;
    Carry := Carry or (Value < Add); // set Carry Flag on overflow or keep it if already set
  end;

Ok, packe ich das Value := Value + Add; in {$Q-} {$Q+} ein knallt es nicht mehr und auch alle
bisher funktionierenden unit Tests funktionieren weiter.

Nur: ich will ja nicht einfach $Q+ danach anmachen, egal ob es schon an war oder nicht.
Ich hab' mir jetzt das hier überlegt:

Delphi-Quellcode:

    {$IFDEF Q+}
      {$define USES_OVERFLOW_CHECKING}    
    {$ENDIF}

    {$Q-}
    Value := Value + Add;

    {$IFDEF USES_OVERFLOW_CHECKING}
      {$Q+}
      {$undefine USES_OVERFLOW_CHECKING}
     {$ENDIF}
    Carry := Carry or (Value < Add); // set Carry Flag on overflow or keep it if already set

Spricht da was dagegen?

Grüße
TurboMagic

[himitsu]

Es gibt seit Jahren schon den Wunsch einer PUSH-Funktion, also vorher Zustand speichern und nachher wiederherstellen, aber neeeeeeeeeee

Vor allem, da diese Prüfung nur mit Einbuchstabigen Options funktioniert.


Nja, innerhalb eigener Units setze ich sowas zu Beginn der Unit und ein zurücksetzen ist (meistens) unnötig,
ansonsten mach ich das UNDEF auch zu Beginn ... immer alles in sich Konsistent, ohne dass man auf Vorhergehendes/Nachfolgendes achten muß.

Delphi-Quellcode:

    {$UNDEF USES_OVERFLOW_CHECKING}  // oder mit Else (vor allem beim Einzeiligen)
    {$IFOPT Q+}
      {$DEFINE USES_OVERFLOW_CHECKING}    
    {$ENDIF}

    {$Q-}
    Value := Value + Add;

    {$IFDEF USES_OVERFLOW_CHECKING}
      {$Q+}
    {$ENDIF}

Delphi-Quellcode:

    //{$UNDEF USES_OVERFLOW_CHECKING}  {$IFOPT Q+} {$DEFINE USES_OVERFLOW_CHECKING} {$ENDIF}
    {$IFOPT Q+} {$DEFINE USES_OVERFLOW_CHECKING} {$ELSE} {$UNDEF USES_OVERFLOW_CHECKING} {$ENDIF}
    {$Q-}
    Value := Value + Add;
    {$IFDEF USES_OVERFLOW_CHECKING} {$Q+} {$ENDIF}

[TurboMagic]

Danke! Habe deine untere Variante mit leicht geänderter Formatierung jetzt übernommen.
Splittet man das in mehrere Zeilen zeigt einem die IDE nun schön welche der beiden Varianten aktiv ist

[himitsu]

Ohhh, och muß zugeben, dass ich beim neuen ausgegrauten Highlighting noch garnicht nachgesehn hab, wie es jetzt aussieht.

[TurboMagic]

Das funktioniert nur, wenn das auszugrauende in einer separaten Zeile steht!
Darum hab' ich deine Lösung leicht umformatiert.

[himitsu]

und ich dachte Emba hätte es richtig eingebaut