Procedure in Datenmodul (TIdHTTP Komponente)

[Jumpy]

dm:= TFrmDm.Create(FrmDm); Was ist FrmDm? Wie oft gibt es dein datenmodul?

[Delphi.Narium]

Da es die Variabel FrmDm für die Klasse TFrmDm gibt, hätte ich eher dashier erwartet:

Delphi-Quellcode:

procedure TEuropeanCentralBankCurrencyService.Timer1Timer(Sender: TObject);
begin
  WriteToLog('Timer1Timer','Start');
  FrmDm.doDownload(WEBSITE, outputFilePathName);
  WriteToLog('Timer1Timer','Finished');
  DoStop;
end;

Befremdlich finde ich auch, dass dm in der Timerprozedure erstellt und freigegeben wird, aber die Variabel dazu nicht in der Prozedure deklariert ist, sondern eine globale Variabel zu sein scheint.

Sehe ich das richtig?
dm:= TFrmDm.Create(FrmDm);
Damit wird ein Datenmodul dm vom Typ TFrmDm erstellt, dessen Owner ein Datenmodul vom Typ TFrmDm ist?

Das ist rekursionsverdächtig.

[haentschman]

Moin...

Zitat:

Jedoch komme ich nicht in die Funktion hinein und der Timer startet immer von neuem ohne etwas zu tun.

Fragen:
1. Wieso ein Timer?
2. Intervall des Timers?

Vermutung:
Der Intervall des Timers ist zu kurz. Das würde bedeuten, daß der Timer sich wieder selbst "aufruft" ('Timer startet immer von neuem')
Lösung in diesem Falle:
In Timer1Timer in der ersten Zeile den Timer deaktivieren und in der letzten Zeile wieder aktivieren.

PS: Besser auf den Timer verzichten.

[DaSchwoa]

Zitat von haentschman:

PS: Besser auf den Timer verzichten.

Niemals ohne meinen geliebten Timer

Das habe ich schon ein paar mal gehört das der Timer nicht die beste Lösung ist. Aber bis jetzt hat es immer funktioniert.
Das mit dem Intervall kann auch nicht das Problem sein, da ich es, wie oben erklärt, schon funktioniert hat. Jedoch ohne Aufruf der Prozedur sondern der Komponenten.

(Timer ist auf 1 Minute eingestellt... Das müsste reichen)

Aber ich versuche mit Enabled auf false während des Durchlaufes.

[DaSchwoa]

Danke an alle die mir geholfen haben. Mein Programm funktioniert jetzt.
Jedoch bin ich mir unsicher was falsch war . Ich vermute es hat was mit der rekursion was zu tun.

[DaSchwoa]

Hier ist mein Code... Vielleicht kann ihn wer gebrauchen :

Code:

nit main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.SvcMgr, Vcl.Dialogs,
  Vcl.ExtCtrls, DMUnit;

type
  TEuropeanCentralBankCurrencyService = class(TService)
    Timer1: TTimer;
    procedure ServiceAfterInstall(Sender: TService);
    procedure ServiceContinue(Sender: TService; var Continued: Boolean);
    procedure ServiceCreate(Sender: TObject);

    procedure WriteToLog(destination, Text: string);
    procedure ServiceExecute(Sender: TService);
    procedure ServicePause(Sender: TService; var Paused: Boolean);
    procedure ServiceStart(Sender: TService; var Started: Boolean);
    procedure ServiceStop(Sender: TService; var Stopped: Boolean);
    procedure Timer1Timer(Sender: TObject);
  private
    swLogFile: TStreamWriter;

    outputFileName, outputFilePath, outputFilePathName: String;

    currency: TStringList;

  const
    WEBSITE = 'https://www.ecb.europa.eu/stats/eurofxref/eurofxref-daily.xml';

  public
    function GetServiceController: TServiceController; override;
    { Public-Deklarationen }
  end;

var
  EuropeanCentralBankCurrencyService: TEuropeanCentralBankCurrencyService;

implementation

