Image.Picture.SaveToStream in ein Datenbankfeld

[NoGAD]

Huhu.

Mit folgendem Code versuche ich ein Stream aus einem TImage in ein Graphic - Feld einer Datenbank zu schreiben. Es scjeint, als wäre der Stream leer, da beim Lesen des Feldes immer eine Fehlermeldung erzeugt wird.

Code für das Schreiben:

Delphi-Quellcode:

var
  BlobStream: TStream;
  PictureStream: TStream;
begin
    PictureStream := TMemoryStream.Create;
    Image1.Picture.SaveToStream(PictureStream);
    BlobStream :Table1.CreateBlobStream(Table1.FieldByName('Thumbnail'), bmWrite);
    BlobStream.Write(PictureStream, PictureStream.SIZE);
    BlobStream.Free;
    PictureStream.Free;
end;

Code für das Auslesen:

Delphi-Quellcode:

var
  JpegImage: TJPEGImage;
  BlobStream: TStream;
begin
  BlobStream := Table1.CreateBlobStream(Table1.FieldByName('Thumbnail'), bmRead);
  JpegImage := TJPEGImage.Create;
  JpegImage.LoadFromStream(BlobStream);  // <--- Hier wird eine Exception ausgelöst, BlobStrem ist () (leer?)
  Image1.Picture.Assign(JpegImage);
  Image1.Visible := True;
  JpegImage.Free;
  BlobStream.Free;
end;

Ist der Fehler beim Schreiben oder beim Lesen zu suchen?

LG Mathias

[DeddyH]

Was passiert, wenn Du beim Schreiben statt

Delphi-Quellcode:

// Alt
BlobStream.Write(PictureStream, PictureStream.SIZE);

das hier verwendest?

Delphi-Quellcode:

// Neu
BlobStream.CopyFrom(PictureStream, 0);

[Uwe Raabe]

Du musst nach dem SaveToStream den PictureStream wieder auf den Anfang setzen. Außerdem ist Write nicht der richtige Weg, sondern CopyFrom (wie Detlef schon bemerkt hat).

[Uwe Raabe]

Außerdem kannst du dir den Umweg über PictureStream ganz sparen:

Delphi-Quellcode:

  BlobStream := Table1.CreateBlobStream(Table1.FieldByName('Thumbnail'), bmWrite);
  try
    Image1.Picture.SaveToStream(BlobStream);
  finally
    BlobStream.Free;
  end;

[himitsu]

Oder direkt ein TDBImage?

Früher konnte das nur TBitmap, aber da Picture.LoadFromStream inzwischen die MagicBytes erkennt und danach entscheiden kann, kann TImage/TDBImage auch alle anderen bekannten TGraphic-Ableger aus Stream laden/anzeigen. (ohne dass man manuell den passenden GraphicTypen erstellt)

[NoGAD]

Zitat von Uwe Raabe:

Außerdem kannst du dir den Umweg über PictureStream ganz sparen:

Delphi-Quellcode:

  BlobStream := Table1.CreateBlobStream(Table1.FieldByName('Thumbnail'), bmWrite);
  try
    Image1.Picture.SaveToStream(BlobStream);
  finally
    BlobStream.Free;
  end;

Das klappt perfekt. Vielen 1000 Dank!

Zitat von himitsu:

Oder direkt ein TDBImage?

Früher konnte das nur TBitmap, aber da Picture.LoadFromStream inzwischen die MagicBytes erkennt und danach entscheiden kann, kann TImage/TDBImage auch alle anderen bekannten TGraphic-Ableger laden/anzeigen.

Und auf so einfache Dinge komme ich immer nicht. Dir auch ganz vielen Dank!

Ihr seid toll!

LG Mathias

[NoGAD]

Hallo nochmal,

ich muss den Thread bitte nochmal ausgraben.



Durch eine Änderung klappt der Code nicht mehr. Als Fehlermeldung wird mir immer angezeigt, dass ein Tabellenfeld einen Wert haben muss.
Dieses Feld ist tatsächlich mit NOT NULL definiert.

