Json unbekanntes feld abfangen

[venice2]

zur zeit wird der Channel auf diese weise eingelesen.

Delphi-Quellcode:

  // Ignore: '{"channel_groups":'
  // a channel-definition begins with "display_alias": "
  PosNext := PosEx('"display_alias"', Data, 1);  // get begin of first channel
  id := 0;
  n := 0;
//Log('UPDCHL', 'LEN: ' + inttostr(length(data)));
  while (PosNext > 0) do
  begin
//LOG('UPDCHL', '------------------------');
    inc(PosNext, 1);
    inc(n);
    Application.ProcessMessages;
    // --- Read all values in order of apperance:
    // "display_alias" - NOZ USED                        // 1)
    sha := GetBool(posnext, Data, '"sharing": ');          // 2)
    rad := GetBool(posnext, Data, '"is_radio": ');         // 3)
    tit := GetStr(PosNext, Data, '"title": "', '"');     // 4)
    tit := DecodeJString(tit);
    cid := GetStr(posnext, Data, '"cid": "', '"');       // 5)
//Log('UPDCHL', inttostr(PosNext) + ' | CID: ' + cid);
    num := GetStr(PosNext, Data, '"number": ',',');      // 6)
//Log('UPDCHL', inttostr(PosNext) + ' | ZatNum: ' + num + ' | RecNum: ' + inttostr(n));
    // Here: ... EPG-NEXT  7)
    rec := GetBool(posnext, Data, '"recording": ');      // 8)
    // --- Check if Channel already exists:
    x := GetChlbyCID(1, cid, ChlRec);
    if (x < 0) then
    begin
      // NOT FOUND !!! New ChlRec
      New(ChlRec);                          // create a new record:
      id := FCHLList.Add(ChlRec);
//Log('UPDCHL', 'New ChlRec: '); // + inttostr(id +1) + ' - ' +booltostr(rad, true));
      CHLrec.SortNum   := -1;
      CHLrec.QSelect   := -1;     // no Quality-Rec selected
      // ----- DYNAMIC-DATA -----
      ChlRec.Qualy     := TList.Create;
      CHLrec.EPG       := TList.Create;
    end;
//    else
//      Log('UPDCHL', '********** CHL AVAILABLE: ' + booltostr(ChlRec.Is_Radio, true));
    // --- Set values new:
    ChlRec.Sharing   := sha;
    ChlRec.Is_Radio  := rad;
    StrLCopy(CHLrec.Title, PAnsiChar(tit), High(ChLrec.Title) - 1);
    StrLCopy(CHLrec.CID, PAnsiChar(cid), High(CHLrec.CID) - 1);
    ChlRec.Num       := StrToInt(num);
    ChlRec.Recording := rec;
    // --- check CHANNEL-QUALITIES:
    // Section "qualities" will / must be present
    // we should have min. 1 (SD) , mostly 2 (HD+SD), more ?
    // TRICKY: first read "recommendations" for max. loop-position !
    posrem:= PosEx('"recommendations"', Data, posnext);   // REMAIN "JUMP"
    numQRec := -1;
    // --- Clear QRecs if available:
    for i := 1 to ChlRec.Qualy.Count do
      Dispose(PChlQualyRec(ChlRec.Qualy[i - 1]));
    ChlRec.Qualy.Clear;
    // --- Read QRecs new
    s := GetStr(posnext, Data, '"stream_types": [', '],'); // get first qualy-data
    while (PosNext > 0) AND (PosRem > PosNext) do
    begin
      inc(numQrec);
      New(QRec);                                                      // 10)
      ChlRec.Qualy.Add(QRec);
      FillChar(QRec^, sizeof(TChlQualyRec), 0);
      // title - UNUSED HERE
      QRec.stream_types := GetSTreamTypes(s);
      QRec.level := 0;     // default undefined
      s := GetStr(posnext, Data, '"level": "', '",');
      if (s = 'hd') then QRec.level := 2;
      if (s = 'sd') then QRec.level := 1;
      s := GetStr(posnext, Data, '"logo_token": "', '",');
      StrLCopy(QRec.logo_token , PAnsiChar(s), High(QRec.logo_token) - 1);
      s := GetStr(posnext, Data, '"availability": "', '"');
      QRec.available := (s = 'available');
      inc(PosNext, 5);  // jump over last bracketsm komma & spaces !
