Fenster an Bildschirmrand / Taskleiste andocken lassen

[Matze]

Hi!

So kann man das Fenster seiner Anwendung an die Ränder des Desktopbereichs andocken lassen, sprich, an den Bildschirmrand, ausgenommen die Taskleiste (die Taskleiste wird nicht überdeckt).

Delphi-Quellcode:

private
    { Private-Deklarationen }
    procedure WMWindowPosChanging(var Message: TWMWINDOWPOSCHANGING);
    message WM_WINDOWPOSCHANGING;

...

procedure TForm1.WMWindowPosChanging(var Message: TWMWINDOWPOSCHANGING);
const
  distance = 10;
begin
  { Obere und untere Festerkante }
  if (Message.WindowPos.y <= distance) and
     (Message.WindowPos.y >= -distance) then
        Message.WindowPos.y := 0
  else
  if (Message.WindowPos.y + Height > (Screen.WorkAreaHeight - distance)) and
     (Message.WindowPos.y + Height < (Screen.WorkAreaHeight + distance)) then
        Message.WindowPos.y := Screen.WorkAreaHeight - Height;

  { Linke und rechte Fensterkante } 
  if (Message.WindowPos.x <= distance) and
     (Message.WindowPos.x >= -distance) then
        Message.WindowPos.x := 0
  else 
  if (Message.WindowPos.x + Width > (Screen.WorkAreaWidth - distance)) and
     (Message.WindowPos.x + Width < (Screen.WorkAreaWidth + distance)) then
        Message.WindowPos.x := Screen.WorkAreaWidth - Width;
end;

Dieser Code wurde von DieHardMan in diesem Thread veröffentlicht.

Dieser Code ist vor allem für die NonCVL-Programmierer interessant.


Die anderen können es auch so lösen (der Beitrag stammt von Meflin):
Man stellt die Property screensnap der Form auf true. snapbuffer gibt den Pixelabstand an, bei dem die Form angedockt wird.

SirThornberry hat folgenden Tipp:
Der Source ist auch ein super Ansatz wenn man mehrere Forms hat um diese aneinander andocken zu lassen.

[Robert_G]

Das Problem mit dem Code ist ein Desktop an dem mehrere Monitore angeschlossen sind.
Ich habe es eben mal Quick 'n dirty für Multi-Monitor-Kompatibilität umgeschrieben:
Es sollte IMHO auch noch unter den seltsamsten Monitorpositionen auf dem Desktop funktionieren.

Delphi-Quellcode:

Procedure TFormIrgendWas.WMWindowPosChanging(Var Message: TWMWINDOWPOSCHANGING);
Var
  MoniRect, DistRect: TRect;
Begin
  { Abmessungen des Monitors, auf dem sich das Fenster befindet }
  MoniRect := Screen.Monitors[Monitor.MonitorNum].WorkareaRect;

  With Message Do
    With DistRect Do
    Begin
      { Abweichungen vom Monitorrand }
      Top    := WindowPos.Y - MoniRect.Top;
      Bottom := WindowPos.Y + Height - MoniRect.Bottom;
      Left   := WindowPos.X - MoniRect.Left;
      Right  := WindowPos.X + Width - MoniRect.Right;

      { Obere Fensterkante }
      If (Top <=  SnapBuffer) And
         (Top >= -SnapBuffer) Then
        WindowPos.Y := MoniRect.Top
      { Untere Fensterkante }
      Else If (Bottom <=  SnapBuffer) And
              (Bottom >= -SnapBuffer) Then
        WindowPos.Y := MoniRect.Bottom - Height;
      { Linke Fensterkante }
      If (Left <=  SnapBuffer) And
         (Left >= -SnapBuffer) Then
        WindowPos.X := MoniRect.Left
      { Rechte Fensterkante }
      Else If (Right <=  SnapBuffer) And
              (Right >= -SnapBuffer) Then
        WindowPos.X := MoniRect.Right - Width;
    End;
End;

Für alle die sich wundern warum ich einen Unterschied zwischen MonitorX rechts und MonitorY links mache -> zieht mal die Taskbar an die linke Seite des 2. Monitors und schaut wie sich das Fenster jetzt "anheftet".

[edit=Matze]Für die Code-Lib vorbereitet, Mfg, Matze[/edit]

[CalganX]

Von idontwantaname kommt folgende Portierung als nonVCL-Variante:

Delphi-Quellcode:

function WndProc(WndHWND: HWnd; uMsg: UInt; wParam: WParam; lParam: LParam): LResult; stdcall;
const
  DISTANCE = 20;
var
  MyWndPos: PWindowPos;
  WorkAreaRect: TRect;
begin
   Result := 0;

   case uMsg of
    WM_WINDOWPOSCHANGING: begin
      // Nötige Informationen holen
      SystemParametersInfo(SPI_GETWORKAREA, 0, @WorkAreaRect, 0);
      MyWndPos := PWINDOWPOS(lParam);

      // Oben und Unten
      if (MyWndPos.y <= DISTANCE) and
         (MyWndPos.y >= -DISTANCE) then
           MyWndPos.y := 0;
      if (MyWndPos.y + MyWndPos.cy > (WorkAreaRect.Bottom - DISTANCE)) and
         (MyWndPos.y + MyWndPos.cy < (WorkAreaRect.Bottom + DISTANCE)) then
           MyWndPos.y := WorkAreaRect.Bottom - MyWndPos.cy;

      // Links und Rechts
      if (MyWndPos.x <= DISTANCE) and
         (MyWndPos.x >= -DISTANCE) then
           MyWndPos.x := 0;
      if (MyWndPos.x + MyWndPos.cx > (WorkAreaRect.Right - DISTANCE)) and
         (MyWndPos.x + MyWndPos.cx < (WorkAreaRect.Right + DISTANCE)) then
           MyWndPos.x := WorkAreaRect.Right - MyWndPos.cx;
    end;

    WM_DESTROY: begin
      PostQuitMessage(0);
    end;

     else Result := DefWindowProc(WndHWND, uMsg, wParam, lParam);
   end;
end;