Spring4D Logging

[mytbo]

Zitat von taveuni:

Ich bin dies auch am evaluieren. Bevor ich da tiefer gehe: Ist für den FileAppender eine automatisch Rotation mit MaxFileSize eingebaut?

Wenn du am Logging interessiert bist, ist mORMot einen Blick wert. Die Hilfe vermittelt einen ersten Überblick. Ein Beispiel für die Anwendung:

Delphi-Quellcode:

program TestLogging;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  System.Classes,
  mormot.core.base,
  mormot.core.rtti,
  mormot.core.log,
  mormot.core.zip;

procedure Test1;
var
  log: ISynLog;
begin
  log := TSynLog.Enter;
  log.Log(sllInfo, 'Test1 arbeitet');
end;

procedure Test2;
var
  list: TStringList;
begin
  list := TStringList.Create;
  try
    TSynLog.Add.Log(sllInfo, 'Test2 arbeitet', list);
    list[0];
  finally
    list.Free;
  end;
end;

begin
  var logFamily: TSynLogFamily := TSynLog.Family;
  logFamily.Level := LOG_VERBOSE;
  logFamily.AutoFlushTimeOut := 2;
  logFamily.HighResolutionTimestamp := False;
  logFamily.PerThreadLog := ptNoThreadProcess;
  logFamily.ExceptionIgnore.Add(EConvertError);
  logFamily.OnArchive := EventArchiveZip;
  logFamily.ArchiveAfterDays := 1;

  try
    Test1;
    Test2;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Ein kleiner Auszug aus der Logdatei:

Code:

20230213 20391650  +    TestLogging Test1 (19) 
20230213 20391651 info  Test1 arbeitet
20230213 20391651  -    00.000.042
20230213 20391651 info  System.Classes.TStringList(032688f0) Test2 arbeitet
20230213 20391651 EXC   EStringListError {Message:"Listenindex außerhalb des gültigen Bereichs (0)"} [Main] at 16a833 System.Classes.pas TStringList.Get (7644)

Die Funktion TSynLog.Enter protokolliert Unit-, Klassen- und Funktionsname mit Quelltext-Zeilennummer. Beim Verlassen der Funktion wird die Ausführungszeit ermittelt. Im Beispiel sind es 42us. Mit dem Aufruf Log kann ein Eintrag hinzugefügt werden. Bei Angabe einer Instanz wird der Unit- und Klassenname mit dem Instanz Pointer aufgeführt. Es stehen 32 vordefinierte Events zur Verfügung. Bei einer Exception wird die Fehlermeldung und der Aufrufpfad, mit allen Unit-, Klassen- und Funktionsname inklusive Zeilennummern aufgelistet. Ein Beispiel aus der Praxis findest du im Quelltext dieses DP Artikels.

Bis bald...
Thomas

[taveuni]

Das sieht sehr gut aus danke.

[dummzeuch]

Zitat von mytbo:

Wenn du am Logging interessiert bist, ist mORMot einen Blick wert.

Die Funktion TSynLog.Enter protokolliert Unit-, Klassen- und Funktionsname mit Quelltext-Zeilennummer. Beim Verlassen der Funktion wird die Ausführungszeit ermittelt. Im Beispiel sind es 42us. Mit dem Aufruf Log kann ein Eintrag hinzugefügt werden. Bei Angabe einer Instanz wird der Unit- und Klassenname mit dem Instanz Pointer aufgeführt. Es stehen 32 vordefinierte Events zur Verfügung. Bei einer Exception wird die Fehlermeldung und der Aufrufpfad, mit allen Unit-, Klassen- und Funktionsname inklusive Zeilennummern aufgelistet. Ein Beispiel aus der Praxis findest du im Quelltext dieses DP Artikels.

Hm, wie ermittelt das denn die Informationen zu Unit-, Klassen- und Funktionsname mit Quelltext-Zeilennummer ? Ich habe bisher dafür jclDebug benutzt, aber ich vermute mORMot verwendet die JCL nicht.

