Integer in Set laden

[DieDolly]

Dann verstehe ich euch tatsächlich nicht und verstehe auch grundsätzlich überhaupt nix mehr.

Wenn ich von Außen 57 lese dann bedeutet das Niveau 1, 4, 5 und 6 sind frei. 2 und 3 noch nicht.
Wie gestaltet sich dann die Abfrage?

Delphi-Quellcode:

if TNiveau.nB in NiveauInt then // das hier dürfe niemals zutreffen, da Niveau 2 (B) nicht freigeschaltet ist.
 Include(NiveauSet, TNiveau.nB);

Aber da oben wird doch im Prinzip geprüft, ob die 1 in der 57 ist. Denn Element nB ist das zweite Element im Set mit dem Wert 1.
Aber eigentlich müsste ich 2 abfragen.

Ok ich glaube das wars ich gebe auf. Ich brauche diese Zahlen weil ich sonst keine Ahnung habe wie ich prüfen kann was frei ist und was nicht.

[samso]

Ich kann mich nur wiederholen. Mein Programm leistet exakt das, was Du möchtest. Teste es doch bitte bitte bitte mal!

Delphi-Quellcode:

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

type
 TNiveau = (Niveau1, Niveau2, Niveau3, Niveau4, Niveau5, Niveau6);
 TNiveauSet = set of TNiveau;

var
  Niveaus: TNiveauSet;
  N: TNiveau;
begin
  Niveaus := TNiveauSet(Byte(StrToInt('57'))); // Integer in das Set laden
  // Ausgabe welche Niveaus freigeschaltet sind
  for N:=Niveau1 to Niveau6 do
  begin
    if N in Niveaus then
      WriteLn(Format('Niveau %d ist freigeschaltet', [ord(N)+1]));
  end;
  ReadLn;
end.

[p80286]

Warum machst Du es nicht nach alter Väter Sitte

Delphi-Quellcode:

funktion Bit0set(wert:byte)_boolean;
begin
result:=((wert and 1) =1);
end;

funktion Bit1set(wert:byte):boolean;
begin
result:=((wert and 2) =2);
end;

usw.

Gruß
K-H

[Uwe Raabe]

Zitat von p80286:

Warum machst Du es nicht nach alter Väter Sitte

Ich hatte schon auf so was gewartet...

[p80286]

Zitat von Uwe Raabe:

Zitat von p80286:

Warum machst Du es nicht nach alter Väter Sitte

Ich hatte schon auf so was gewartet...

Na dann erzähl mal.
Ich hab bisher den Eindruck, daß der Einsatz eines Sets nicht eben intuitiv ist.


Gruß
K-H

[Uwe Raabe]

Zitat von p80286:

Ich hab bisher den Eindruck, daß der Einsatz eines Sets nicht eben intuitiv ist.

Ist er eigentlich schon - und besser lesbar auch. Wie jedes programmtechnische Konstrukt muss man es halt beherrschen. Das unterscheidet die Sets nicht von Pointern, Arrays, Records, Strings oder Klassen - von Generics, Threads und Anonymen Methoden ganz zu schweigen. Der ASM-Verweis hatte schon seine Berechtigung. Damit lässt sich all das auch nach alter Väter Sitte realisieren. Ist aber vielleicht nicht erstrebenswert.

[Michael II]

Hallo Dolly

gib nicht auf .

Die Vorschläge sind ja alle mehr als brauchbar.

Hier noch ein paar Funktionen, welche nützlich sein könnten...

allefaelle zählt alle möglichen Fälle (0..63) auf
niv_in_n prüft, ob ein Niveau im "Fall" n enthalten ist

niv_str wandelt ein Element in einen String um
nivset_str wandelt eine Menge in einen String um

Delphi-Quellcode:

uses System.TypInfo;


type
TNiveau = (nA, nB, nC, nD, nE, nF);
TNiveauSet = set of TNiveau;

function getNiveauSet( n : byte ) : TNiveauSet;
begin
 (*
  alle fälle aufzählen:
  Result := [];
  if n and 1 = 1 then Result := Result + [nA];
  if n and 2 = 2 then Result := Result + [nB];
  if n and 4 = 4 then Result := Result + [nC];
  if n and 8 = 8 then Result := Result + [nD];
  if n and 16 = 16 then Result := Result + [nE];
  if n and 32 = 32 then Result := Result + [nF];
   *)
  // oder einfacher so:
  Result := TNiveauSet( n );
