Externes Programm zum durchsuchen von *.dfm Dateien und Speicherung von Actions

[Axti]

Okay ich hab mir den Ratschlag zu herzen genommen und das ganze mal gebastelt. Ich gehe jede Zeile der *.dfm durch und isoliere den TMainMenu block. Dieser wird dann in einer StringList TempMenuData gespeichert. Diese Liste gehe ich von oben bis unten für jede Datei durch und speicher dann entsprechend den Pfad. Am Ende gehe ich die fertige Tabelle durch und hänge an der entsprechenden Stelle der Action den Pfad dran. Zumindest sollte es so sein. Leider macht er nicht genau das sondern speichert nur den zuerst gefundenen Menüpunkt. Alle darauffolgenden nicht mehr. In dem Falle nur "Datei" und alle seine Items. Der nächste Menüpunkt wäre Bearbeiten. Diesen Block speichert er schon nicht mehr ab.

Delphi-Quellcode:

    for linePath in TempMenuData do
    begin
      if (MenuLevel = 1)
        and (TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('object')
        and  TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('TMenuItem'))
      then
      begin
        tempMenuTop := TempMenuData.Strings[TempMenuData.IndexOf(linePath)];
        tempMenuTop := tempMenuTop.Replace(' ', EmptyStr);
        tempMenuTop := tempMenuTop.Replace('object', EmptyStr);
        tempMenuTop := tempMenuTop.Replace(':TMenuItem', EmptyStr);

        MenuLevel := 2;
      end
      else if (MenuLevel = 2)
        and (TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('object')
        and  TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('TMenuItem'))
      then
      begin
        tempPath := tempMenuTop + '->' + TempMenuData.Strings[TempMenuData.IndexOf(linePath)];
        tempPath := tempPath.Replace(' ', EmptyStr);
        tempPath := tempPath.Replace('object', EmptyStr);
        tempPath := tempPath.Replace(':TMenuItem', EmptyStr);

        if TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1].Contains('Action') then
        begin
          tempMenuAction := TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1];
          tempMenuAction := tempMenuAction.Replace('Action = ', '');
          tempMenuAction := tempMenuAction.Replace(' ', '');
        end;

        MenuLevel := 3;
      end
      else if (MenuLevel = 3)
        and (TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('object')

        and  TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('TMenuItem'))
      then
      begin
        tempPath := tempPath + '->' + TempMenuData.Strings[TempMenuData.IndexOf(linePath)];
        tempPath := tempPath.Replace(' ', EmptyStr);
        tempPath := tempPath.Replace('object', EmptyStr);
        tempPath := tempPath.Replace(':TMenuItem', EmptyStr);

        if TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1].Contains('Action') then
        begin
          tempMenuAction := TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1];
          tempMenuAction := tempMenuAction.Replace('Action = ', '');
          tempMenuAction := tempMenuAction.Replace(' ', '');
        end;
      end;

      if not linePath.Contains('end') then
      begin
        for lineNewPath in FinishedTable do
        begin
          if FinishedTable[FinishedTable.IndexOf(lineNewPath)].Contains(tempMenuAction)
           and not FinishedTable[FinishedFile.IndexOf(lineNewPath)].Contains('Path')
          then
          begin
            FinishedTable.Strings[FinishedTable.IndexOf(lineNewPath)]
                := FinishedTable.Strings[FinishedTable.IndexOf(lineNewPath)] +
                   ' Path: ' + tempPath;
            break;
          end;
        end;
      end
      else if linePath.Contains('end') then
      begin
        MenuLevel := MenuLevel-1;
      end;

      if MenuLevel = 0 then
      begin
        tempPath := EmptyStr;
      end;

    end;

[freimatz]