{$R *.dfm}
uses
  System.Win.Registry, System.ioutils;

procedure TEuropeanCentralBankCurrencyService.WriteToLog(destination: string; Text: string);
begin
  swLogFile.WriteLine('[' + DateTimeToStr(now) + '] ' + destination + ' schreibt: ' + text);
end;

procedure ServiceController(CtrlCode: DWord); stdcall;
begin
  EuropeanCentralBankCurrencyService.Controller(CtrlCode);
end;

function TEuropeanCentralBankCurrencyService.GetServiceController: TServiceController;
begin
  Result := ServiceController;
end;

procedure TEuropeanCentralBankCurrencyService.ServiceAfterInstall(Sender: TService);
var
  Reg: TRegistry;
begin
  Reg := TRegistry.Create(KEY_READ or KEY_WRITE);
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKey('\SYSTEM\CurrentControlSet\Services\' + name, false) then
    begin
      Reg.WriteString('Description', 'Dieses Service Synchronisiert die Daten European Central Bank');
      Reg.CloseKey;
    end;
  finally
    Reg.Free;
  end;
end;

procedure TEuropeanCentralBankCurrencyService.ServiceContinue(Sender: TService;var Continued: Boolean);
begin
  WriteToLog('ServiceContinue','Continued');
  Continued:= true;
end;

procedure TEuropeanCentralBankCurrencyService.ServiceCreate(Sender: TObject);
var
  ExePath, logFilePathName, logFileName, logFilePath: String;
begin
  //Übergebe den Pfad der Exe
  ExePath         := TPath.GetDirectoryName(GetModuleName(HInstance));

  //Namen der Dateien
  logFileName     := 'log_Service.txt';
  outputFileName  := 'currency.xls';

  //Weise dem ExePath den jeweiligen Ordner zu
  logFilePath     := TPath.Combine(exePath, 'logFile');
  outputFilePath     := TPath.Combine(exePath, 'OutputFile');

  //Füge zu den Pfaden, die Namen hinzu
  logFilePathName   := TPath.Combine(logFilePath, logFileName);
  outputFilePathName:= TPath.Combine(outputFilePath, outputFileName);

  //Erstelle Path wenn nicht existiert
  if not TDirectory.Exists(logFilePath) then
    TDirectory.CreateDirectory(logFilePath);
  if not TDirectory.Exists(outputFilePath) then
    TDirectory.CreateDirectory(outputFilePath);

  //Erstelle Log Stream Reader
  swLogFile := TStreamWriter.Create(TFileStream.Create(logFilePathName, fmCreate or fmShareDenyWrite));

  currency:= TStringList.Create;
end;

procedure TEuropeanCentralBankCurrencyService.ServiceExecute(Sender: TService);
begin
  while not Terminated do
  begin
    ServiceThread.ProcessRequests(false);
    TThread.Sleep(1000);
  end;
end;

procedure TEuropeanCentralBankCurrencyService.ServicePause(Sender: TService;
  var Paused: Boolean);
begin
  WriteToLog('ServicePause', 'Paused');
  Paused:= True;
end;

procedure TEuropeanCentralBankCurrencyService.ServiceStart(Sender: TService;
  var Started: Boolean);
begin
  WriteToLog('ServiceStart', 'Service Started');
  Started:= true;
  Timer1.Enabled:= true;
end;

procedure TEuropeanCentralBankCurrencyService.ServiceStop(Sender: TService;
  var Stopped: Boolean);
begin
  WriteToLog('ServiceStop','Stopped');
  Stopped:= true;
end;

procedure TEuropeanCentralBankCurrencyService.Timer1Timer(Sender: TObject);
begin
  WriteToLog('Timer1Timer','Start');
  FrmDm.doDownload(WEBSITE, outputFilePathName);
  WriteToLog('Timer1Timer','Finished');
end;

end.

Code:

unit DMUnit;

interface

uses
  System.SysUtils, System.Classes, IdIOHandler, IdIOHandlerSocket,
  IdIOHandlerStack, IdSSL, IdSSLOpenSSL, IdBaseComponent, IdComponent,
  IdTCPConnection, IdTCPClient, IdHTTP;

type
  TFrmDm = class(TDataModule)
    IdHTTP1: TIdHTTP;
    IdSSLIOHandlerSocketOpenSSL1: TIdSSLIOHandlerSocketOpenSSL;

    procedure WriteToLog(Destination, Text: String);
    procedure DataModuleCreate(Sender: TObject);
    procedure doDownload(Website, Outputfile: String);

  private
    swLogFile: TStreamWriter;
  public

  end;

var
  FrmDm: TFrmDm;

implementation
  uses System.ioutils;

{%CLASSGROUP 'Vcl.Controls.TControl'}

{$R *.dfm}

procedure TFrmDm.DataModuleCreate(Sender: TObject);
var
  ExePath, logFilePathName, logFileName, logFilePath: String;
begin
  //Übergebe den Pfad der Exe
  ExePath         := TPath.GetDirectoryName(GetModuleName(HInstance));

  //Namen der Dateien
  logFileName     := 'log_DM.txt';

  //Weise dem ExePath den jeweiligen Ordner zu
  logFilePath     := TPath.Combine(exePath, 'logFile');

  //Füge zu den Pfaden, die Namen hinzu
  logFilePathName := TPath.Combine(logFilePath, logFileName);

  //Erstelle Path wenn nicht existiert
  if not TDirectory.Exists(logFilePath) then
    TDirectory.CreateDirectory(logFilePath);

  //Erstelle Log Stream Reader
  swLogFile := TStreamWriter.Create(TFileStream.Create(logFilePathName, fmCreate or fmShareDenyWrite));
  WriteToLog('DataModuleCreate', 'Created');
end;

procedure TFrmDm.WriteToLog(destination: string; Text: string);
begin
  swLogFile.WriteLine('[' + DateTimeToStr(now) + '] ' + destination + ' schreibt: ' + text);
end;

procedure TFrmDm.doDownload(Website: string; Outputfile: string);
var
  ResponseStream: TFileStream;
begin
  WriteToLog('doDownload', 'Try to read');

  ResponseStream := TFileStream.Create(Outputfile, fmCreate);
  IdHTTP1.IOHandler:= IdSSLIOHandlerSocketOpenSSL1;
  IdHTTP1.HandleRedirects:= true;
  try
    IdHTTP1.Get(Website, ResponseStream);
   WriteToLog('Timer1Timer','HTTP-Status: ' + IntToStr(IdHTTP1.ResponseCode));
  finally
    ResponseStream.Free;
  end;
  WriteToLog('doDownload', 'Download abgeschlossen');
end;

end.

[DaSchwoa]

Zitat von Delphi.Narium:

Damit wird ein Datenmodul dm vom Typ TFrmDm erstellt, dessen Owner ein Datenmodul vom Typ TFrmDm ist?

Das ist rekursionsverdächtig.

Ja ich weiß. Anfangs hätte ich es versucht mit FrmDm.doDownload aber das hat auch nicht funktioniert. Ich komme aber einfach nicht in meine Procedure rein.

Nur wenn ich die einzelnen Komponenten von meinem Datenmodul einbinde geht es. (also mit FrmDm.IdHttp). Aber das muss doch auch schöner gehen

[Delphi.Narium]

Zitat von DaSchwoa:

Ich komme aber einfach nicht in meine Procedure rein.

Was heißt das?

Steht die Ausgabe von WriteToLog('Timer1Timer','Start'); nie in der Logdatei?
Oder steht es in der Logdatei, aber die Ausgabe von  WriteToLog('doDownload', 'Try to read'); fehlt?
Oder ...?

Irgendwie reichen Deine Informationen noch nicht aus, um sich eine konkrete Vorstellung des Problemes machen zu können.

Wäre es möglich den Quelltext des Projektes hier mal anzuhängen, einschließlich einer Logdatei, in der der Fehler nachzuvollziehen ist?