//LOG('UPDCHL', '--- Q' + inttostr(numQRec) + ' - avail: ' + booltostr(QRec.available, true) +
//               ' | level: ' + inttostr(QRec.level));
      // ----- Check if selectable:
      if (ChlRec.QSelect < 0) then
        if QRec.available then ChlRec.QSelect := ChlRec.Qualy.Count - 1;
      s := GetStr(posnext, Data, '"stream_types": [', '],'); // get next qualy-data
    end;
//LOG('UPDCHL', '--- selected: ' + inttostr(ChlRec.QSelect));
    PosNext := PosRem;  // !!! ... because PosNext is in range of next channel !
    // Ignore: "recommendations"                                      // 11)
    // Here: ... EPG-Now  7)
    // Ignore: "id": "ard",                                           // 13)
    // Ignore: "aliases": ["daserste"]                                // 14)
    // IGNORE: FAV-block
    PosNext := PosEx('"display_alias"', Data, PosNext);  // // get begin of next channel
  end;

Wie man sehen kann ist das sehr aufwendig und es ist nicht immer garantiert das diese art des Parsen zum gewünschten erfolg führt.
Meine frage daher wie kann ich das mit mORMot Json Parser umsetzen?
Sollte das funktionieren sollen mir die 280 KB egal sein.

Kenne das Framework nicht und ellenlange Englische Seiten zu lesen ist nicht mein Ding.

EDIT:
Dann kann ich
ShowMessage(docPrograms.S['g'].ToCSV);
In D2010 nicht übergeben so wie man im Shot sehen kann. (Ist nur ein String nicht gesplittet)

Zitat:

[DCC Error] Unit1.pas(125): E2018 Record, object or class type required

[mytbo]

Ich habe das jetzt nur mal schnell überflogen. So sollte es aber funktionieren. Wenn du heute Abend (Nacht) noch ein Problem damit hast, sage einfach bescheid. Ich schaue mir das dann gerne mal an.

Delphi-Quellcode:

var
  iRun, nRun: Integer;
  doc: TDocVariantData;
  docChannelGroup: PDocVariantData;
  docChannels: PDocVariantData;
begin
  doc.InitJSONFromFile('Channels_data.json', JSON_OPTIONS_FAST_EXTENDED);
  if not doc.B['success'] then Exit; //=>

  for iRun := 0 to doc.A['channel_groups'].Count - 1 do
  begin
    docChannelGroup := doc.A['channel_groups']._[iRun];
    for nRun := 0 to docChannelGroup.A['channels'].Count - 1 do
    begin
      docChannels := docChannelGroup.A['channels']._[nRun];
      ShowMessage(docChannels.S['display_alias']);
      ShowMessage(docChannels.I['number'].ToString);
    end;
  end;

Bis bald...
Thomas

[venice2]

Zitat:

Wenn du heute Abend (Nacht) noch ein Problem damit hast, sage einfach bescheid. Ich schaue mir das dann gerne mal an.

Das ist nett von dir werde es mal implementieren.
Danke schön.

Hmm.. Ich glaube wir haben uns nicht richtig verstanden.
Dein Schnipsel gibt mir die Value von display_alias zurück.
Das ist aber nicht was ich wollte.

Mein bestreben ist in der Json nach 'display_alias' zu suchen und darauf hin den Count auszulegen.
display_alias kommt 172 mal in der Json vor diese und die nachfolgenden Einträge muss ich parsen bis zum nächsten 'display_alias'
und so lange bis er halt nicht mehr vorkommt.