end;

function niv_str( niv : TNiveau ) : string;
begin
  Result := GetEnumName(typeinfo(TNiveau),ord(niv));
end;

function nivset_str( nivset : TNiveauSet ) : string;
var niv : TNiveau;
begin
  Result := '';
  for niv := nA to nF do
    if niv in nivset then
      Result := Result + niv_str( niv ) + ' ';
end;

function niv_in_n( niv : TNiveau; n : byte ) : boolean;
begin
  Result := niv in getNiveauSet( n );
end;

function fallnummer( n : byte ) : string;
var nivset : TNiveauSet;
begin
  nivset := getNiveauSet( n );
  Result := nivset_str( nivset );
end;

function allefaelle : string;
var
  i: Integer;
  hs : string;
begin
  hs := '';
  for i := 0 to 63 do
      hs := hs + i.ToString + ' ' + fallnummer( i ) + #13#10;
  Result := hs;
end;


procedure TForm1.Button1Click(Sender: TObject);
begin
  showmessage(allefaelle);
end;

[samso]

In dem Augenblick in dem die Zahl in ein Set übertragen wurde, muss man gedanklich die Welt der Zahlen verlassen und in die Welt der Mengenlehre eintauchen. Hier wird nicht mehr mit Zahlen hantiert, sondern mit Elementbeziehungen. Das hier behandelte Beispiel ist geradezu ein Musterbeispiel für eine Menge. Die Menge der freigeschalteten Niveaus. Wenn die einzelnen Niveaus (Elemente der Menge) dann auch noch sinnvolle Namen bekommen, bildet die Programmiersprache wunderbar anschaulich ab was der Programmierer eigentlich will. Das ist dann fast schon Umgangssprache und genau das macht die Sache dann auch so sexy.

Richtig ist, dass die Zuweisung

Code:

Niveaus := TNiveauSet(Byte(StrToInt('57')));

nicht der reinen Lehre entspricht, weil diese Zuweisung implementationsabhängig ist. Sauberer wäre diese Formulierung:

Delphi-Quellcode:

function IntegerToNiveauSet(NiveauInt: Integer): NiveauSet;
var
  N: TNiveau;
  z: Integer;
begin
  z := 1;
  Result := [];
  for N := Low(TNiveau) to High(TNiveau) do
  begin
    if z and NiveauInt<>0 then
      include(Result, N);
    z := z * 2;
  end;
end;

Die Zuweisung lautet dann
Niveaus := IntegerToNiveauSet(StrToInt('57'));

[samso]

Zitat von DieDolly:

Dann verstehe ich euch tatsächlich nicht und verstehe auch grundsätzlich überhaupt nix mehr.

Wenn ich von Außen 57 lese dann bedeutet das Niveau 1, 4, 5 und 6 sind frei. 2 und 3 noch nicht.
Wie gestaltet sich dann die Abfrage?

Delphi-Quellcode:

if TNiveau.nB in NiveauInt then // das hier dürfe niemals zutreffen, da Niveau 2 (B) nicht freigeschaltet ist.
 Include(NiveauSet, TNiveau.nB);

Aber da oben wird doch im Prinzip geprüft, ob die 1 in der 57 ist. Denn Element nB ist das zweite Element im Set mit dem Wert 1.
Aber eigentlich müsste ich 2 abfragen.

Ok ich glaube das wars ich gebe auf. Ich brauche diese Zahlen weil ich sonst keine Ahnung habe wie ich prüfen kann was frei ist und was nicht.

Man kann das natürlich auch ohne Sets umsetzen. Dann bekommt man auch die 32 zu sehen...

Delphi-Quellcode:

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

var
  Niveaus: Integer;
  i: Integer;
  N: Integer;
begin
  Niveaus := StrToInt('57');
  N := 1;
  for i := 1 to 6 do
  begin
    if N and Niveaus<>0 then
      WriteLn(Format('Niveau %d ist freigeschaltet', [i]));
    N := N * 2;
  end;
  ReadLn;
end.

Gerne liefere ich das auch in Assembler...

[samso]

Zitat von DieDolly:

Aber da oben wird doch im Prinzip geprüft, ob die 1 in der 57 ist.

Und das stimmt eben nicht! Da wird geprüft ob nB in der Menge NiveauInt enthalten ist. Hier bildet Pascal/Delphi die Mengenlehre nach.