TCP connect an definiertem Host und Port mit wählbaren Timeouts

[Sherlock]

Nachdem das hier https://www.delphipraxis.net/198916-...-moeglich.html so toll geklappt hat. Die nächste Frage:

In meinem verteilten Client/Server System möchte ich frühzeitig und schnell erkennen, ob ein Server eventuell nicht läuft. Dazu habe ich ihn früher einfach angepingt. Ab iOS und ab bestimmten Windowsversionen ist das nicht mehr ohne weiteres möglich, weshalb ich auf dieses kleine "Wunderwerk" kam, das bei der Gelegenheit auch den Service (über den Port) direkt prüft:

Delphi-Quellcode:

function TKommunikation.DoPing(const AHostName: string; const APort: Word): Boolean;
var
  tcp: TIdTCPClient;
begin
  tcp := TIdTCPClient.Create;
  try
    tcp.Host := AHostName;
    tcp.Port := APort;
    tcp.ReadTimeout := 10; // Should be unused by this particular method here
    tcp.ConnectTimeout := fTimeout_ms;
    try
      tcp.Connect;
      tcp.Disconnect;
      Result := True; // Success
    except
      on E: Exception do
      begin
        Result := False;
      end;
    end;
  finally
    tcp.Free;
  end;
end;

Schlüssel ist der wählbare Timeout, der relativ kurz gesetzt werden kann, da sich die Server im lokalen Netz befinden und schnell Verbindungen zulassen.

Meine Bestrebungen sind bekanntlich, die Indys zu eliminieren. Ich stieß auf http://docwiki.embarcadero.com/Libra...tem.Net.Socket was ein Schritt in die richtige Richtung schien, aber mir fehlen die Möglichkeiten zum Setzen von TimeOuts. Ist das die richtige Komponente, oder was ist aus System.Net besser geeignet?

Sherlock

[Der schöne Günther]

Ich finde vorheriges Pingen sinnlos. Du willst dich doch sowieso verbinden. Dann tu es doch und wenn es nicht klappt, dann klappte es nicht. 10 ms sind auch sehr sportlich. Ein ARP-Request oder gar DNS-Lookup kann das schon locker auffressen.

Auch: Die Entscheidung wie lange ein Timeout ist scheint Sache des Betriebssystems zu sein:
https://serverfault.com/q/193160

[Sherlock]

Das Problem an der Stelle war, daß die reguläre Verbindung über die die Delphi-SOAP Schnittstelle erfolgt. Da ist mir das Setzen eines Verbindungs-Timeouts nicht möglich, bzw. nicht bekannt, wo das zu setzen ist. Darum habe ich diesen Fake-Ping vorgelagert, der wunderbar funktioniert, nur halt leider mit den Indys.

Sherlock

[TiGü]

Hilft dir das weiter?

Delphi-Quellcode:

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}


uses
  System.SysUtils,
  System.Net.HttpClient;

function IsOnline(const ARemoteAddress: string): Boolean;
var
  HttpClient: THTTPClient;
  HttpResponse: IHTTPResponse;
begin
  Result := False;
  HttpResponse := nil;

  HttpClient := THTTPClient.Create;
  try
    try
      // Hier wird der TimeOut gesetzt!
      HttpClient.ConnectionTimeout := 5000;

      HttpResponse := HttpClient.Get(ARemoteAddress);
      if Assigned(HttpResponse) then
      begin
        // andere StatusCodes können ebenso gültig sein, entsprechend anpassen!
        Result := (HttpResponse.StatusCode = 200) and
          (HttpResponse.ContentStream.Size > 512); // in Byte. Passenden Wert einsetzen!
      end;
    except
      on E: Exception do
      begin
        Result := False;
      end;
    end;
  finally
    HttpClient.Free;
  end;
end;

begin
  try
    // siehe hier: https://www.predic8.de/soap/blz-webservice.htm

    // Beispielaufruf. Hier wird auf die Existenz der WSDL geprüft.
    Writeln(IsOnline('http://www.thomas-bayer.com/axis2/services/BLZService?wsdl'));

    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;

end.

[Sherlock]

Danke sehr! Ich schau mal, wie sich das anfühlt. Muss halt noch einen von http abweichenden Port eintragen können, aber das sollte in der Adresse an sich gehen.

Sherlock