AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Thema durchsuchen
Ansicht
Themen-Optionen

Sortieren eines Arrays of String

Ein Thema von DonPedroFo · begonnen am 8. Jul 2019 · letzter Beitrag vom 23. Jul 2019
Antwort Antwort
Der schöne Günther

Registriert seit: 6. Mär 2013
6.196 Beiträge
 
Delphi 10 Seattle Enterprise
 
#1

AW: Sortieren eines Arrays of String

  Alt 8. Jul 2019, 10:11
Ich finde das alles etwas zu kompliziert. TArray.Sort(..) aus System.Generics.Collections bietet dir alles um ein Array zu sortieren wie du magst. Die Adresse und andere Dinge lassen sich prächtig mit regulären Ausdrucken (System.RegularExpressions ) auslesen.

Hier ein Beispiel dass deine Strings der Adresse nach sortiert ausgibt:

Delphi-Quellcode:
program Project1;

{$APPTYPE CONSOLE}
{$R *.res}

uses
   System.SysUtils,
   System.Generics.Collections,
   System.Generics.Defaults,
   System.RegularExpressions;

type
   TAddress = Word;

   function getAddress(const line: String): TAddress;
   const
      pattern = '^S(\d)(\d){2}((\d){4}).*FF';
   var
      match: TMatch;
   begin
      match := TRegEx.Match(line, pattern);
      Result := TAddress.Parse(match.Groups[3].Value);
   end;

   procedure printLines(const lines: TArray<String>); inline;
   var
      line: String;
   begin
      for line in lines do
         WriteLn(line);
    end;

procedure p();
var
   lines: TArray<String>;
   sortByAddress: IComparer<String>;
begin
   lines := [
      'S10011223344556677889900AABBCCDDEEFF', // Adresse "1122"
      'S10010223344556677889900AABBCCDDEEFF', // Adresse "1022"
      'S10014223344556677889900AABBCCDDEEFF'  // Adresse "1422"
   ];

   sortByAddress :=
      TComparer<String>.Construct(
         function(const left, right: String): Integer
         begin
            Result := getAddress(left) - getAddress(right);
         end
      );

   TArray.Sort<String>(lines, sortByAddress);
   printLines(lines);
end;

begin
   p();
   readln;
end.
  Mit Zitat antworten Zitat
Antwort Antwort

 

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 20:18 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz