Anonyme Methode in Schleife ausführen - wie abbrechen?

[hschmid67]

Hallo zusammen,

ich hab ein Konstrukt, mit dem ich ein Objekt kapsele, um daraus ein Interface zu machen. Das Interface stellt dann eine Art ForEach-Methode für Daten des Objekts zur Verfügung, etwa so:

Delphi-Quellcode:

encapsulate(lObject).ForEach(procedure(mStr: string)
  begin
  // do something
  end);

Das funktioniert soweit sehr gut, aber ich würde nun gerne das ForEach durch irgendeine Bedingung in der anonymen Methode abbrechen. Habt Ihr hier eine Idee, wie das gehen könnte?

Das encapsulate.ForEach ist in etwa so implementiert (Beispielobjekt TStringList)

Delphi-Quellcode:

procedure encapsulate.ForEach(proc: TProc<string>);
begin
  for lStr in lObject.List do
  begin
    Proc(lStr);
    // hier könnte man eine Bedingung prüfen und ggf. das ganze ForEach abbrechen
    // also z.B. brich nach dem x-ten Element ab, oder brich ab, wenn Du in lStr "xxx" gefunden hast
    // hier hart codiert ist kein Problem, aber...
  end;
end;

Aber wie bekomme ich die Bedingung in die anonyme Methode? Man müsste in der anonymen Methode ein Flag setzen können, das dann in encapsulate.ForEach überprüft wird... Aber wie kann ich in der anonyment Methode auf ein Flag im Interface (oder dem dahinter liegenden Object) zugreifen?

Viele Grüße
Harald

[Der schöne Günther]

Gib der Methode doch einen var-Parameter canContinue oder so mit. Eingänglich auf True gesetzt und wenn jemand den ganzen Vorgang abgebrochen haben will, setzt er das auf False .

Also dass die Methode nicht mehr TProc<String> ist, sondern TMyProc = reference to procedure(const mStr: String; var canContinue: Boolean) .
Oder TFunc<String, Boolean> .

[dummzeuch]

Wäre SysUtils.Abort eine Option? Oder eine von EAbort abgeleitete Exception? Oder generell eine spezielle eigene Exception, die man dann im Debugger ignoriert?

[TigerLilly]

Du könntest deinem Konstrukt eine zweite anonyme Funktion spendieren, die eine Abbruchbedingung auswertet.

[hschmid67]

Vielen Dank für Euer Mitüberlegen und die Ideen!
- Über den var-Parameter hatte ich auch schon nachgedacht: muss ich mal ausprobieren.
- Und die Abort-Funktion habe ich tatsächlich die letzten 20 Jahre noch nie verwendet - und kenn ich bisher gar nicht. Werde ich auch mal testen.
- Wegen der zweiten anonymen Methode: - muss ich mal in Ruhe durchdenken. Das kann ich mir im Moment noch gar nicht richtig vorstellen.
Jedenfalls klingt das schon so, als könnte ich daran weiterarbeiten und vielleicht auch eine elegante Lösung finden.
Danke nochmal und viele Grüße
Harald

[jaenicke]

In der Windows API und anderswo wird oft auch schlicht der Rückgabewert der anonymen Funktion verwendet. Solange man True zurückliefert, läuft die Schleife weiter.

Das ist aber im Grunde natürlich nichts anderes als der var-Parameter, nur dass man den entsprechend bezeichnen kann.

[Uwe Raabe]

Zitat von hschmid67:

ich hab ein Konstrukt, mit dem ich ein Objekt kapsele, um daraus ein Interface zu machen. Das Interface stellt dann eine Art ForEach-Methode für Daten des Objekts zur Verfügung

Wäre das nicht eher etwas für einen Enumerator?

Delphi-Quellcode:

type
  TMyObject = class
  private type
    TEnumerator = record
    private
      FIndex: Integer;
      FOwner: TMyObject;
      function GetCurrent: string;
    public
      constructor Create(AOwner: TMyObject);
      function MoveNext: Boolean;
      property Current: string read GetCurrent;
    end;
  private
    FList: TStringList;
  public
    constructor Create;
    destructor Destroy; override;
    function GetEnumerator: TEnumerator;
  end;

function TMyObject.GetEnumerator: TEnumerator;
begin
  Result := TEnumerator.Create(Self);
end;

constructor TMyObject.TEnumerator.Create(AOwner: TMyObject);
begin
  FIndex := -1;
  FOwner := AOwner;
end;

function TMyObject.TEnumerator.GetCurrent: string;
begin
  Result := FOwner.FList[FIndex];
end;

function TMyObject.TEnumerator.MoveNext: Boolean;
begin
  Inc(FIndex);
  Result := FIndex < FOwner.FList.Count;
end;

Dann kannst du die übliche for-in Syntax verwenden und die Abbruchbedingung direkt einprogrammieren:

Delphi-Quellcode:

var
  myObject: TMyObject;
begin
  myObject := TMyObject.Create;
  try
    for var S in myObject do begin
      if S = 'Stop' then
        Break;
      ShowMessage(S);
    end;
  finally
    myObject.Free;
  end;
end;

[himitsu]

Zitat:

nur dass man den entsprechend bezeichnen kann.

Und es nichts macht, wenn man ihm nichts zuweist. (weil ja vor dem Funktionsaufruf initialisiert)
(wobei zwar Delphi inzwischen Integer/Boolean-Results mit 0 zu initialisieren scheint, also das EAX)

OK, bei OUT statt VAR, würde es per se wie beim Result reagieren und man sollte besser in der Prozudur da etwas zuweisen.

Zitat:

Dann kannst du die übliche for-in Syntax verwenden und die Abbruchbedingung direkt einprogrammieren:

Nur das Break da "direkt" nicht geht, weil ja in einer Prozedur.

Abort oder Raise ginge, bzw. das mit dem Result/Var und dann nach der Prozedur in der Schleife das Break, bzw. die Abbruch-Variable in die Schleifenbedingung.



PS: Beim Result hat man den Spaß, dass ... ja was Bedeutet es nun?
True (Boolean) oder z.B. 1 (Integer) ... ist das nun Weitermachen oder Abbrechen

[freimatz]

Zitat von himitsu:

PS: Beim Result hat man den Spaß, dass ... ja was Bedeutet es nun?
True (Boolean) oder z.B. 1 (Integer) ... ist das nun Weitermachen oder Abbrechen

Da mache ich dann gerne statt dem Boolean einen Auzählungstyp. Ist zwar Arbeit, aber dann ist es klar und vermeidet Fehler.