Hallo,
ich habe zwar jetzt nicht so die Ahnung im konkreten Fall, aber weil seit einem Tag sich niemand gemeldet hat versuche ich mal zu helfen:
Wenn ich an einem Code bin der nicht funktioniert und nicht weiß warum, dann räume ich erst mal auf. Das könntes Du auch versuchen, vielleicht kommst Du vielleicht selber drauf oder kannst uns dann den präsentieren.
z.B:
1.
- am Anfang ein i:Integer; und ein line: string;
- dann statt "for linePath in TempMenuData do" ein "for i in TempMenuData do".
- zwei Zeilen später dann ein "line := TempMenuData.Strings[i]
- dann alle "TempMenuData.Strings[TempMenuData.IndexOf(linePath)]" durch "line" ersetzen
2.
- die jeweils drei Zeilen mit "tempMenuTop.Replace" in eine separate Methode verpacken (z.B. CleanMenItem und CleanAction)
3.
- das zweite "if linePath.Contains('end')" scheint mir überflüssig zu sein.
4.
- Kurze Zeilen mit if zusammenziehen

Dann wird übersichtlicher und Du oder wir sehen eher woran es hakt.

Ansonsten teile ich die Meinung von TigerLilly und meine eine zeilenweise Analyse ist in Deinem Fall zielführend. Für mich riecht es danach, also wäre das nur ein Tool firmenintern. Da einen Lexer oder mit binären DFM zu hantieren halte ich für übertrieben. (Ich gehe davon aus, dass jeder, der professionell Software entwickelt, dfm als Text speichert, weil man sonst Versionskontrolle nicht sinnvoll benutzen kann.)

[Axti]

Hab die Vorschläge jetzt ausprobiert und jetzt funktioniert alles super. Danke

[Dennis07]

Zitat von Axti:

Delphi-Quellcode:

    for linePath in TempMenuData do
    begin
      if (MenuLevel = 1)
        and (TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('object')
        and  TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('TMenuItem'))
      then
      begin
        tempMenuTop := TempMenuData.Strings[TempMenuData.IndexOf(linePath)];
        tempMenuTop := tempMenuTop.Replace(' ', EmptyStr);
        tempMenuTop := tempMenuTop.Replace('object', EmptyStr);
        tempMenuTop := tempMenuTop.Replace(':TMenuItem', EmptyStr);

        MenuLevel := 2;
      end
      else if (MenuLevel = 2)
        and (TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('object')
        and  TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('TMenuItem'))
      then
      begin
        tempPath := tempMenuTop + '->' + TempMenuData.Strings[TempMenuData.IndexOf(linePath)];
        tempPath := tempPath.Replace(' ', EmptyStr);
        tempPath := tempPath.Replace('object', EmptyStr);
        tempPath := tempPath.Replace(':TMenuItem', EmptyStr);

        if TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1].Contains('Action') then
        begin
          tempMenuAction := TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1];
          tempMenuAction := tempMenuAction.Replace('Action = ', '');
          tempMenuAction := tempMenuAction.Replace(' ', '');
        end;

        MenuLevel := 3;
      end
      else if (MenuLevel = 3)
        and (TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('object')

        and  TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('TMenuItem'))
      then
      begin
        tempPath := tempPath + '->' + TempMenuData.Strings[TempMenuData.IndexOf(linePath)];
        tempPath := tempPath.Replace(' ', EmptyStr);
        tempPath := tempPath.Replace('object', EmptyStr);
        tempPath := tempPath.Replace(':TMenuItem', EmptyStr);

        if TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1].Contains('Action') then
        begin
          tempMenuAction := TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1];
          tempMenuAction := tempMenuAction.Replace('Action = ', '');
          tempMenuAction := tempMenuAction.Replace(' ', '');
        end;
      end;

      if not linePath.Contains('end') then
      begin
        for lineNewPath in FinishedTable do
        begin
          if FinishedTable[FinishedTable.IndexOf(lineNewPath)].Contains(tempMenuAction)
           and not FinishedTable[FinishedFile.IndexOf(lineNewPath)].Contains('Path')
          then
          begin
            FinishedTable.Strings[FinishedTable.IndexOf(lineNewPath)]
                := FinishedTable.Strings[FinishedTable.IndexOf(lineNewPath)] +
                   ' Path: ' + tempPath;
            break;
          end;
        end;
      end
      else if linePath.Contains('end') then
      begin
        MenuLevel := MenuLevel-1;
      end;

      if MenuLevel = 0 then
      begin
        tempPath := EmptyStr;
      end;

    end;

