Zwischenablage Zugriff verweigert

[haentschman]

Hallöle...

Zitat:

Zwischenablage Zugriff verweigert kann nicht geöffnet werden.

...der Fehler kommt in diesem Falle aus einer Fremdkomponente. (DevExpress) Das das ein Windowsproblen ist, ist bekannt.
https://www.delphipraxis.net/164785-...-gesperrt.html

Mein MadExcept schließt immer die komplette Anwendung... Welche Möglichkeiten gibt es das anders abzufangen...

PS: In meinen Anwendungen habe ich immer eine Schleife mit Abbruchbedingung um den Except Block...wie kriege ich das mit der Fremdkomponente hin? (ich weigere mich eigentlich bei DevExpress Workarounds einzuarbeiten...mit jeder neuen Version wieder von vorn. ) Oder direkt im Vcl.Clipboard?

Delphi-Quellcode:

procedure TcxCustomTextEdit.PasteFromClipboard;
var
  ANewSelStart: Integer;
  ANewText, S: string;
begin
  if Clipboard.HasFormat(CF_TEXT) then
    if Focused then
    begin
      BeginUserAction;
      try
        S := Clipboard.AsText;
        if CanChangeSelText(S, ANewText, ANewSelStart) then
          InnerEdit.CallDefWndProc(WM_PASTE, 0, 0);
      finally
        EndUserAction;
      end;
    end
    else
      SelText := Clipboard.AsText;
end;
...
procedure TClipboard.Open;
begin
  if FOpenRefCount = 0 then
  begin
    FClipboardWindow := Application.Handle;
    if FClipboardWindow = 0 then
    begin
      FClipboardWindow := AllocateHWnd(MainWndProc);
      FAllocated := True;
    end;
    if not OpenClipboard(FClipboardWindow) then
      raise EClipboardException.CreateResFmt({$IFNDEF CLR}@{$ENDIF}SCannotOpenClipboard, // <---
        [SysErrorMessage(GetLastError)]);
    FEmptied := False;
  end;
  Inc(FOpenRefCount);
end;

Was würdet ihr empfehlen?

[Sinspin]

Warum schließt MadExcept deine ganze Anwendung? Per Einstellung?
Dann solltest du sehen was das für eine Exception class ist und dafür sorgen dass die von MadExcept anders behandelt wird.

[haentschman]

Die Idee ist schon mal umgesetzt...(Bild)

...das löst aber leider nicht das grundsätzliche Problem.

[Uwe Raabe]

Zitat von haentschman:

ich weigere mich eigentlich bei DevExpress Workarounds einzuarbeiten...mit jeder neuen Version wieder von vorn.

- Die DevExpress-Sourcen in ein Git-Repo.
- Einen eigenen Branch mit deinen Anpassungen aufmachen.
- Bei neuen Versionen diese in Main nachpflegen.
- Main in deinen Branch mergen.

[haentschman]

Zitat:

Die DevExpress-Sourcen in ein Git-Repo.

...habe ich ja schon. ...mache ich schon. Das Problem ist aber auch, daß mit jeder neuen Version auch die Workarounds fehlerhaft sein können...hatte ich schon mal.

Ich fange mit jeder Version wieder an zu testen.

Aktuell wird das Grid komplett schwarz wenn ApplicationProcessMessages aufgerufen wird. (nicht fragen , Control/Form.Repaint in allen Varianten funktioniert trotz Aufruf teilweise nicht nicht. Die Labels und die Progressbar einer "StatusForm" (TForm) sind manchmal eingefroren)

@Uwe:
Du hast doch einen heißen Draht zu Emba. Vieleicht können sie die Schleife in TClipboard.Open einbauen.

Vorschlag zum Optimieren:

Delphi-Quellcode:

procedure TClipboard.Open;
var
  OpenCount: Integer;
  OpenResult: LongBool;
