Spezieller TFrame

[hzzm]

Zitat von peterbelow:

Du kannst deiner Frame-Basisclasses durchaus einen Konstruktor verpassen, der neben dem Owner: TComponent noch einen weiteren Parameter für das zu verwendende Icon hat. Du mußt Dir nur klar darüber sein, dass dieser Konstruktor nur verwendet wird, wenn Du eine Frame-Instanz per Kode erzeugst und deinen Konstruktor explizit aufrufst. Wenn Du eine Instanz im Designer auf ein Form knallst wird unweigerlich der Standard TComponent-Konstruktor (oder dessen override) verwendet, da kannst Du nur ebenfalls im Designer das Icon laden oder halt in einer geeigneten Form-Methode zuweisen. So ein Icon fällt nicht vom Himmel, wenn Du die gleiche Frame-Klasse je nach Anwendung mit verschiedenen Icons verwenden willst geht nur auf eine der vorstehend genannten Wege.

Wenn Du allerdings einen festen Satz von Icons hast gibt es noch eine andere Möglichkeit. Da könntest Du der Basisklasse eine TImagelist mit dem vollen Satz der Icons verpassen, einen enumerated Type mit entsprechend vielen Elementen definieren, dem Frame eine published property dieses Typs mit einer Settermethode verpassen, und diese dann das gewünschte Icon aus der Imagelist in das Icon-TImage kopieren lassen.

Der Konstruktor meiner "neuen" Frame-Klasse ist mir egal, der braucht kein Icon und gar nichts.
Die Idee ist, einen TMyBaseFrame in der IDE zu erstellen, der eine Member/Feldvariable Icon: TImage hat. Von dem will ich Frames ableiten (programmatisch erstellen), die leicht anders aufgebaut sind, aber auch immer ein Icon: TImage haben. Ueber die Klasse TMyBaseFrame sollte somit im code klar sein, dass sie immer dieses TMyBaseFrame.Icon: TImage; beinhaelt. Denn dann kann ich einfach generell bei so einem Frame auf

Code:

TMyCoolFrame = class(TMyBaseFrame)
...
AMyCoolFrame := TMyCoolFrame.Create(AOwner);
AMyCoolFrame.Icon := TImage(Whatever);

zugreifen.

Wenn ich also wie man es normal vermuten wuerde, einfach eine neue Klasse von TFrame ableite und ein Member Icon hinzufuege, war nicht moeglich, in der IDE im Code TMyCoolFrame = class(TFrame) abzuaendern in TMyCoolFrame = class(TMyBaseFrame), so dass bekannt ist, dass ein Icon enthalten ist und gleichzeitig trotzdem das Editieren des TFrame im FormEditor moeglich ist (F12).

Kurz gesagt wie in Post 1 geschrieben.
"war nicht moeglich", weil ich es mittlerweile geschafft habe. Was fuer ein Teufelsritt, ich weiss gar nicht, warum die IDE sich da so scheut

[Rollo62]

Als Gedankenanstoß:

Du könntest auch ein Interface dazunehmen, und so dein TFrame zwingen entsprechende Felder und Routinen anzulegen.

TMyCoolFrame = class(TFrame, IMyCoolFrame) Das funktioniert dann auch im Designer wie gewohnt,
aber ich denke du möchtest von der Basisklasse ableiten eben um dir das Anlegen in jedem Frame zu sparen.

[Der schöne Günther]

Nur wenn man auf Zugriffsverletzungen und ähnliches steht.

Nie Interface- und TObject-basierte Referenzierung mischen

[Schokohase]

Zitat von Der schöne Günther:

Nur wenn man auf Zugriffsverletzungen und ähnliches steht.

Nie Interface- und TObject-basierte Referenzierung mischen

So ein Unsinn ... in diesem Fall ist das genauso gefährlich als wenn ich die TFrame-Instanz direkt übergebe.

Das Problem, auf welches du dich beziehst ist dort, wo die Referenzzählung die Instanz aus dem Speicher kicken kann, da sollte man nur noch per Interface auf die Instanz zugreifen.

[hzzm]

Zitat von Der schöne Günther:

Nur wenn man auf Zugriffsverletzungen und ähnliches steht.

Nie Interface- und TObject-basierte Referenzierung mischen

Soweit ich das verstanden habe, kriegst Du das Problem nur, wenn Du von TInterfacedObject erbst. Sonst findet keine Referenzgezaehlte Destruktion statt.

[Rollo62]

Zitat von Der schöne Günther:

Nur wenn man auf Zugriffsverletzungen und ähnliches steht.

Nie Interface- und TObject-basierte Referenzierung mischen

Das mache ich auch nicht, und habe keinerlei Probleme damit.
Der Zugriff ist dann natürlich ausschliesslich über Interfaces.

[Schokohase]

Was geht ist folgendes:

Wir erstellen uns manuell eine Ableitung von TFrame :

Delphi-Quellcode:

unit CustomFrameApp.Frames.MyBaseFrame;

interface

uses
  Vcl.ExtCtrls,
  Vcl.Forms;

type
  TMyBaseFrame = class(TFrame)
  private
    FIcon: TImage;
  published
    property Icon: TImage read FIcon write FIcon;
  end;

implementation

end.

Dann erstellen wir uns ein neues TFrame wie gehabt und verändern den Source leicht:

Delphi-Quellcode:

unit CustomFrameApp.Frames.MyFrame;

interface

uses
  Winapi.Windows,
  Winapi.Messages,
  System.SysUtils,
  System.Variants,
  System.Classes,
  Vcl.Graphics,
  Vcl.Controls,
  Vcl.Forms,
  Vcl.Dialogs,
  // die Unit mit dem Vorgänger-Frame
  CustomFrameApp.Frames.MyBaseFrame;

// Umbiegen der Klasse TFrame auf die gewünschte Klasse
type
  TFrame = CustomFrameApp.Frames.MyBaseFrame.TMyBaseFrame;

type
  TMyFrame = class(TFrame)
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

implementation

{$R *.dfm}

end.

[hzzm]

Zitat von Schokohase:

Delphi-Quellcode:

// Umbiegen der Klasse TFrame auf die gewünschte Klasse
type
  TFrame = CustomFrameApp.Frames.MyBaseFrame.TMyBaseFrame;

Interessant, und der FormDesigner bei F12 frisst das Teil dann trotzdem wie gewohnt?
Muss ich mal testen. Mein Loesungsweg war dann doch ne Ecke umstaendlicher...

[Schokohase]

Das Problem ist, dass die IDE nach dem Namen der Vorgänger-Klasse schaut, wenn der Vorgänger keine DFM Datei hat.

Wenn dann der Name der Vorgänger-Klasse <> TFrame dann wird das Dingen wie ein TForm behandelt. Das ist das ganze Geheimnis.

Auf das gleiche Problem trifft man übrigens auch bei TDataModule (aber wahrscheinlich seltener, weil man da nicht so viel ableitet).

[Rollo62]

Zitat von hzzm:

Zitat von Schokohase:

Delphi-Quellcode:

// Umbiegen der Klasse TFrame auf die gewünschte Klasse
type
  TFrame = CustomFrameApp.Frames.MyBaseFrame.TMyBaseFrame;

Hallo Schokohase,

ja, das ist eine super Lösung.
Ich benutze das "Umbiegen" in ähnlicher Form an einigen Stellen.

Ich frage mich wie das "Umbiegen" als Fachbegriff heisst, weil ich nenne das für mich manchmal Unit-Forwarding.

Hat diese Methode vielleicht einen klaren Namen ?