Also nicht auf docChannels sondern auf
docChannels.S['display_alias']

Es gibt ja nur diese möglichkeiten..
docChannels.SearchItemByProp
docChannels.SearchItemByValue

aber beides führte nicht zum gewünschten Ergebnis.

PS:
EPG ist fertig und funktioniert soweit.
Nun muss ich nur noch die Channels erfolgreich rüberbringen.

so geht es nicht..

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
type
  TChannelsData = record
    display_alias: string;
    sharing: BOOL;
    is_radio: BOOL;
    title: string;
    cid: string;
    number: LongInt;
    recording: BOOL;
    success: BOOL;
  end;
var
  iRun, i, nRun: Integer;
  doc: TDocVariantData;
  docChannelGroup: PDocVariantData;
  docChannels: PDocVariantData;
  x: TRawUtf8DynArray;
  gChannels: array of TChannelsData;
begin
  doc.InitJSONFromFile('Channels_data.json', JSON_OPTIONS_FAST_EXTENDED);
  if not doc.B['success'] then
    Exit; //=>

  for iRun := 0 to doc.A['channel_groups'].Count - 1 do
  begin
    docChannelGroup := doc.A['channel_groups']._[iRun];
    for nRun := 0 to docChannelGroup.A['channels'].Count - 1 do
    begin
      docChannels := docChannelGroup.A['channels']._[nRun];
      for i := 0 to docChannels.A['display_alias'].Count - 1 do // Wie komme ich an den Count und wie finde ich den nächsten Eintrag von 'display_alias'
      begin
        setLength(gChannels, i + 1);

        gChannels[i].display_alias := docChannels.S['display_alias'];
        gChannels[i].sharing := docChannels.B['sharing'];
        gChannels[i].is_radio := docChannels.B['is_radio'];
        gChannels[i].title := docChannels.S['title'];
        gChannels[i].cid := docChannels.S['cid'];
        gChannels[i].number := docChannels.I['number'];
        gChannels[i].recording := docChannels.B['recording'];
      end;
    end;
  end;
end;

[mytbo]

Ich habe deinen Post mehrmals durchgelesen, aber so ganz genau weis ich immer noch nicht, welche Infos dir fehlen.

Zitat von venice2:

Mein bestreben ist in der Json nach 'display_alias' zu suchen und darauf hin den Count auszulegen.
display_alias kommt 172 mal in der Json vor diese und die nachfolgenden Einträge muss ich parsen bis zum nächsten 'display_alias'
und so lange bis er halt nicht mehr vorkommt.

"channels" ist ein Array. Mit meinem Beispiel durchlaufe ich alle Objekte dieses Arrays. docChannels zeigt auf das Object, das mit dem Index nRun gerade im Array ausgewählt ist.

Hier noch mal ein Beispiel. Zur Sicherheit gebe den vollständigen Pfad für die JSON-Datei ein.

Delphi-Quellcode:

var
  s: String;
  i: Integer;
  iRun, nRun: Integer;
  doc: TDocVariantData;
  docChannelGroup: PDocVariantData;
  docChannels: PDocVariantData;
begin
  doc.InitJSONFromFile('Channels_data.json', JSON_OPTIONS_FAST_EXTENDED);
  if not doc.B['success'] then Exit; //=>

  i := 0;
  for iRun := 0 to doc.A['channel_groups'].Count - 1 do
  begin
    docChannelGroup := doc.A['channel_groups']._[iRun];
    for nRun := 0 to docChannelGroup.A['channels'].Count - 1 do
    begin
      docChannels := docChannelGroup.A['channels']._[nRun];
      s := s + ' | ' + docChannels.S['display_alias'];
      Inc(i);
    end;
  end;

  ShowMessage(s);
  ShowMessage(i.ToString);
end;

