inifile ReadFloat deutsch/english formatsettings

[bernhard_LA]

Würde gerne mit einem Deutschen Windows PC ( dezimale = 1,2 ) Ini files einlesen die jemand auf einem englischen PC geschrieben hat ( 1.2)
mit der Funktion Ini.ReadFloat(....) .
Was muss ich machen damit ich beide Formate einlesen kann ?

Delphi-Quellcode:

fIni := TIniFile.Create(aFileName);
  try

    X := fIni.ReadFloat(SectionStr, 'x', -99999);  //  mag nur Komma-Zahlen  mit Deutschen Format 1,2   :-( 


  finally 
    fIni.free; 
  end;

[bcvs]

Als String einlesen und mit StrToFloat umwandeln. Dabei die FormatSettings nach Bedarf setzen.

[bernhard_LA]

gibt's ne Lösung bei der ich nix selber schreiben muss .... eigentlich doch ne Aufgabe der Klasse inifile ......

[himitsu]

Erstmal ist es totaler Schwachsinn, dass INIs überhaupt lokalisiert gespeichert/gelesen werden.
(aber für INIs gibt es ja leider auch eigentlich keine globale einheitliche Konvention/Richtline/Norm/...)
Und leider kam in den letzten 20 Jahren auch noch keiner auf die Idee eine FormatSettings-Variable in TCustomIniFile für Floats und DateTimes einzufügen.

Fazit:

• Du mußt, wie schon gesagt wurde, selbst den Float behandeln
  StrToFloat(INI.ReadString(...), DeinFormatSettings)
  • manuell, vor Ort
  • TIniFile ableiten und diese Funktionen überschreiben überdecken
  • oder besser noch einfach mit einem ClassHelper erweitern, z.B. um ein ReadFloatUS
• oder du stellst das globale FormatSettings in der SysUtils um
  • also entweder vor und nach dem Zugriff auf die INI, vorübergehend (aber ist auch keine gute Idee, da nicht threadsave usw.)
  • oder permanent dein Programm auf Englisch umstellen
    System.SysUtils.FormatSettings := TFormatSettings.Create('en-US');

Aber vielleicht wird das Problem ja im nächsten Jahrtausend behoben sein.
https://quality.embarcadero.com/browse/RSP-17616

[Der schöne Günther]

Oder du machst es dir einmal als class helper und benutzt dann einfach die folgende Unit in deiner uses . Das ist das schwere Los eines Software-Entwicklers, manchmal muss man doch tatsächlich wenigstens noch ein uses tippen.

Delphi-Quellcode:

unit System.IniFiles.TCustomIniFile.Helper;

interface uses System.IniFiles, System.SysUtils;

type
   /// <summary>
   ///     Ersetzt die Methode
   ///    <c>WriteFloat</c> und deren <i>Read</i>-Gegenstück da die
   ///    RTL-Implementation von <c>TCustomIniFile</c> dummerweise
   ///    mit den <b>globalen Formatsettings</b> arbeitet
   /// </summary>
   /// <remarks>
   ///     Floats werden mit <c>.</c> als <c>DecimalSeparator</c> geschrieben.
   /// </remarks>
   TCustomIniFileHelper = class helper for TCustomIniFile
      protected class var
         internalFormatSettings: TFormatSettings;
      protected
         class constructor Create();
      public
         procedure WriteFloat(const Section, Name: string; Value: Double);
         function ReadFloat(const Section, Name: string; Default: Double): Double;
   end;


implementation

{ TCustomIniFileHelper }

class constructor TCustomIniFileHelper.Create();
begin
   internalFormatSettings := TFormatSettings.Invariant();
end;

function TCustomIniFileHelper.ReadFloat(
   const Section, Name: string;
   Default: Double
): Double;
var
   FloatStr: string;
begin
   FloatStr := ReadString(Section, Name, '');
   Result := Default;
   if FloatStr <> '' then
   try
      Result := StrToFloat(FloatStr, internalFormatSettings);
   except
      on EConvertError do
         Result := inherited ReadFloat(Section, Name, Default);
   else
      raise;
   end;
end;

procedure TCustomIniFileHelper.WriteFloat(
   const Section, Name: string;
   Value: Double
);
begin
   WriteString(Section, Name, FloatToStr(Value, internalFormatSettings));
end;

end.

[Uwe Raabe]

Zitat von bernhard_LA:

gibt's ne Lösung bei der ich nix selber schreiben muss .... eigentlich doch ne Aufgabe der Klasse inifile ......

Das sehen andere zwar auch so (https://quality.embarcadero.com/browse/RSP-17616), aber solange das nicht implementiert ist musst du wohl selber ran.

[Rolf Frei]

Doppelpost

[Rolf Frei]

Eigentlich reicht es doch einfach das DecimalChar zu setzen:

Delphi-Quellcode:

var OrgDecSep: Char;
fIni := TIniFile.Create(aFileName);
  try
    try
      X := fIni.ReadFloat(SectionStr, 'x', -99999); // mag nur Komma-Zahlen mit Deutschen Format 1,2 :-(
    except
      OrgDecSep := FormatSettings.DecimalSeparator;
      try      
        FormatSettings.DecimalSeparator := '.';
        X := fIni.ReadFloat(SectionStr, 'x', -99999); // mag nur Komma-Zahlen mit Deutschen Format 1,2 :-(
      finally
        FormatSettings.DecimalSeparator := OrgDecSep;
      end;
    end;
  finally
    fIni.free;
  end;

Oder wenn du genau weisst, dass das INI nach US/ANSI Regel gespeichert wurde, kannst du das auch einmalig vor der Verarbeitung der INI machen:

Delphi-Quellcode:

var OrgDecSep: Char;
OrgDecSep := FormatSettings.DecimalSeparator;
fIni := TIniFile.Create(aFileName);
  try
    FormatSettings.DecimalSeparator := '.';
    X := fIni.ReadFloat(SectionStr, 'x', -99999); // mag nur Komma-Zahlen mit Deutschen Format 1,2 :-(
    ... weitere ReadFLoat, etc.
  finally
    FormatSettings.DecimalSeparator := OrgDecSep;
    fIni.free;
  end;

[Uwe Raabe]

Zitat von Rolf Frei:

Eigentlich reicht es doch einfach den DecimalSeparator zu setzen

Wenn sich das ganze nicht in einem Thread abspielt, geht das wohl.

[himitsu]

Es ist egal, ob DAS in einem Thread oder im Hauptthread abläuft ... wenn irgendwer Anderes in einem "anderen" Thread gleichzeitig das auch nutzen oder gar ebenfalls ändern will, dann ...