[Arnaud]

Zitat von dummzeuch:

Hm, wie ermittelt das denn die Informationen zu Unit-, Klassen- und Funktionsname mit Quelltext-Zeilennummer ? Ich habe bisher dafür jclDebug benutzt, aber ich vermute mORMot verwendet die JCL nicht.

Sie haben Recht: mORMot hat ihren eigenen .map file parser und kann ihn für den Stack-Trace verwenden, um alle Quellcode-Referenzen (Unit, Funktionsname und Zeilennummer) abzurufen. Es kann den .map-Inhalt viel stärker komprimieren als jclDebug und alternativ, da es sein eigenes optimiertes Binärformat verwendet.

[mytbo]

Zitat von dummzeuch:

Hm, wie ermittelt das denn die Informationen zu Unit-, Klassen- und Funktionsname mit Quelltext-Zeilennummer ?

Arnaud hat es angesprochen, du musst die Erstellung der Map-Datei detailliert für das Projekt aktivieren. Beim Programmstart wird automatisch aus der Map-Datei eine *.mab Datei erzeugt. Im obigen Beispiel ist die Map-Datei ca. 2,8MB, die Mab-Datei 0,17MB groß. Das Logging wird im mORMot2 Framework so effizient gehandhabt, dass es kein {$define WITHLOG} mehr gibt. Einfach selbst ausprobieren. Mit Hilfe dieser kurzen Anleitung ist es in 3 Minuten auf dem Rechner und bei Nichtgefallen in 3 Sekunden wieder spurlos entfernt.

Nachtrag: Warum belastet Logging mit mORMot nicht? Dazu folgender Quelltext aus der Unit mormot.core.log, Zeile 4223:

Delphi-Quellcode:

class function TSynLog.Add: TSynLog;
var
  P: pointer;
begin
  // inlined TSynLog.Family with direct fGlobalLog check
  result := pointer(Self);
  if result <> nil then
  begin
    P := PPointer(PAnsiChar(result) + vmtAutoTable)^;
    if P <> nil then
    begin
      // we know TRttiCustom is in the slot, and Private is TSynLogFamily
      P := TRttiCustom(P).PrivateSlot;
      result := TSynLogFamily(P).fGlobalLog;
      // <>nil for ptMergedInOneFile and ptIdentifiedInOneFile (most common case)
      if result = nil then
        result := TSynLogFamily(P).SynLog; // ptOneFilePerThread or at startup
    end
    else
      result := nil; // TSynLog.Family/FamilyCreate should have been called
  end;
end;

Gibt es keine LogFamily, ist der Overhead nur minimale Pointerei. Wer genau aufgepasst hat, sieht den Fehler in Funktion Test1 im Beispiel. Tipp: Es fehlt eine Prüfung auf Nil.

Bis bald...
Thomas

[taveuni]

Zitat von mytbo:

Wenn du am Logging interessiert bist, ist mORMot einen Blick wert. Die Hilfe vermittelt einen ersten Überblick.

Eine kleine Frage: Ich habe mich gewundert dass die Datei erst beim beenden geschrieben wird obwohl ich AutoFlushTimeOut gesetzt habe. Ich habe dann im mormot.core.log.pas dies gefunden:

Delphi-Quellcode:

procedure TSynLogFamily.StartAutoFlush;
begin
  if (AutoFlushThread = nil) and
     not SynLogFileFreeing and
     (fAutoFlushTimeOut <> 0)
     {$ifdef ISDELPHI} and (DebugHook = 0) {$endif} then
    AutoFlushThread := TAutoFlushThread.Create;
end;

Ich möchte aber auch auch wenn ich die Anwendung im Debugger laufen lasse die Datei fortlaufend schreiben.
Gibt es ein property welches ich übersehen habe um dies zu tun? Oder muss ich in der mormot.defines.inc das define ISDELPHI rausnehmen? Wohl kaum.

[mytbo]

Zitat von taveuni:

