Nutzung von Routinen / Fehler E2016 bei Array

[H.Bothur]

Moin,

ich versuche ja immer noch mit tgputty weiterzukommen.

Meine Version: Delphi 10.4 CE
unter Tools/Optionen/Sprache/Delphi/Bibliothek/Bibliothekspfad habe ich das Verzeichnis tgputty hinzugefügt
(da sind auch die Pas-Files von tgputty drin)

in meinem Source ist unter anderem der Zugriff auf die Funktion

Delphi-Quellcode:

function TForm1.ListingCallback(const names: Pfxp_names): Boolean;
var StartRow,
    i: Integer;
begin
  StartRow := RemoteFilesSG.RowCount;
  RemoteFilesSG.RowCount := StartRow +names.nnames;
  RemoteFilesSG.Cells[0, StartRow +1] := names.names[1].filename;

Diese Routine habe ich so aus einer Demo kompiert - aber, obwohl die Demo sich kompilieren lässt bekomme ich dabei die Fehlermeldung

[dcc32 Fehler] SFTPUnit.pas(55): E2016 Array-Typ erforderlich

Wobei die Zeile 55 die letzte obige Zeile ist und der Cursor das [i] als falsch markiert.

... Ja, in meinem Source wurde da nirgends ein Array definiert, aber das müsste doch aus den Routinen aus tgputty kommen, oder ? Was mache ich da falsch ?

Gruss
Hans

[himitsu]

Nja, kopiert, dein genanntes [i] ist bei dir ein [1], aber egal.
https://github.com/superflexible/TGP...ntMainForm.pas

Außerdem ist der erste Eintrag 0 und nicht 1.



So, Pfxp_names ist erstmal ein Zeiger auf einen Record, welche einen Zeiger auf ein statisches Record-Array enthält.

Also du hast kein eigenes Pfxp_names deklariert, sondern das aus der tgputtylib.pas benutzt? (diese Unit in den Uses)

Zitat:

:= names.names[1].filename;

Eigentlich sollte dürfte Delphi hier alle Zeiger implizit (automatisch) dereferenzieren,
aber du kannst es ja mal explizit versuchen.

:= names^.names^[1].filename;
* der Zeiger auf den Record
* der Zeiger auf das statische Record-Array
* und zum Schluß noch PChar zu String