Kleiner Hinweis: Lade die JSON-Datei in Notepad++. Hier kannst du Zweige ein- und ausklappen und die Struktur, ob es ein Objekt oder Array ist, sofort erkennen. Bei einem Array wendest du das oben gezeigt Schema zum Durchlaufen an und kopierst danach nur noch die Namen der Eigenschaften aus der JSON-Datei in die Zugriffsfunktionen.

Bis bald...
Thomas

[venice2]

ok dann nochmal

  PosNext := PosEx('"display_alias"', Data, 1); // get begin of first channel
Ist der erste Index vom Knoten "display_alias"

Dann kommt die schleife

while (PosNext > 0) do
die läuft jetzt solange durch bis "display_alias" nicht mehr gefunden wird.

Die letzte Zeile schaltet zum nächsten Index Knoten "display_alias"
 PosNext := PosEx('"display_alias"', Data, PosNext); // // get begin of next channel

Das ist was ich mit dem Parser nicht geregelt bekomme.

EDIT:
Ok du gibst jetzt alle "display_alias" aus.

Aber!
Der Rest zwischen dem nächsten "display_alias" der fehlt.
Verstehst du was ich meine?

Also du gehst auf das erste "display_alias" dann muss ich die nachfolgenden Einträge analysieren..

Delphi-Quellcode:

        gChannels[i].display_alias := docChannels.S['display_alias'];
        gChannels[i].sharing := docChannels.B['sharing'];
        gChannels[i].is_radio := docChannels.B['is_radio'];
        gChannels[i].title := docChannels.S['title'];
        gChannels[i].cid := docChannels.S['cid'];
        gChannels[i].number := docChannels.I['number'];
        gChannels[i].recording := docChannels.B['recording'];

und erst dann auf das nächste "display_alias" springen. .hier lese ich dann wieder die nachfolgenden variablen ein bis zum nächste "display_alias"
Da habe ich meine probleme mit. Verstehe das Framework noch nicht so richtig.

Danke für die Hilfe

[venice2]

Hmm das scheint es zu sein.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
type
  TChannelsData = record
    display_alias: string;
    sharing: BOOL;
    is_radio: BOOL;
    title: string;
    cid: string;
    number: LongInt;
    recording: BOOL;
    success: BOOL;
  end;
var
  s: String;
  i: Integer;
  iRun, nRun: Integer;
  doc: TDocVariantData;
  docChannelGroup: PDocVariantData;
  docChannels: PDocVariantData;
  gChannels: array of TChannelsData;
begin
  doc.InitJSONFromFile('Channels_data.json', JSON_OPTIONS_FAST_EXTENDED);
  if not doc.B['success'] then 
    Exit;

  i := 0;
  for iRun := 0 to doc.A['channel_groups'].Count - 1 do
  begin
    docChannelGroup := doc.A['channel_groups']._[iRun];
    for nRun := 0 to docChannelGroup.A['channels'].Count - 1 do
    begin
      docChannels := docChannelGroup.A['channels']._[nRun];
      setLength(gChannels, i + 1);

      gChannels[i].display_alias := docChannels.S['display_alias'];
      gChannels[i].sharing := docChannels.B['sharing'];
      gChannels[i].is_radio := docChannels.B['is_radio'];
      gChannels[i].title := docChannels.S['title'];
      gChannels[i].cid := docChannels.S['cid'];
      gChannels[i].number := docChannels.I['number'];
      gChannels[i].recording := docChannels.B['recording'];

      Inc(i);
    end;
  end;

  ShowMessage(IntToStr(i));
end;

Nochmals Danke

[mytbo]

Wenn du auch die Werte für das qualities Array benötigst, dann einfach das obere Schema für den Zugriff auf Arrays verwenden. Es ist immer die Wiederholung des gleichen Schemas.

Bis bald...
Thomas

[venice2]

Zitat von mytbo:

Wenn du auch die Werte für das qualities Array benötigst, dann einfach das obere Schema für den Zugriff auf Arrays verwenden. Es ist immer die Wiederholung des gleichen Schemas.

