Abfangen Windows-Shortcut WIN+SHIFT+Pfeil links/rechts

[ULIK]

Ich bräuchte mal eine Idee:

- das Hauptfenster meiner Anwendung läuft auf Bildschirm 1
- mit WIN+SHIFT+Pfeil links/rechts wird dieses dann ja auf einen zweiten Monitor verschoben.

So weit so gut. Nun öffnet die Anwendung ein Popupfenster, dessen Inhalt wiederum durch eine Form definiert ist, die nach dem Öffnen des Popups auch den Fokus hat (ist so, kann ich wegen externer Komponente auch nicht ändern).
Problem: WIN+SHIFT+Pfeil links/rechts wirkt nun auf diese Form und verschiebt sie auf den zweiten Monitor, währen die aufrufende Hauptform weiterhin auf Monitor 1 steht.

Ich bräuchte jetzt einen Weg, entweder das Verschieben dieser Popupform durch die Tastenkombination zu verhindern oder eben zu erkennen, daß dieses Popup aufgrund der Tastenkombination verschoben werden soll, um dann die Hauptform ebenfalls auf den anderen Monitor zu verschieben.
Idealerweise würde ich den Verschiebbefehl dabei auf mein Hauptfomular umleiten

Ein simples Beispiel:
- zwei Formulare, Formular 1 mit Button
- Formular 1 erzeugt via Button Formular 2 und zeigt dieses mit Formular2.Show an
- nun soll WIN+SHIFT+Pfeil rechts nicht nur Formular 2 auf den zweiten Monitor schieben, sondern auch Formular 1, so daß dieses die relative Position zu Formular 2 behält.

[himitsu]

Oder auf WM_MOVE der Form reagieren und dann entsprechend auch die andere Form verschieben.

Delphi-Quellcode:

if Self.Monitor <> Form26.Monitor then
  //Self.Monitor := Form26.Monitor;  // Monitor hat keinen Setter
  Self.MakeFullyVisible(Form26.Monitor);  // bzw. -stattdessen- vorher besser Top und Left setzen <- entsprechend der Top/Left beider Monitore verschieben

[ULIK]

Danke!

die Lösung für meine Bedürfnisse ist letztendlich, für die entsprechenden Fenster die Message WM_WINDOWPOSCHANGING auszuwerten und die Änderung der Position dann im Vorhinein gleich einmal zu unterbinden (wenn man auf dem weiteren Bildschirm landen würde, etc.).
Damit kann ich das Verschieben dieser Popup-Fenster erst einmal unterbinden und kann dann benutzerfreundlicher reagieren.

Code:

procedure Txxx.WMWindowPosChanging(var Message: TWMWindowPosChanging);
begin
  // Nachfolgender Code funktioniert vor allem deswegen, weil dieses Fenster hier nicht manuell verschoben werden kann. 
  // Darum können Positionsänderungen nur aufgrund von Erstellung oder Monitorwechsel auftreten

  // SWP_NOMOVE muß auf alle gesetzt sein, sonst ignorieren wir das
  if (Message.WindowPos.flags and SWP_NOMOVE = SWP_NOMOVE) then
  begin
    inherited;
    exit;
  end;

  // SWP_NOOWNERZORDER muß gesetzt sein (um falsches Anspringen bei Erstanzeige Popup zu vermeiden, wenn Anwendung  auf zweitem Monitor steht, denn
  // das Fenster wird ursprünglich auf dem Default-Monitor erstellt und dann durch Umhängen des Parent auf den zweiten Monitor platziert)
  if (Message.WindowPos.flags and SWP_NOOWNERZORDER <> SWP_NOOWNERZORDER) then
  begin
    inherited;
    exit;
  end;

  // aktuelle Position bestimmen und den zugehörigen Monitor.
  var rectPos := TRect.Empty;
  GetWindowRect(Message.WindowPos.hwnd, rectPos);
  var curMon := Monitor;

  // neue Position (des Zentrums, denn dieses triggert eventuelle Umskalierungen)
  var ptNewPos := TPoint.Create(Message.WindowPos.x + Message.WindowPos.cx div 2, Message.WindowPos.y + Message.WindowPos.cy div 2);
  var newMon := Screen.MonitorFromPoint(ptNewPos);

  // wenn sich die Monitore unterscheiden, dann Änderung ignorieren
  if newMon.Handle <> curMon.Handle then
  begin
    // Änderung der Position ignorieren
    Message.WindowPos.x := rectPos.Left;
    Message.WindowPos.y := rectPos.Top;
    Message.WindowPos.cx := rectPos.Width;
    Message.WindowPos.cy := rectPos.Height;
    Message.Result := 1;

    // weitere Aktionen ausführen, abhängig vom Popup
    ...
  end
  else
    inherited;
end;