Aber eigentlich sollte folgender Code einen Inhalt im Tabellenfeld erzeugen:

Delphi-Quellcode:

//  { Tabelle für Bilder }
    { Tabellenname } TableName: 'table_thumbnail';
    { SQL Tabelle für die Bilder }
    SQL: 'CREATE TABLE table_thumbnail(id AUTOINC NOT NULL MINVALUE 0,' +
    ' thumbnail_picture GRAPHIC BLOBBlockSize 102400 BLOBCompressionAlgorithm BZIP BLOBCompressionMode 9 NOT NULL,' +
    ' thumbnail_sha512 VARCHAR(255))';


// MyABSTable ist ein Record


var
  FileStream: TFileStream;
  BlobStream: TStream;
  Dummy_String_SHA512: String;
  Dummy_Bool_SHA512: Boolean;
begin

  { :: Bild hinzufügen / bearbeiten - }
  if OpenPictureDialog1.Execute then
  begin
    try
      FileStream := TFileStream.Create(OpenPictureDialog1.FileName, fmOpenRead or fmShareDenyNone);
      Dummy_String_SHA512 := GetStreamToHashSHA256Hex(FileStream);
      Dummy_Bool_SHA512 := MyABSTable.atable_construct[4].Table.Locate(MyABSTable.atable_construct[4].FieldNames[2], Dummy_String_SHA512, []);
      case Dummy_Bool_SHA512 of
        True: { benötige ich nicht, ist nur für meine Lesbarkeit }
          ; 
        False:
          begin
            MyABSTable.atable_construct[4].Table.Insert;
            BlobStream := MyABSTable.atable_construct[4].Table.CreateBlobStream(MyABSTable.atable_construct[4].Table.FieldByName(MyABSTable.atable_construct[4].FieldNames[1]), bmWrite);
            BlobStream.Seek(0, soFromBeginning);
            BlobStream.CopyFrom(FileStream, FileStream.Size); // mit ,0); wird es auch nicht besser
            MyABSTable.atable_construct[4].Table.FieldByName(MyABSTable.atable_construct[4].FieldNames[2]).AsString := Dummy_String_SHA512;
            MyABSTable.atable_construct[4].Table.Post; // HIER knallt immer eine Exception rein, mit der Meldung: Feld 'xyz' muss einen Wert haben
            // Feld 'xyz' ist definitiv mein Blob Field
          end;
      end;
      if assigned(FileStream) then
        FileStream.Free;
      if assigned(BlobStream) then
        BlobStream.Free;
      MyABSTable.atable_construct[0].Table.Edit;
      MyABSTable.atable_construct[0].Table.FieldByName(MyABSTable.atable_construct[0].FieldNames[13]).AsInteger := MyABSTable.atable_construct[4].Table.RecNo;
      MyABSTable.atable_construct[0].Table.Post;

      ABSTable1AfterScroll(MyABSTable.atable_construct[0].Table);
    except
      MyABSTable.atable_construct[4].Table.Cancel;
      MyABSTable.atable_construct[0].Table.Cancel;
    end;
  end;
  { - Bild hinzufügen / bearbeiten :: }

Erkennt jemand eventuell, warum das Grafikfeld (Blob) angeblich leer sein soll?



Edit: Nachdem ich den Code umgestellt habe und die Streams direkt nach der Zuweisung wieder freigebe, ist das Datenbankfeld wieder gefüllt.
Sehr eigenartig, aber es klappt nun wieder.

Delphi-Quellcode:

{..}
                BlobStream.CopyFrom(FileStream, FileStream.Size);
// ab hier
                if assigned(FileStream) then
                  FileStream.Free;
                if assigned(BlobStream) then
                  BlobStream.Free;
// bis hier hatte gefehlt
                MyABSTable.atable_construct[4].Table.FieldByName(MyABSTable.atable_construct[4].FieldNames[2]).AsString := Dummy_String_SHA512;
                MyABSTable.atable_construct[4].Table.Post;
{..}

LG Mathias