Bis bald...
Thomas

werde es versuchen

[venice2]

Habe immer noch ein Problem mit den stream_types

Delphi-Quellcode:

const
  MAX_STREAM_TYPES = 7;

  TStreamTypes : array[0..MAX_STREAM_TYPES] of string =
  ( 'dash',              // 0    1          MPEG     VLC !
    'dash_playready',    // 1    2          MPEG
    'dash_widevine',     // 2    4          MPEG
    'hls',               // 3    8          APPLE    VLC & LAV !
    'hls7',              // 4    16         APPLE
    'hls7_fairplay',     // 5    32         APPLE
    'hds',               // 6    64         ADOBE    none
    'smooth_playready'   // 7    128        ?
  );

type
  PQualitiesData = ^TQualitiesData;
  TQualitiesData = packed record
    logo_black_84: string;
    title: string;
    stream_types: string;
    level: string;
    logo_white_42: string;
    logo_token: string;
    logo_black_42: string;
    logo_white_84: string;
    availability: string;
  end;

Wie übergebe ich jetzt die werte für stream_types aus der Json?

Delphi-Quellcode:

  i := 0;
  for iRun := 0 to doc.A['channel_groups'].Count - 1 do
  begin
    docChannelGroup := doc.A['channel_groups']._[iRun];

    for nRun := 0 to docChannelGroup.A['channels'].Count - 1 do
    begin
      // Channels
      docChannels := docChannelGroup.A['channels']._[nRun];

      setLength(gChannels, i + 1);

      gChannels[i].display_alias := docChannels.S['display_alias'];
      gChannels[i].sharing := docChannels.B['sharing'];
      gChannels[i].is_radio := docChannels.B['is_radio'];
      gChannels[i].title := docChannels.S['title'];
      gChannels[i].cid := docChannels.S['cid'];
      gChannels[i].number := docChannels.I['number'];
      gChannels[i].recording := docChannels.B['recording'];
      // Qualities
      docQualities := docChannels.A['qualities']._[xRun];
      SetLength(gQualities, Length(gQualities) + 1);

      gChannels[i].qualities.logo_black_84 := docqualities.S['logo_black_84'];
      gChannels[i].qualities.title := docqualities.S['title'];

//      gChannels[i].qualities.stream_types // Wie auswerten/ übergeben

      gChannels[i].qualities.level := docqualities.S['level'];
      gChannels[i].qualities.logo_white_42 := docqualities.S['logo_white_42'];
      gChannels[i].qualities.logo_token := docqualities.S['logo_token'];
      gChannels[i].qualities.logo_black_42 := docqualities.S['logo_black_42'];
      gChannels[i].qualities.logo_white_84 := docqualities.S['logo_white_84'];
      gChannels[i].qualities.availability := docqualities.S['availability'];

      Inc(i);
    end;
  end;

Das andere geht soweit.

EDIT:
Ich kann jetzt so vorgehen.
  gChannels[i].qualities.stream_types := docqualities.S['stream_types']; Dann bekomme ich aus der Json diese werte zurück.

Code:

"stream_types": [
   "dash",
   "dash_playready",
   "dash_widevine",
   "hls7",
   "hls7_fairplay"
],

Ist das so gedacht und korrekt?
Das wären dann die Typen die unterstütz werden? Richtig?

[mytbo]

Zitat von venice2:

EDIT:
Ich kann jetzt so vorgehen.
  gChannels[i].qualities.stream_types := docqualities.S['stream_types']; Dann bekomme ich aus der Json diese werte zurück.

Code:

"stream_types": [
   "dash",
   "dash_playready",
   "dash_widevine",
   "hls7",
   "hls7_fairplay"
],

Ist das so gedacht und korrekt?

Oder das Array als CSV so: docQualities.A['stream_types'].ToCSV

Bis bald...
Thomas