[EDIT]
"drüfte"
Beim ersten pointer. ist es eindeutig,
aber beim zweiten pointer[ kommt es darauf an, wie es interpretiert wird.

Standardmäßig wird die Zeiger-Arithmetik aktiv sein
und dann wird der Pointer selber als Array behandelt, also ein Array auf den kompletten Subtyp array[0..20000000] of fxp_name , so als würden mehrere 20-Millionen-Arrays hintereinander liegen,
anstatt es hier dereferenziert und dann der Array-Zugriff "innerhalb" des Arrays passiert.

Fazit:
so
:= names.names^[1].filename;
oder so
:= names^.names^[1].filename;

[H.Bothur]

Zitat von himitsu:

Nja, kopiert, dein genanntes [i] ist bei dir ein [1], aber egal.
Außerdem ist der erste Eintrag 0 und nicht 1.

Stimmt - das kam durch verschiedene Versuche das so zu kürzen das sogar ich es verstehe

Zitat:

So, Pfxp_names ist erstmal ein Zeiger auf einen Record, welche einen Zeiger auf ein statisches Record-Array enthält.
Also du hast kein eigenes Pfxp_names deklariert, sondern das aus der tgputtylib.pas benutzt? (diese Unit in den Uses)

Nein - selbst habe ich da nichts definiert sondern einfach nur die Unit eingebunden.

Zitat:

Beim ersten pointer. ist es eindeutig,
so
:= names.names^[1].filename;
oder so
:= names^.names^[1].filename;

Jetzt sieht es so aus:

Delphi-Quellcode:

function TForm1.ListingCallback(const names: Pfxp_names): Boolean;
var StartRow,
    i: Integer;
begin
  StartRow := RemoteFilesSG.RowCount;
  for i := 0 to names.nnames -1 do
  begin
    RemoteFilesSG.RowCount := StartRow +names.nnames;
    RemoteFilesSG.Cells[0, StartRow +1] := names^.names^[i].filename;
  end;
  Result:=true;
end;

Aber in beiden Varianten bekomme ich jetzt die Fehlermeldung

E2149 Klasse besitzt keine Standardeigenschaft in Zeile 57 (die Zeile mit den Pointern).
Unterkringelt wird das die eckige Klammer auf beim [i]

Gruss
Hans

[himitsu]

Zitat von H.Bothur:

E2149 Klasse besitzt keine Standardeigenschaft in Zeile 57 (die Zeile mit den Pointern).
Unterkringelt wird das die eckige Klammer auf beim [i]

Wo steht der Text-Cursor (nach dem Kompilieren),
bzw. wo nach dem Doppelklick auf die Fehlermeldung?

Ich weiß aber auch nicht wie er hier auf "Klasse" kommt.
OK, vielleicht eine leicht missverständliche StandardMeldung die eigentlich heißt "Punkt geht hier nicht, weil ist keine Klasse oder Record".



https://github.com/superflexible/TGP...tgputtylib.pas

Delphi-Quellcode:

     fxp_name=record
       filename,longname:PAnsiChar;
       attrs:fxp_attrs;
       end;
     Pfxp_name=^fxp_name;

     Tfxp_name_array=array[0..20000000] of fxp_name;
     Pfxp_name_array=^Tfxp_name_array;

     fxp_names=record
       nnames:Integer;
       names:Pfxp_name;
       end;
     Pfxp_names=^fxp_names;

names = pointer auf fxp_names (bei nachfolgendem . dereferenziert Delphi automatisch)
names^ = das fxp_names
also hier eigentlich egal ob mit oder ohne ^

names^.nnames oder names.nnames = die Anzahl
names^.names oder names.names = Zeiger auf das Namen-Array
names^.names^ oder names.names^ = das Namen-Array

also müsste names.names^[i] eigentlich der Array-Zugriff sein

names.names^[i].filename der Zugriff auf ein Feld einer der Records im Array.




[EDIT]
Ahhhhhhhm jetzt seh ich es.

fxp_names.names ist ein Zeiger auf den "ersten" Record, nicht auf das Record-Array.
fxp_names=record ... names:Pfxp_name; und nicht ... names:Pfxp_name_array; , obwohl ja ein Array gemeint ist.
Physisch ist es das "Gleiche", aber logisch vom Verhalten her eventuell unterschiedlich.

Also sollte eigentlich doch names.names[i].filename oder names^.names[i].filename funktionieren,
wenn die Zeigerarithmetik aktiv ist.

Ist die bei dir etwa ausgeschaltet?

OK, so oder so, sollte es dann gehen, wenn du selber auf das Array castest.
Pfxp_name_array(names.names)[i].filename

Oder so, falls der direkte Cast sich weigert.
Pfxp_name_array(Pointer(names.names))[i].filename

[H.Bothur]

Zitat von himitsu:

Also sollte eigentlich doch names.names[i].filename oder names^.names[i].filename funktionieren,
wenn die Zeigerarithmetik aktiv ist.

Ist die bei dir etwa ausgeschaltet?

Wo kontrolliere ich das denn ?

Zitat:

OK, so oder so, sollte es dann gehen, wenn du selber auf das Array castest.
Pfxp_name_array(names.names)[i].filename

Das scheint zuz klappen ... keine Fehlermeldung mehr und das Programm scheint so zu funktionieren
Danke für deine Hilfe !

Gruss
Hans

[himitsu]

https://docwiki.embarcadero.com/RADS...r_Math_(Delphi)
Ohhh, es ist wohl doch standardmäßig aus.

Und ich hätte eine Option z.B. in Projektoptionen > Erzeugen > Delphi-Compiler > Compilieren erwartet (die standardmäßig True wäre) ... aber nö.

Dachte ist an, weil es bei mir meistens geht (mit Inc), ohne dass ich es anschalten mußte.
Und es IMHO doch keinen Unterschied zwischen Inc(P, 4); und P := P + 4; gibt.

Delphi-Quellcode:

{$POINTERMATH ON}  // Fehler wenn OFF

procedure TForm1.FormCreate(Sender: TObject);
var
  P: PInteger;
  R: PRect;
begin
  P := nil;
  R := nil;
  Inc(P);  // entspricht P[1] bzw. Inc(P, 4) für P[4]
  Inc(R);

  // [DCC Fehler] E2015 Operator ist auf diesen Operandentyp nicht anwendbar
  P := P + 4;  // entspricht Inc(P, 4) also P[1+4]
  R := R + 4;

  // [DCC Fehler] E2016 Array-Typ erforderlich <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
  if P[3] = 0 then ;  // entspricht P[1+4+3]
  if R[3].Left = 0 then ;
end;

Bis Delphi XE zurück ist es Default OFF,
aber hätte sein können, dass es ganz früher (z.B. Delphi 7) mal ON war.

Aber wenn ich jetzt danach suche ...
https://github.com/superflexible/TGP...ntMainForm.pas

Delphi-Quellcode:

unit VCLClientMainForm;

interface

{$POINTERMATH ON}

...