So solltest du bei Parsern aber nicht arbeiten. StringReplace ist sehr unsicher, da du den Kontext nicht beachtest. Das kann in einigen Fällen zu unbeabsichtigten Ergebnissen oder sogar Fehlern führen. Wieso benutzt du nicht einfach TParser? Da brauchst du dir um all das keine Gedanken zu machen, und außerdem ist ein andauerndes Aufrufen von StringReplace auch nicht gerade performant.

[himitsu]

Zitat:

Wieso benutzt du nicht einfach TParser?

Weil er nichts fertiges nutzen will, denn sonst würde er direkt TReader verwenden, welches das Format sogar direkt versteht.

[Dennis07]

Zitat von himitsu:

sonst würde er direkt TReader verwenden, welches das Format sogar direkt versteht.

Das tut TParser doch auch??

Und falls er es nicht verwenden will (wieso auch immer), kann er es sich doch innerhalb von ner halben Stunde einfach nachbauen...?

[Dennis07]

Übrigens hat er nirgendwo geschrieben, dass er nichts fertiges benutzen will (korrigiere mich bitte, falls ich falsch liege, habe aber nichts gefunden, das darauf hindeutet. Und selbst wenn, TParser ist nichts "fertiges", es ist nur ein Baustein, genau wie TStringList. Dennoch kann es dir einiges an Arbeit hier abnehmen. Habe das ganze mal (außer die Menüstruktur, da ich noch nicht genau verstanden habe, wie das mit dem "auslesen" gemeint ist) hingeschrieben. So in etwa ließe sich das mit TParser lösen:

Delphi-Quellcode:

program DfmAnalyzer;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.SysUtils, System.Classes, System.Generics.Collections, Vcl.Controls;

var
  FileName: String;
  Stream: TFileStream;
  Parser: TParser;
  Current: String;

  FormName: String;
  Actions: TDictionary<TComponentName, TCaption>;

procedure ParseObject(const Depth: Byte = 0; const Item: Boolean = False);

  procedure ParseCollection;
  begin
    Parser.NextToken;
    while Parser.Token <> '>' do
    begin
      if Parser.TokenSymbolIs('item') then
      begin
        ParseObject(Succ(Depth), True);
      end;
      Parser.NextToken;
    end;
    Parser.NextToken;
  end;

var
  ComponentName: String;
  ComponentType: String;
begin
  Parser.NextToken;
  if not Item then
  begin
    ComponentName := Parser.TokenString;
    if Depth = 0 then
    begin
      FormName := ComponentName;
    end;
    Parser.NextToken;
    Parser.NextToken;
    ComponentType := Parser.TokenString;
    Parser.NextToken;
  end;
  while not Parser.TokenSymbolIs('end') do
  begin
    if Parser.TokenSymbolIs('object') then
    begin
      ParseObject(Succ(Depth));
    end else
    begin
      if Parser.Token = '<' then
      begin
        ParseCollection;
      end else
      begin
        if not Item and (ComponentType = 'TAction') and
          (Parser.TokenSymbolIs('Caption')) then
        begin
          Parser.NextToken;
          Parser.NextToken;
          Actions.Add(ComponentName, Parser.TokenWideString);
        end;
      end;
    end;
    Parser.NextToken;
  end;
end;

begin
  try
    ReadLn(FileName);
    Stream := TFileStream.Create(FileName, fmOpenRead);
    Stream.Seek(0, soBeginning);
    Parser := TParser.Create(Stream, TFormatSettings.Invariant);
    Actions := TDictionary<TComponentName, TCaption>.Create;
    try
      ParseObject;
      WriteLn('Formularname: ', FormName);
      for Current in Actions.Keys do
      begin
        WriteLn('Caption von ', Current, ': ', QuotedStr(Actions[Current]));
      end;
    finally
      Actions.Free;
      Parser.Free;
      Stream.Free;
      ReadLn;
    end;
  except
    on E: Exception do
      WriteLn(E.ClassName, ': ', E.Message);
  end;

end.

Das nur mal, um evtl. einen Denkanstoß zu geben.