TZipFile und TMemoryStream

[Willie1]

Hallo Delphi-Freunde*innen,
ich bin noch mit TZipFile zu Gange Ihr (Himitsu u.a.) hattet mir schon im letzten Sommer erklärt, dass ich eine Datei aus einem Zip-Archiv ohne den Umweg über die Festplatte Virtuell öffnen kann. Jetzt will ich das lernen.
Ich habe mir das Folgende überlegt:

Delphi-Quellcode:

procedure TForm1.Button7Click(Sender: TObject);
var
  ms: TMemoryStream;
  Data: TBytes;
  ss: string;
  i: Integer;
begin
  if fod.Execute then begin
    ms := TMemoryStream.Create;
    try
      ms.LoadFromFile(fod.FileName);
      MyZip.Open(ms, zmRead);
      MyZip.Read(0, Data);  //Index 0 erste Datei im Archiv
    finally
      ms.Free;
    end;
    ss := '';
    for i:=Low(Data) to High(Data) do
      ss := ss + Chr(Data[i]);
    Memo1.Text := ss;
    MyZip.Close;
  end;
end;

hier mit einem Textfile. Ist das der richtige Weg? Index liefert die lfd. Nr. aus dem Archiv.
Kalte Grüße Willie.

[Uwe Raabe]

Ist die Textdatei ANSI-codiert? Dann kannst du die Umwandlung in einen String vereinfachen (falls es ein anderes Encoding ist natürlich auch):

Delphi-Quellcode:

procedure TForm1.Button7Click(Sender: TObject);
var
  ms: TMemoryStream;
  Data: TBytes;
  ss: string;
begin
  if fod.Execute then begin
    ms := TMemoryStream.Create;
    try
      ms.LoadFromFile(fod.FileName);
      MyZip.Open(ms, zmRead);
      MyZip.Read(0, Data); //Index 0 erste Datei im Archiv
      MyZip.Close;
    finally
      ms.Free;
    end;
    ss := TEncoding.ANSI.GetString(Data);
    Memo1.Text := ss;
  end;
end;

[Willie1]

Hallo,
das klappt tatsächlich.
Aber es geht um was anderes, ich habe TFileZip Auspacken mit TMemoryStream gelernt. Zum Testen setze ich ein Textfile von Delphi ein. Ich freue mich, dass dies jetzt funktioniert.
In der Realität will ich ein zweidimensionales Array of Record aus der gepackten Datei einlesen. Das ist mit Read(..,TByte) (für mich) schwierig. Wie muss ich vorgehen?

[Uwe Raabe]

Es gibt ja auch Read-Overloads, die Streams unterstützen.

Zitat von Willie1:

In der Realität will ich ein zweidimensionales Array of Record aus der gepackten Datei einlesen.

Wie würdest du es denn mit einem TMemoryStream machen?

[himitsu]

TMemoryStream gibt uns einen Zeiger auf seinen interen Speicher
TCustomMemoryStream.Memory
und man kann somit auch direkt zugreifen/casten.



Mit einer Text-Datei:

Für TEncoding muß man beim TMemoryStream erst nach TBytes kopieren (System.Move oder Stream.Write), bzw. man nutze einfach TBytesStream.Bytes,
aber man könnte auch SetString oder MultiByteToWideChar nutzen.

Oder wie wäre es mit TStringStream.DataString?

[Willie1]

Zitat von Uwe Raabe:

Es gibt ja auch Read-Overloads, die Streams unterstützen.

Wie würdest du es denn mit einem TMemoryStream machen?

Die gespeicherten Daten sehen so aus (vereinfacht): TFussballMatrix: Array[0..17,0..17] of Record Eg: string[3]; Spt: Byte; end; Es ist 2932 Bytes groß.

Ca 100 dieser Dateien sind in dem Zip-Archiv gespeichert und ich will sie öffnen, ohne sie auf der Platte (zwischen)speichern zu müssen. Ich möchte lernen, wie es geht. Den Umweg über den ext. Speicher weiß ich.
W.

[himitsu]

Wenn es ein reine statische Daten (z.B. StaticArray/Record/ShortString) sind, dann kann man das als Pointer auch direkt auf den MemoryStream.Memory casten.
PFussballMatrix

[Uwe Raabe]

Zitat von Willie1:

Ca 100 dieser Dateien sind in dem Zip-Archiv gespeichert und ich will sie öffnen, ohne sie auf der Platte (zwischen)speichern zu müssen.

Eventuell so:

Delphi-Quellcode:

var
  header: TZipHeader;
  matrix: TFussballMatrix;
  MyZip: TZipFile;
  stream: TStream;
begin
  ...
  MyZip.Read(0, stream, header);
  try
    stream.Read(matrix, Sizeof(matrix));
  finally
    stream.Free;
  end;
  ...

[himitsu]

Delphi-Quellcode:

var
  stream: TMemoryStream;
begin
  ...
  stream := TMemoryStream.Create;
  try
    MyZip.Read(0, stream, header);

    xxx := PFussballMatrix(stream.Memory)^[x, y].Eg;

  finally
    stream.Free;
  end;

[edit]
Ohh, der TZipFile erstellt den Stream selber?

Da müsste man mal schauen was der innen ist und beim TMemoryStream kann, man dann in Ruhe casten.

Delphi-Quellcode:

var
  stream: TStream;
begin
  ...
  MyZip.Read(0, stream, header);
  try

    xxx := PFussballMatrix((stream as TMemoryStream).Memory)^[x, y].Eg;

  finally
    stream.Free;
  end;

Ansonsten doch nochmal umkopieren, siehe Uwe.

[edit2]
Schade, ist ein TZDecompressionStream/TCustomZStream, da geht das mit dem Cast nicht direkt.

[Uwe Raabe]

Zitat von himitsu:

Schade, ist ein TZDecompressionStream/TCustomZStream, da geht das mit dem Cast nicht direkt.

Das war doch zu erwarten. Schließlich liegt die Datei im Zip ja in komprimierter Form vor.