Wie bei Änderung des Formats den Ordner wechseln?

[TurboMagic]

Hallo,

gegeben ist D10.3.3 und eine Action mit einem TOpenDialog.
Wenn der Benutzer auf einen bestimmten Dateityp wechselt soll im
OpenDialogTypeChange Event der Ordner, den der OpenDialog anzeigt
geändert werden.

In einer alten C++ buolder Zeitschrift hatte ich einen Lösungsansatz
gefunden den ich wie folgt nach Delphi portiert hatte, der aber nicht
mehr zu funktionieren scheint.

Delphi-Quellcode:

procedure ChangeDialogFolder(Dialog:TOpenDialog; NewPath: string);
var
  DlgHandle     : HWND;
  EdtHandle     : HWND;
  OkBtnHandle   : HWND;

  OldPathLength : Integer;
  OldPath       : string;
begin
  DlgHandle := GetParent(Dialog.Handle);
  EdtHandle := GetDlgItem(DlgHandle, edt1);

  OldPathLength := GetWindowTextLength(EdtHandle);
  SetLength(OldPath, OldPathLength);

  GetWindowText(EdtHandle, PWideChar(OldPath), OldPathLength + 1);
  OldPath := PWideChar(OldPath);

  SetWindowText(EdtHandle, NewPath);

  OkBtnHandle := GetDlgItem(DlgHandle, IDOK);
  SendMessage(OkBtnHandle, BM_CLICK, 0, 0);
  SetWindowText(EdtHandle, OldPath);
end;

Leider ist EdtHandle immer 0 und auch wenn ich das auf cmb1 ändere (also Combobox
weil anders als früher nur noch eine Combo Box auf dem Dialog da ist) ist's auch 0.

Gibt es irgend eine andere Möglichkeit den angezeigten Pfad zur Laufzeit zu ändern?
Nein, InitialDir tut das nur bevor der Dialog geöffnet wurde.

Grüße
TurboMagic

[KodeZwerg]

Wenn ich Dich richtig verstehe, möchtest Du die Winapi überlisten, so das nicht eines der zuletzt besuchten Ordner sondern ein von Dir bestimmter geöffnet wird, korrekt?

Dies kannst Du erreichen indem Du den Filter justierst, "LW:\Pfad\*.ext" sollte funktionieren.

[venice2]

sorry vergiß es.

[Uwe Raabe]

In der Regel verwendet der TOpenDialog einen Fall-Forward zu dem neuen TFileOpenDialog, der seit Vista verfügbar ist. In den meisten Fällen kann man diesen TFileOpenDialog anstatt des alten TOpenDialog verwenden.

Netterweise hat TFileOpenDialog ein Dialog-Property auf das verwendete IFileDialog-Interface (eigentlich IFileOpenDialog) und somit dessen SetFolder Methode. Diese erwartet zwar ein IShellItem als Parameter, aber das kannst du dir analog zu der Implementierung für DefaultFolder in TCustomFileDialog.Execute besorgen.

[himitsu]

Ich kann jetzt nicht helfen, aber dir den Grund sagen, warum es (vermtulich) nicht geht.

Der TOpenDialog nutzt seit paar Jahren/Delphiversionen im aktuellen Windows (versionsabhängig) intern den TFileOpenDialog (Vista-Dialog), welcher mit einer anderen API arbeitet.
Ich würde empfehlen direkt TFileOpenDialog zu nutzen, da du so einen besseren Zugriff auf die interne Implementation hast. (außer du mußt immernoch XP und davor unterstüzen)

[edit] Man, bin ich langsam.

[TiGü]

Disclaimer: Die Lösung verwendet diesen Ansatz: https://stackoverflow.com/questions/...16715#36716715.
Mein Beispielcode basiert auf Delphi Sydney, in früheren oder späteren Versionen kann die Anzahl der privaten Felder vor allen für TCustomFileDialog und TOpenDialog abweichen und muss dementsprechend angepasst werden.

