meminifiles, inifiles , einlesen scheitert

[BerndS]

Bis zu einer bestimmten Version wurde beim Einlesen abgebrochen, wenn in der Datei /Stream ein #0 vorkommt.
In XE7 ist das so und bei 10.4 nicht mehr.
Erkennbar ist das in der System.Classes in der Methode

Delphi-Quellcode:

procedure TStrings.SetTextStr
...
while P^ <> #0 do
...

Ich würde da mal einen Haltepunkt setzen oder mit dem Hex-Editor (HxD) nach #0 suchen.

[bernhard_LA]

das Problem liegt vlt. doch nicht an den Files ....
ich habe eine Mini-Testprogramm geschrieben , in diesem Falle klappt das einlesen der Sections, welches in der echten Anwendung fehlschlägt

Delphi-Quellcode:

procedure TForm2.ReadPointlist3Dfile(filename: string);
var
  AptList: TPointList3DAlign;
begin
  AptList := TPointList3DAlign.Create;

  AptList.LoadfromFile(filename);

  CopyPointList2Memo(AptList, 'debug 3D', Memo3);
end;

procedure TForm2.ReadPointlistfile(filename: string);
var
  AptList: TPointlist;
begin
  AptList := TPointlist.Create;

  AptList.LoadfromFile(filename);

  CopyPointList2Memo(AptList, 'debug 2D ', Memo3);

  AptList.SavetoFile(filename);
end;

procedure TForm2.ReadInifile(filename: string);
var
  aini: TInifile;
  Sections: TStringlist;
begin
  aini := TInifile.Create(filename);

  Sections := TStringlist.Create;

  aini.ReadSections(Sections);

  Memo2.Lines.AddStrings(Sections);

  aini.Free;

  Sections.Free;
end;

procedure TForm2.Button1Click(Sender: TObject);
begin
  if OpenDialog1.Execute() then
  begin
    Memo1.Lines.LoadfromFile(OpenDialog1.filename);

    ReadInifile(OpenDialog1.filename);

    ReadPointlistfile(OpenDialog1.filename);

    ReadPointlist3Dfile(OpenDialog1.filename);
  end;
end;

end.

Das nun existierende Problem, die eigentliche Anwendung führt auch nur diese 3 Schritte aus (und natürlich viele anderr ...) schlägt weiterhin fehl.

Delphi-Quellcode:

  
  AptList := TPointList3DAlign.Create;

  AptList.LoadfromFile(filename);

  CopyPointList2Memo(AptList, 'debug 3D', Memo3);

im Debugging zeigt sich , daß bei AptList.LoadfromFile(filename); keine Sections gefunden werden .....

[Uwe Raabe]

Vielleicht ist die Datei noch von einer anderen Anwendung gesperrt oder sowas in der Art.

[himitsu]

Da hier sämtliche Ressourcenschutzblöche fehlen, kann er es auch selber sein.

[bernhard_LA]

@himitsu

Zitat:

sämtliche Ressourcenschutzblöche fehlen, kann er es auch selber sein.

was wäre denn hier zu tun ?
eine andere *.ini Datei, im anderen Ordner mit der selben Delphi Anwendung geschieben funktioniert perfekt

[bernhard_LA]

PS: problem gelöst, im der eigentlichen Anwendung wurde der "nur fast" richtige Filename übergeben,super peinlich

schade , daß ich keine exception bekomme wenn ich aus einer ini Datei lesen, die nicht existiert,

dann wäre der Bug viel früher aufgefallen

[Delphi.Narium]

Delphi-Quellcode:

procedure TForm2.ReadPointlist3Dfile(filename: string);
var
  AptList: TPointList3DAlign;
begin
  if not FileExists(filename) then begin
    MessageDlg(Format('Datei %s wurde nicht gefunden.',[ExtractFileName(Filename)]),mtError,[mbOk],0);
    exit;
  end;
  AptList := TPointList3DAlign.Create;
  try
    AptList.LoadfromFile(filename);
    CopyPointList2Memo(AptList, 'debug 3D', Memo3);
  finally
    AptList.Free; // oder muss AptList nicht freigegben werden???
  end;
end;

Delphi-Quellcode:

procedure TForm2.ReadInifile(filename: string);
var
  aini: TInifile;
  Sections: TStringlist;
begin
  if not FileExists(filename) then begin
    MessageDlg(Format('Datei %s wurde nicht gefunden.',[ExtractFileName(Filename)]),mtError,[mbOk],0);
    exit;
  end;
  aini := TInifile.Create(filename);
  try
    Sections := TStringlist.Create;
    try
      aini.ReadSections(Sections);
      Memo2.Lines.AddStrings(Sections);
    finally
      Sections.Free; // Damit die Freigabe auch bei Fehlern erfolgt.
    end;
  finally
    aini.Free; // Damit die Freigabe auch bei Fehlern erfolgt.
  end;
end;

Wenn in der ursprünglichen Routine einmal ein Fehler auftritt, bleibt (schlimmstenfalls) der Zugriff auf die Datei "Filename" bestehen und wenn Du Pech hast, ist die Datei (dauerhaft) blockiert. (Kommt halt auf die jeweils verwendeten Zugriffsrechte auf Dateiebene an.)

Wenn

Zitat:

eine andere *.ini Datei, im anderen Ordner mit der selben Delphi Anwendung geschieben funktioniert perfekt

, heißt das nicht, dass man auf jegliche Fehlerbehandlung und die gesicherte Freigabe von Objekten, ... verzichten kann.

Fehlerbehandlung und Ressourcenschutzblöcke sind halt nicht für den funktionierenden Normalfall, sondern für die Ausnahmen-/Fehlerbehandlung erforderlich, damit eben auch dann "normal" weitergearbeitet werden kann und nicht "irgendwie, irgendwo, irgendwann" nicht nachvollziehbare "Spätfolgen" auftreten.

[venice2]

Zitat:

PS: problem gelöst, im der eigentlichen Anwendung wurde der "nur fast" richtige Filename übergeben,super peinlich

Fehler wäre nie aufgetreten wenn die Dateinamen bekannt und immer gleich sind diese als Konstante definiert gewesen wären.
Man vertippt sich doch sehr leicht.