Eine kleine Frage: Ich habe mich gewundert dass die Datei erst beim beenden geschrieben wird obwohl ich AutoFlushTimeOut gesetzt habe.

Bist du sicher, dass da nichts geschrieben wird? Auch wenn der Explorer 0 Bytes anzeigt, werden die Einträge nach Ablauf der AutoFlushTimeOut Zeit in die Datei geschrieben. Ansonsten erzwingt die Funktion Flush(True) das sofortige Schreiben. Für dich könnten die Echo Funktionen von Interesse sein. Du kannst eine eigene Callback für EchoCustom, oder mit dem ISynLogCallback Interface dein eigenes Remote-Logging schreiben und mit EchoRemoteStart starten. In den DDD Tools von mORMot1 findest du ein Beispiel für WebSockets.

Bis bald...
Thomas

[taveuni]

Zitat von mytbo:

Bist du sicher, dass da nichts geschrieben wird? Auch wenn der Explorer 0 Bytes anzeigt, werden die Einträge nach Ablauf der AutoFlushTimeOut Zeit in die Datei geschrieben.

Ja. Weil wie Du in der Funktion siehst ist der DebugHook = 1. Somit ist die Bedingung nicht erfüllt und der Autoflushthread wird nicht gestartet. Aber klar ich kann das auch manuell machen im Programm wenn $DEBUG defined ist.
Danke

Übrigens sorry dem Threadersteller für das kapern dieses Threads. Eigentlich gings ja um Spring4D...
Gruss Werner

[mytbo]

Zitat von taveuni:

Aber klar ich kann das auch manuell machen im Programm wenn $DEBUG defined ist.

Vielleicht habe ich es nicht verständlich erklärt: Du kannst dein eigenes Remote-Logging schreiben, oder das Programm Synopse LogView aus dem mORMot1 SQLite3\Samples\11 - Exception logging nehmen. Der Quelltext ist noch nicht nach mORMot2 portiert. Du musst mORMot1 installieren und es erstellen. Mit dem Button Server Launch startest du den Server, der auf den konfigurierbaren Port lauscht. Am einfachsten schreibst du dir eine Unit wie folgt:

Delphi-Quellcode:

unit u_RemoteLogging;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.UITypes, System.Classes,
  mormot.core.base,
  mormot.core.text,
  mormot.core.rtti,
  mormot.core.log;

type
  TRemoteLogging = class(TComponent)
  strict private
    FLogClass: TSynLogClass;
  protected
    const
      DEFAULT_PORT = 8091;
  public
    destructor Destroy; override;
    procedure Start(pmLogClass: TSynLogClass; const pmcUri: RawUtf8 = '127.0.0.1/LogService');
  end;

implementation

uses
  mormot.net.sock,
  mormot.rest.http.client;

//==============================================================================
// TRemoteLogging
//==============================================================================

destructor TRemoteLogging.Destroy;
begin
  if FLogClass <> Nil then
    FLogClass.Family.EchoRemoteStop;

  inherited Destroy;
end;

procedure TRemoteLogging.Start(pmLogClass: TSynLogClass; const pmcUri: RawUtf8);
var
  uri: TUri;
begin
  if pmLogClass <> Nil then
  try
    FLogClass := pmLogClass;
    uri.From(pmcUri, Int32ToUtf8(DEFAULT_PORT));
    TRestHttpsClient.CreateForRemoteLogging(uri.Server, pmLogClass, Utf8ToInteger(uri.Port), uri.Root);
  except
    on E: Exception do
      pmLogClass.Add.Log(sllError, E);
  end;
end;

end.

Durch diesen Aufruf TRemoteLogging.Create(Self).Start(TSynLog); bindest du sie ins Programm ein und kannst danach den Einträgen im LogView folgen.

PS: Für dein Programm verwendest du mORMot2. Nur zur Erstellung des Programms Synopse LogView benötigst du zur Zeit noch mORMot1.

Bis bald...
Thomas