Gegeben sei eine Form mit TOpenDialog und Button:

Delphi-Quellcode:

implementation

{$R *.dfm}

uses
  Winapi.ShlObj;

procedure TForm3.Button1Click(Sender: TObject);
begin
  OpenDialog1.Execute(Self.Handle);
end;

type
  TFileDialogWrapperHack = class(TObject)
  protected
    FFileDialog: TCustomFileDialog;
  end;

  TCustomFileDialogHack = class(TComponent)
  private
    FClientGuid: string;
    FDefaultExtension: string;
    FDefaultFolder: string;
    FDialog: IFileDialog;
  end;

  TOpenDialogHack = class(TCommonDialog)
  private
    FHistoryList: TStrings;
    FOptions: TOpenOptions;
    FFilter: string;
    FFilterIndex: Integer;
    FCurrentFilterIndex: Integer;
    FInitialDir: string;
    FTitle: string;
    FDefaultExt: string;
    FFileName: TFileName;
    FFiles: TStrings;
    FFileEditStyle: TFileEditStyle;
    FOnSelectionChange: TNotifyEvent;
    FOnFolderChange: TNotifyEvent;
    FOnTypeChange: TNotifyEvent;
    FOnCanClose: TCloseQueryEvent;
    FOnIncludeItem: TIncludeItemEvent;
    FOptionsEx: TOpenOptionsEx;
    FInternalWrapper: TObject;
  end;

  TOpenDialogHelper = class helper for TOpenDialog
    procedure SetDefaultFolder(const ADefaultFolder: string);
  end;

procedure TOpenDialogHelper.SetDefaultFolder(const ADefaultFolder: string);
var
  FileDialogWrapper: TFileDialogWrapperHack;
  CustomFileDialog: TCustomFileDialog;
  FileDialog: IFileDialog;
  ShellItem: IShellItem;
  HR: HRESULT;
begin
  FileDialogWrapper := TFileDialogWrapperHack(TOpenDialogHack(Self).FInternalWrapper);
  if Assigned(FileDialogWrapper) then
  begin
    CustomFileDialog := FileDialogWrapper.FFileDialog;
    if Assigned(CustomFileDialog) then
    begin
      FileDialog := TCustomFileDialogHack(CustomFileDialog).FDialog;
      if Assigned(FileDialog) then
      begin
        HR := SHCreateItemFromParsingName(PWideChar(ADefaultFolder), nil, IShellItem, ShellItem);
        if Succeeded(HR) then
          FileDialog.SetFolder(ShellItem);
      end;
    end;
  end;
end;

procedure TForm3.OpenDialog1TypeChange(Sender: TObject);
begin
  if Sender is TOpenDialog then
  begin
    case TOpenDialog(Sender).FilterIndex of
      1:
        begin
          TOpenDialog(Sender).SetDefaultFolder('C:\Program Files');
        end;
      2:
        begin
          TOpenDialog(Sender).SetDefaultFolder('C:\Program Files (x86)');
        end;
    end;
  end;
end;

Wer seine Leser in den Wahnsinn treiben will, kann natürlich auch alles ein zwei Zeilen erschlagen:

Delphi-Quellcode:

procedure TOpenDialogHelper.SetDefaultFolder(const ADefaultFolder: string);
var
  ShellItem: IShellItem;
begin
  if Succeeded(SHCreateItemFromParsingName(PWideChar(ADefaultFolder), nil, IShellItem, ShellItem)) then
    TCustomFileDialogHack(TFileDialogWrapperHack(TOpenDialogHack(Self).FInternalWrapper).FFileDialog).FDialog.SetFolder(ShellItem);
end;

[TiGü]

Ansonsten mach dir das Leben einfach und mach das was Uwe sagt.
Dann würde sich das so vereinfachen und aussehen mit einem TFileOpenDialog:

