Connection übergeben verschiedene Datenbanken

[matashen]

Hallo zusammen,

ich habe für Datenbankzugriffe eine kleine Funktionssammlung

um verschiedene Connections anzusprechen hab ich bisher mehrere procedure geschrieben und per Overload parallel betrieben.

Ich möchte aber gern die prozeduren zusammenführen da diese sich nur unterschieden in der Art der Connection

z.B.

Delphi-Quellcode:

procedure MeinZugriff(eineVerbindung:TAdoConnection;irgendwas:String);
var myquery:TAdoQuery;
..
myquery:=TAdoQuery.create;
myquery.connection:=eineVerbindung;

procedure MeinZugriff(eineVerbindung:TFDConnection;irgendwas:String);
var myquery:TFDQuery;
..
myquery:=TFDQuery.create;
myquery.connection:=eineVerbindung;

was ich gern machen würde wär sowas wie

Delphi-Quellcode:

procedure MeinZugriff(eineVerbindung:TCustomConnection;irgendwas:String);
var myquery:????;
..
if eineVerbindung is TFDConnection then myquery:=????.
if eineVerbindung is TAdoConnection then myquery:=????.
createmyquery.connection:=eineVerbindung;

und bei den ???? weis ich nicht wie ich das anstellen soll.


Danke schon mal für Ideen.

[TiGü]

Delphi-Quellcode:

uses
  FireDAC.Stan.Intf, FireDAC.Stan.Option,
  FireDAC.Stan.Error, FireDAC.UI.Intf, FireDAC.Phys.Intf, FireDAC.Stan.Def,
  FireDAC.Stan.Pool, FireDAC.Stan.Async, FireDAC.Phys, FireDAC.VCLUI.Wait,
  Data.DB, FireDAC.Comp.Client, FireDAC.Stan.Param, FireDAC.DatS,
  FireDAC.DApt.Intf, FireDAC.DApt, FireDAC.Comp.DataSet, Data.Win.ADODB;

function CreateFDQuery(eineVerbindung:TCustomConnection): TFDQuery;
begin
  Result := TFDQuery.Create(nil);
  Result.Connection := eineVerbindung as TFDCustomConnection;
end;

function CreateADOQuery(eineVerbindung:TCustomConnection): TADOQuery;
begin
  Result := TADOQuery.Create(nil);
  Result.Connection := eineVerbindung as TADOConnection;
end;

procedure MeinZugriff(eineVerbindung:TCustomConnection;irgendwas:String);
var
  myquery: TDataset;
begin
  if eineVerbindung is TFDConnection then
    myquery := CreateFDQuery(eineVerbindung);
  if eineVerbindung is TADOConnection then
    myquery := CreateADOQuery(eineVerbindung);
end;

[matashen]

Hi Danke,

an TDataset hab ich auch schon gedacht aber wie führ ich dann mit dem Query ein SQL aus. TDataset enthält keine sql.text Eigenschaft

[Delphi.Narium]

Sowas in diese Richtung:

Delphi-Quellcode:

procedure OpenSQL(eineVerbindung : TCustomConnection; myQuery : TDataSet; sSQL : String);
begin
  myQuery.Close;
  if eineVerbindung is TFDConnection then begin
    TFDQuery(myQuery).SQL.Text := sSQL;
    TFDQuery(myQuery).Open;
  end else
  if eineVerbindung is TADOConnection then begin
    TADOQuery(myQuery).SQL.Text := sSQL;
    TADOQuery(myQuery).Open;
  end;
end;

oder:

Delphi-Quellcode:

procedure OpenSQL(myQuery : TDataSet; sSQL : String);
begin
  myQuery.Close;
  if myQuery is TFDQuery then begin
    TFDQuery(myQuery).SQL.Text := sSQL;
    TFDQuery(myQuery).Open;
  end else
  if myQuery is TADOQuery then begin
    TADOQuery(myQuery).SQL.Text := sSQL;
    TADOQuery(myQuery).Open;
  end;
end;

[matashen]

Hallo zusammen,

nochmal Danke

heut steh ich sowas von aufm Schlauch das ich besser den Rechner runter fahre und erstmal zur Eisdiele gehe.

[himitsu]

@Delphi.Narium

Woher willst du wissen, dass eineVerbindung und myQuery zusammenpassen?
Für den Cast der Query ist somit nur das Zweite richtig, welches die zugehörige Instanz prüft.

Das "MeinZugriff" ist natürlich die zentrale "CreateQuery"-Funktion.
Ob an das nun nochmal trennt oder zusammenwirft, ist jedem selbst überallassen.

Man kann auch mal schauen, denn so manche Connection-Klasse hat auch eine Create/Get-Query-Funktion eingebaut.
z.B. könnte man vom TFDCustomConnection.ExecSQL die Variante mit dem AResultSet benutzen.

Delphi-Quellcode:

function CreateQuery(Connection: TCustomConnection): TDataSet;  // oder ein gemeinsamer TIrgendwasQuery-Vorfahre
begin
  if Connection is TFDCustomConnection then begin
    Result := TFDQuery.Create(nil);
    TFDQuery(Result).Connection := TFDCustomConnection(Connection);
  end else if Connection is TADOConnection then begin
    Result := TADOQuery.Create(nil);
    TADOQuery(Result).Connection := TADOConnection(eineVerbindung);
  end else 
    raise Exception.Create('unbekannte Connection');
end;

Delphi-Quellcode:

function CreateQuery(Connection: TCustomConnection; SQL: string='' {; Params: TParams}): TDataSet;  // oder ein gemeinsamer TIrgendwasQuery-Vorfahre
begin
  Result := nil;
  try
    if Connection is TFDCustomConnection then begin
      Result := TFDQuery.Create(nil);
      TFDQuery(Result).Connection := TFDCustomConnection(Connection);
      if SQL <> '' then begin
        TFDQuery(myQuery).SQL.Text := SQL;
        //TFDQuery(myQuery).Params.Assign(Params);  // oder irgendwie sowas ... z.B. den Params-Parameter als "array of const" oder "array of Variant"
        TFDQuery(myQuery).Open;
      end    
    end else if Connection is TADOConnection then begin
      Result := TADOQuery.Create(nil);
      TADOQuery(Result).Connection := TADOConnection(eineVerbindung);
      if SQL <> '' then begin
        TADOQuery(myQuery).SQL.Text := SQL;
        TADOQuery(myQuery).Open;
      end;
    end else 
      raise Exception.Create('unbekannte Connection');
  except
    Result.Free;  // falls das Open knallte
    raise;
  end;
end;