Automatic installation of DPKs

[alpha04]

Thanks for the batch file. I can similarly add to install Lockbox3 modifying the value of the key Computer\HKEY_CURRENT_USER\Software\Embarcadero\BD S\19.0\Library\Win64\SearchPath.

However, what more needs to be done for installing Component "Microsoft ActiveX Data Objects"?
Should I create a new package for the same and make a similar batch file?

Zitat von GPRSNerd:

I do that with the help of a batch script:

Code:

CALL "C:\Program Files (x86)\Embarcadero\Studio\20.0\bin\rsvars.bat"
ECHO %BDS%
ECHO %BDSCOMMONDIR%
SET BPLREG="HKEY_CURRENT_USER\Software\Embarcadero\BDS\20.0\Known Packages"
ECHO %BPLREG%
SET BPLPATH="%BDSCOMMONDIR%\Bpl"
ECHO %BPLPATH%
ECHO ================================================================================

rem MPHexEditor
ECHO MPHexEditor...
ECHO   MPHexEditor
msbuild ".\MPHexEditor\Packages\MPHexEditor.dproj" /t:Build /p:Configuration=Release /p:platform=Win32
IF NOT %ERRORLEVEL%==0 GOTO ERROR
ECHO   MPHexEditorDsgn
msbuild ".\MPHexEditor\Packages\MPHexEditorDsgn.dproj" /t:Build /p:Configuration=Release /p:platform=Win32
IF NOT %ERRORLEVEL%==0 GOTO ERROR
reg delete %BPLREG% /v "%BPLPATH%\MPHexEditorDsgn.bpl" /f >NUL 2>&1
reg add    %BPLREG% /v "%BPLPATH%\MPHexEditorDsgn.bpl" /t REG_SZ /d "MP HexEditor Designtime" >NUL

rem PNGComponents
ECHO PNGComponents...
ECHO   PngComponents
msbuild ".\PngComponents\PackagesRio\PngComponents.dproj" /t:Build /p:Configuration=Release /p:platform=Win32
IF NOT %ERRORLEVEL%==0 GOTO ERROR
ECHO   PngComponentsDesign
msbuild ".\PngComponents\PackagesRio\PngComponentsDesign.dproj" /t:Build /p:Configuration=Release /p:platform=Win32
IF NOT %ERRORLEVEL%==0 GOTO ERROR
reg delete %BPLREG% /v "%BPLPATH%\PngComponentsDesign260.bpl" /f >NUL 2>&1
reg add    %BPLREG% /v "%BPLPATH%\PngComponentsDesign260.bpl" /t REG_SZ /d "Png Components Designtime" >NUL

...

GOTO DONE

:ERROR
ECHO ================================================================================
ECHO FEHLER aufgetreten! ERRORLEVEL = %ERRORLEVEL%
ECHO ================================================================================
PAUSE
GOTO END

:DONE
ECHO ================================================================================
ECHO Build erfolgreich!
ECHO ================================================================================
PAUSE

:END
SET BPLREG=
SET BPLPATH=

The packages are build with msbuild and "installed" into the IDE by setting the corresponding values in the registry.