Delphi-Quellcode:

procedure TForm3.FileOpenDialog1TypeChange(Sender: TObject);
var
  ShellItem: IShellItem;
  HR: HRESULT;
  NewDefaultFolder: string;
begin
  if Sender is TFileOpenDialog then
  begin
    case TFileOpenDialog(Sender).FileTypeIndex of
      1:
        begin
          NewDefaultFolder := 'C:\Program Files';
        end;
      2:
        begin
          NewDefaultFolder := 'C:\Program Files (x86)';
        end;
    end;
    HR := SHCreateItemFromParsingName(PWideChar(NewDefaultFolder), nil, IShellItem, ShellItem);
    if Succeeded(HR) then
      TFileOpenDialog(Sender).Dialog.SetFolder(ShellItem);
  end;
end;

[TurboMagic]

Danke für alle die Infos.
Muss ich mal bald probieren.

Frage: wär's dann nicht mahl an der Zeit, wenn Delphi den TOpenDialog
auf die Nutzung der neueren Variante umstellen würde und die neuen Funktionen
dann nach außen führen würde oder evtl. über ein Property auswählbar ob der neue oder die alte
Variante intern zum Einsatz kommt?

[TiGü]

Zitat von TurboMagic:

Frage: wär's dann nicht mahl an der Zeit, wenn Delphi den TOpenDialog
auf die Nutzung der neueren Variante umstellen würde

Tut er doch?
Setz dir mal einen Breakpoint in Vcl.Dialogs.TFileOpenDialogWrapper.CreateFileDialo g.

Code:

Vcl.Dialogs.TFileOpenDialogWrapper.CreateFileDialog
Vcl.Dialogs.TFileDialogWrapper.Create(???)
:00579b95 TFileOpenDialogWrapper.CreateFileDialog + $11
Vcl.Dialogs.TOpenDialog.Execute(???)

Delphi-Quellcode:

function TFileOpenDialogWrapper.CreateFileDialog: TCustomFileDialog;
begin
  Result := TFileOpenDialog.Create(nil);
  Result.OnExecute := OnExecuteEvent;
end;

[TurboMagic]

Ich habe jetzt diese Variante erfolgreich kurz ausprobiert und ich denke ich baue diese sobald ich dazu komme ein:

Zitat von TiGü:

Disclaimer: Die Lösung verwendet diesen Ansatz: https://stackoverflow.com/questions/...16715#36716715.
Mein Beispielcode basiert auf Delphi Sydney, in früheren oder späteren Versionen kann die Anzahl der privaten Felder vor allen für TCustomFileDialog und TOpenDialog abweichen und muss dementsprechend angepasst werden.

Gegeben sei eine Form mit TOpenDialog und Button:

Delphi-Quellcode:

...

procedure TOpenDialogHelper.SetDefaultFolder(const ADefaultFolder: string);
var
  FileDialogWrapper: TFileDialogWrapperHack;
  CustomFileDialog: TCustomFileDialog;
  FileDialog: IFileDialog;
  ShellItem: IShellItem;
  HR: HRESULT;
begin
  FileDialogWrapper := TFileDialogWrapperHack(TOpenDialogHack(Self).FInternalWrapper);
  if Assigned(FileDialogWrapper) then
  begin
    CustomFileDialog := FileDialogWrapper.FFileDialog;
    if Assigned(CustomFileDialog) then
    begin
      FileDialog := TCustomFileDialogHack(CustomFileDialog).FDialog;
      if Assigned(FileDialog) then
      begin
        HR := SHCreateItemFromParsingName(PWideChar(ADefaultFolder), nil, IShellItem, ShellItem);
        if Succeeded(HR) then
          FileDialog.SetFolder(ShellItem);
      end;
    end;
  end;
end;

...

Es wäre halt schön, wenn die Komponente sowas in Zukunft einfacher machen würde...

Danke nochmal

TurboMagic