Screeshot TWebbrowser

[joacim]

Hallo zusammen,
vorab, ich arbeite mit Delphi 6 und habe kaum Erfahrung mit html usw.
Ich versuche einen Screenshot von einer Web-Browser Seite (open street map) zu erstellen und verwende TWebbrowser. Soweit ich verstanden habe basiert TWebbrowser auf IE4. Das ist ja nun nicht mehr die jüngste Software. Es geht um eine ganz bestimmte Seite

http://tools.geofabrik.de/map/#18/50...abrik_Standard

Die Koordinaten sind hier nur ein Beispiel. Im z.B. Firefox sieht alles gut aus,
im TWebbrowser bekomme ich mitten im Bild (Karte) so was wie ein Edit-Feld
angezeigt. Mag es sein, dass TWebbrowser da gewisse Dinge „noch nicht kann“?

Ich habe im Netz div. Beiträge zu diesem Thema gefunden, es hat mich aber alles nicht wirklich weitergebracht.
Ich bin auch für jeden alternativen Vorschlag dankbar. Wichtig ist, dass ich aus meinem
Programm heraus einen Schreenshot zum Weiterverarbeiten bekommen kann.

[TiGü]

Folgender Codeschnipsel funktioniert bei mir:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.OleCtrls, SHDocVw, Vcl.StdCtrls, Winapi.ActiveX;

type
  TForm1 = class(TForm)
    WebBrowser1: TWebBrowser;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function GetIEBitmap(IEDoc: IWebBrowser2): TBitmap;
var
  ViewObject: IViewObject;
  DrawRect: TRect;
begin
  Result := TBitmap.Create;
  Result.Width := IEDoc.Width;
  Result.Height := IEDoc.Height;
  if IEDoc.Document <> nil then
  begin
    IEDoc.Document.QueryInterface(IViewObject, ViewObject);
    if ViewObject <> nil then
    try
      DrawRect := Rect(0, 0, Result.Width, Result.Height);
      ViewObject.Draw(DVASPECT_CONTENT, 1, nil, nil, Form1.Handle,
        Result.Canvas.Handle, @DrawRect, nil, nil, 0);
    finally
      ViewObject._Release;
    end;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  IE: IWebbrowser2;
  MyBitmap: TBitmap;
begin
  IE := Webbrowser1.DefaultInterface as IWebBrowser2;
  MyBitmap := GetIEBitmap(IE);
  MyBitmap.SaveToFile('C:\Temp\MyScreenshot.bmp');
  MyBitmap.Free;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  WebBrowser1.Navigate('http://tools.geofabrik.de/map/#18/50.4720/7.4568&type=Geofabrik_Standard');
end;

end.

GetIEBitmap habe ich hier gefunden: https://www.delphipraxis.net/69655-w...creenshot.html

[joacim]

danke, das ist eine schöne Funktion. Funktioniert gut!
ABER: Das Hauptproblem mit dem nicht zu identifiziernendem "edit" (oder was auch immer)
im Bild ist damit leider nicht beseitigt. Wie gesagt, mit anderen Browsern ist diese "edit" nicht
in der Anzeige. (firefox und edge)

[softtouch]

Mal versuchen, ob es besser aussieht when IE11 emuliert wird:

Delphi-Quellcode:

var exename:string;
  exename:=TPath.GetFileName(ParamStr(0));
  reg := TRegistry.Create(KEY_SET_VALUE);
  reg.RootKey := HKEY_CURRENT_USER;
  Win32Check(reg.OpenKey(registryPath,True) );
  reg.WriteInteger(exeName, 11000);
  reg.CloseKey;
  reg.Free;

[joacim]

@softtouch
danke, aber das ist leider nicht so meine Spezialgebiet...
was ist mit registryPath gemeint?
Würde es gerne testen

[mmw]

Hallo,
daas duerfte gemeint sein-

Delphi-Quellcode:

HKEY_LOCAL_MACHINE (or HKEY_CURRENT_USER)
   SOFTWARE
      Microsoft
         Internet Explorer
            Main
               FeatureControl
                  FEATURE_BROWSER_EMULATION
                     anwendung.exe = (DWORD) 00011000

https://docs.microsoft.com/en-us/pre...ectedfrom=MSDN

Gruß

[Delphi.Narium]

Delphi-Quellcode:

procedure IERegFake(sProgName : String; dwVersion :DWord);
var
          reg : TRegistry;
begin
  // 11000 = Version 11.0
  // 10001 = Version 10.0
  //  8000 = Version  8.0 Build = 86001
  //  7000 = Version  7.0
  reg := TRegistry.Create;
  reg.RootKey := HKEY_CURRENT_USER;
  reg.OpenKey('Software\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_BROWSER_EMULATION',true);
  reg.WriteInteger(sProgName,dwVersion);
  reg.Free;
end;
// Aufruf z. B.:
IERegFake(ExtractFileName(Application.ExeName), 11000);

[joacim]

noch ein guter Hinweis, danke..
aber ich muß die Umstellung (wenn sie denn was bringt) auf einem Kunden-PC
vornehemen. Daher wäre mir eine Lösung per Programm lieber. Kunden mögen nicht
in der Registry arbeiten

[Delphi.Narium]

Probier' erstmal aus, ob es funktioniert.

Dann baust Du meinen Funktion (oder eine ähnliche) ins FormCreate der Mainform ein und fertig ist die Laube.

Da muss dann keiner in der Registry rumhandwerken. Macht das Programm beim Start von ganz alleine.

[peer81]

Hallo joacim,

das von Delphi.Narium bindest du ja in dein Programm ein und rufst die Funktion auch in deinem Programm auf.
Sollte auch auf dem Kunden PC gehen. Mit HKEY_CURRENT_USER geht das auch bei einem "normalen" User.

MfG