Dynamische Multipanel Anordnung - Seitenverhältnis bei Resize

[Uwe Raabe]

Versuch es doch mal mit dem Aufruf von ResizePlayerGrid im FormCreate, dem Resize-Event des Grids und bei Änderung des Seitenverhältnisses (hier beispielhaft für 4:3 und 16:9):

Delphi-Quellcode:

procedure ResizeControlWithAspectRatio(AControl: TControl; RatioWidth, RatioHeight: Integer);
var
  actWidth: Integer;
  actHeight: Integer;
  calcHeight: Integer;
  calcWidth: Integer;
  margin: Integer;
  margin1: Integer;
  margin2: Integer;
begin
  actWidth := AControl.Margins.ControlWidth;
  actHeight := AControl.Margins.ControlHeight;
  calcHeight := MulDiv(actWidth, RatioHeight, RatioWidth);
  calcWidth := MulDiv(actHeight, RatioWidth, RatioHeight);
  if calcHeight < actHeight then
  begin
    margin := actHeight - calcHeight;
    margin1 := margin div 2;
    margin2 := margin - margin1;
    AControl.Margins.SetBounds(0, margin1, 0, margin2);
  end
  else
  begin
    margin := actWidth - calcWidth;
    margin1 := margin div 2;
    margin2 := margin - margin1;
    AControl.Margins.SetBounds(margin1, 0, margin2, 0);
  end;
end;

procedure ResizePlayerGrid(AGrid: TGridPanel; AWideScreen: Boolean);
var
  ratioHeight: Integer;
  ratioWidth: Integer;
begin
  ratioWidth := 4*AGrid.ColumnCollection.Count;
  ratioHeight := 3*AGrid.RowCollection.Count;
  if AWideScreen then begin
    ratioWidth := 4*ratioWidth;
    ratioHeight := 3*ratioHeight;
  end;
  ResizeControlWithAspectRatio(AGrid, ratioWidth, ratioHeight);
end;

Update: Ach ja: AlignWithMargins muss bei dem Grid aktiv sein.

[taveuni]

Zitat von Uwe Raabe:

Versuch es doch mal mit dem Aufruf von ResizePlayerGrid im FormCreate, dem Resize-Event des Grids und bei Änderung des Seitenverhältnisses (hier beispielhaft für 4:3 und 16:9):

Update: Ach ja: AlignWithMargins muss bei dem Grid aktiv sein.

Hallo Uwe,
besten Dank für Deine Hilfe. Mit Deinem Vorschlag wird schon mal das Grid Proportional vergrössert und verkleinert. Aber noch nicht unter der Berücksichtigung der maximalen Grösse (siehe im Anhang rot eingezeichnet) und nicht zentriert. Vermutlich werde ich das noch hinbekommen.

Was aber muss ich mit den Row- und ColItems machen? Einfach auf sspercent setzen? Oder auf ssAuto? Damit die mitziehen? Oder muss ich die Werte manuell setzen (insbesondere wenn das Layout ändert)?
Danke für Deine Hilfe.
Gruss Werner

[Uwe Raabe]

Zitat von taveuni:

Was aber muss ich mit den Row- und ColItems machen? Einfach auf sspercent setzen? Oder auf ssAuto? Damit die mitziehen? Oder muss ich die Werte manuell setzen (insbesondere wenn das Layout ändert)?

Ich habe die hier auf ssPercent gesetzt, alle Rows bzw. Colums in der Strukturansicht selektiert und den Value auf 0 stellen. Dann werden die Prozente gleichmäßig aufgeteilt. Programmtechnisch gibt es dafür die Methode EquallySplitPercentuals in den entsprechenden Collections. Die einzelnen Player-Controls müssen dann Align = alClient gesetzt werden.

ssAuto bedeutet, dass sich die Zelle an die Größe des Controls anpasst. Das passt natürlich nicht zu dem Align.

Ich habe mal ein Beispiel angehängt mit dem du ja weiter probieren kannst. Als Platzhalter für die Player verwende ich TMemo.

[taveuni]

Zitat von Uwe Raabe:

Ich habe mal ein Beispiel angehängt mit dem du ja weiter probieren kannst. Als Platzhalter für die Player verwende ich TMemo.

Wow. Vielen Dank dafür!