begin
  OpenCount := 0;
  OpenResult := False;

  if FOpenRefCount = 0 then
  begin
    FClipboardWindow := Application.Handle;
    if FClipboardWindow = 0 then
    begin
      FClipboardWindow := AllocateHWnd(MainWndProc);
      FAllocated := True;
    end;

    repeat
      Inc(OpenCount);
      OpenResult := OpenClipboard(FClipboardWindow);
      if not OpenResult then
      begin
        Sleep(30);
      end;
    until OpenResult or (OpenCount > 50);
    if not OpenResult then
    begin
       raise EClipboardException.CreateResFmt({$IFNDEF CLR}@{$ENDIF}SCannotOpenClipboard,
          [SysErrorMessage(GetLastError)]);
    end;

    FEmptied := False;
  end;
  Inc(FOpenRefCount);
end;

[Sinspin]

Zitat von haentschman:

Aktuell wird das Grid komplett schwarz wenn ApplicationProcessMessages aufgerufen wird.

Ist bei mir auch so. Ich habe es aufgegeben nach einer Lösung zu suchen.
Laut DevExpress ist aktuell jemand dabei, sich der ganzen Fehler in den VCL Komponenten anzunehmen. Vermutlich sitzt der jemand gerade in einem Schützengraben, denn ich sehe keine Verbesserungen.

Ich habe auch ein Problem mit meinem Pluginsystem. Ich habe diverse Dll's mit Dialogen die auch Grids enthalten. Klappt soweit wunderbar...bis ich das Form mit dem Grid im Hauptform einbette. Alle Komponenten funktionieren wie immer, nur in Grids bekommt man keinen sichtbaren Focus mehr auf Records.
DevExpress stellt bei den Grids irgendwas mit der WindowProc an was es nicht überlebt wenn sich durch das einbetten das WindowHandle, etc ändert.

[haentschman]

[Luft ablassen ON]

Zitat:

Ist bei mir auch so. Ich habe es aufgegeben nach einer Lösung zu suchen.

Das kostet immer wieder Zeit...

[Uwe Raabe]

Zitat von haentschman:

Vieleicht können sie die Schleife in TClipboard.Open einbauen.

Das wird aus Kompatibilitätsgründen wohl nicht passieren. Ich könnte mir eher eine Lösung dieser Art vorstellen (später mal direkt in TClipboard):

Delphi-Quellcode:

type
  TClipboardHelper = class helper for TClipboard
    function TryOpen(MaxTries: Integer = 50; Delay: Integer = 20): Boolean;
  end;

function TClipboardHelper.TryOpen(MaxTries: Integer = 50; Delay: Integer = 20): Boolean;
begin
  var cnt := 0;
  while True do begin
    try
      Open;
      Exit(True);
    except
      on EClipboardException do begin
        Inc(cnt);
        if cnt < MaxTries then
          Sleep(Delay)
        else
          Exit(False);
      end;
    end;
  end;
end;

Das erfordert aber eine Anpassung aller Open-Aufrufe.

[haentschman]

...ich habe das mal im TcxCustomTextEdit.PasteFromClipboard integriert

Delphi-Quellcode:

procedure TcxCustomTextEdit.PasteFromClipboard;
var
  ANewSelStart: Integer;
  ANewText, S: string;

  function GetClipboardText: string;
  var
    RetryCount: Integer;
    Success: Boolean;
  begin
    RetryCount := 0;
    Success := False;
    while not Success do
    begin
      try
        Result := Clipboard.AsText;
        Success := True;
      except
        on EClipboardException do
        begin
          Inc(RetryCount);
          if RetryCount < 50 then
          begin
            Sleep(20)
          end
          else
          begin
            raise Exception.Create('Cannot read clipboard after fifty attempts');
            // Exit(''); // Alternativ statt raise
          end;
        end
        else
          raise;
      end;
    end;
  end;

begin
  if Clipboard.HasFormat(CF_TEXT) then
  begin
    if Focused then
    begin
      BeginUserAction;
      try
        S := GetClipboardText;
        if CanChangeSelText(S, ANewText, ANewSelStart) then
          InnerEdit.CallDefWndProc(WM_PASTE, 0, 0);
      finally
        EndUserAction;
      end;
    end
    else
      SelText := GetClipboardText;
  end;
end;

[Uwe Raabe]

Man sollte eigentlich nie eine simple Exception werfen, da man damit dem Aufrufer die Möglichkeit nimmt, selektiv auf diese zu reagieren. Besser wäre hier wieder eine EClipboardException oder ein schlichtes raise;