Funktion Needle und Array übergeben - aber generisch

[DieDolly]

Ich zerbreche mir gerade verzweifelt den Kopf.

Ich möchte gerne eine Funktion haben die prüft, ob Needle in einem gegebenem Array vorhanden ist. Wenn nicht, soll 0 zurückgegeben werden.
Damit das aber wiederverwendbar ist, am besten generisch.

Aber das funktioniert wohl nicht so wie ich will, weil die Typen nicht kompatibel sind und die Vergleichsoperatoren nicht angewendet werden können.
Am besten wäre es natürlich, wenn Needle auch noch generisch wäre. Könnt ihr mir da bitte helfen?

Mein bisheriger Ansatz

Delphi-Quellcode:

// e.g. const IntArray: Array[0 .. 2] of Integer = (0, 1, 2);
// i := FindInArray<Integer, Integer>(1, IntArray);

function FindInArray<T1, T2>(const Needle: T1; var Arr: TArray<T2>): Integer;
var
 i: Integer;
begin
 Result := 0;

 for i := Low(Arr) to High(Arr) do
  begin
   if Needle = Arr[i] then
    begin
     Result := Needle;
     Break;
    end;
  end;
end;

Ich brauche nicht den Index. ich überprüfe einfach nur, ob Needle in Array ist. Wenn nicht, soll 0 zurück kommen.

[Der schöne Günther]

Richtig, Vergleichsoperatoren sind nicht auf allen Typen definiert, deshalb geht es nicht. Der Ausweg steckt in der Unit System.Generics.Defaults . Dort kannst du dann z.B. mittels TEqualityComparer<T>.Default() dir einen IEqualityComparator<T> holen der beliebige Typen auf Gleichheit prüft.


Habe grade kein Delphi in der Nähe, aber vielleicht hilft dir das schon weiter?


PS: Warum hast du eigentlich zwei generische Typen? Entweder ist es für mich noch zu früh am Morgen, oder so wird das nicht funktionieren.

[DieDolly]

Die Funktion soll am Ende so aufgebaut sein, dass Needle und Array von jeglichem Typ sein können und ich nur eine Funktion habe statt X überladene. Daher dachte ich direkt an Generics.
Vielleicht denke ich aber auch ganz falsch.

[Uwe Raabe]

Der Rückgabewert von 0 für nicht gefunden ist vielleicht etwas ungeschickt, da er nicht von der erfolgreichen Suche nach dem ersten Elements unterschieden werden kann. Besser wäre es da wie anderswo auch eine -1 zurückzugeben.

Ich würde das analog aufbauen wie TArray.BinarySearch aus System.Generics.Collection:

Delphi-Quellcode:

interface

uses
  System.Generics.Default;

type
  TMyArray = class
  public
    class function IndexOf<T>(const Values: array of T; const Item: T): Integer; overload; static;
    class function IndexOf<T>(const Values: array of T; const Item: T; const Comparer: IEqualityComparer<T>): Integer; overload;
        static;
    class function IndexOf<T>(const Values: array of T; const Item: T; const Comparer: IEqualityComparer<T>; Index, Count:
        Integer): Integer; overload; static;
  end;

implementation

uses
  System.RtlConsts;

class function TMyArray.IndexOf<T>(const Values: array of T; const Item: T): Integer;
begin
  Result := IndexOf<T>(Values, Item, TEqualityComparer<T>.Default,
    Low(Values), Length(Values));
end;

class function TMyArray.IndexOf<T>(const Values: array of T; const Item: T; const Comparer: IEqualityComparer<T>): Integer;
begin
  Result := IndexOf<T>(Values, Item, Comparer,
    Low(Values), Length(Values));
end;

class function TMyArray.IndexOf<T>(const Values: array of T; const Item: T; const Comparer: IEqualityComparer<T>; Index, Count:
    Integer): Integer;
var
  I: Integer;
begin
  if (Index < Low(Values)) or ((Index > High(Values)) and (Count > 0))
    or (Index + Count - 1 > High(Values)) or (Count < 0)
    or (Index + Count < 0) then
    raise EArgumentOutOfRangeException.CreateRes(@SArgumentOutOfRange);

  Result := -1;
  for I := Index to Index + Count - 1 do begin
    if Comparer.Equals(Values[I], Item) then
      Exit(I);
  end;
end;

[gammatester]

Zitat von Uwe Raabe:

Der Rückgabewert von 0 für nicht gefunden ist vielleicht etwas ungeschickt, da er nicht von der erfolgreichen Suche nach dem ersten Elements unterschieden werden kann. Besser wäre es da wie anderswo auch eine -1 zurückzugeben.

Das wäre nicht wesentlich geschickter, da ja auch -1 im Array vorhanden sein kann. Es wird ja nicht der Index des übereinstimmenden Wertes geliefert, der darüber hinaus noch nicht mal eindeutig sein muß.

[TiGü]

Da braucht man nicht mal einen Compiler, um zu sehen, dass dies nicht kompiliert .
Mach aus T1 und T2 ein einzigen Parameter T und als Rückgabewert Boolean. True für gefunden und fertig.
Beachte auch die Hinweise auf den Comparer. Wenn dir das unklar ist, frag bitte nach.

[Uwe Raabe]

Zitat von gammatester:

Es wird ja nicht der Index des übereinstimmenden Wertes geliefert, der darüber hinaus noch nicht mal eindeutig sein muß.

Ja, jetzt sehe ich es auch.

Wäre in dem Fall nicht ein Boolean als Rückgabewert geschickter? Im vorliegenden Fall würde ja auch eine 0 zurückkommen, wenn nach 0 gesucht wird, diese aber im Array nicht vorkommt.

[Delphi.Narium]

Die Funktion kann man nur als boolesche Funktion implementieren. Bei allem anderen numerischen besteht die Gefahr, dass der Rückgabewert 0 für nicht gefunden auch als Wert im Array vorkommen kann und damit der Rückgabewert der Funktion nicht korrekt ist.

Statt Boolean könnte man natürlich auch 0 für nicht gefunden und 1 für gefunden definieren (oder was man sonst noch eindeutig unterscheiden kann). Aber der Rückgabewert darf nicht ein Wert aus dem Array sein, der dem Rückgabewert für nicht gefunden entsprechen kann.

[DieDolly]

Die Lösung aus Nummer 4 gefällt mir schon ganz gut denn sie ist mit mehreren Datentypen verwendbar.
Aber leider lässt es sich nicht kompilieren. Die Fehlermeldung im ersten IndexOf lautet

Es gibt keine überladene Version von 'TMyArray.IndexOf<T>', die man mit diesen Argumenten aufrufen kann

[Uwe Raabe]

Zitat von DieDolly:

Die Lösung aus Nummer 4 gefällt mir schon ganz gut denn sie ist mit mehreren Datentypen verwendbar.
Aber leider lässt es sich nicht kompilieren. Die Fehlermeldung im ersten IndexOf lautet

Es gibt keine überladene Version von 'TMyArray.IndexOf<T>', die man mit diesen Argumenten aufrufen kann

Fixed! Es muss natürlich TEqualityComparer heißen.