Interfaces, Factory- und Singletonpattern

[Der schöne Günther]

Oh Gott, entweder ist es für mich noch zu früh am Morgen, oder das ist schon nicht mehr leicht verständlich.

Ich habe kein Delphi mit Quelltext vor mir, aber nicht dass du den falschen Konstruktor per Rtti erwischt? Hat TInterfacedPersistent wirklich einen parameterlosen Konstruktur (wegen der Owner-Geschichte würde ich tippen dass er einen Konstuktor mit einem optionalen Parameter hat, aber keinen ohne).


PS: In deinem TVDialogBase hätte ich für deine Hook-Methode AfterCall eigentlich erwartet dass "CallResult" ein var-Parameter ist, oder?

PPS: Was ist der Rückgabetyp von deiner letzten Methode?

PPPS: Hast du ein Minimalbeispiel zum selbst ausführen?

[Ghostwalker]

Jap...hat einen Parameterlosen auch lt. Doku.

Callresult ist der Rückgabewert der Execute-Methode und letztlich der Rückgabewert von z.B. TColorDialog.Execute;

Er zeigt lediglich an ob der User mit OK oder Abbruch reagiert hat.

Der Rückgabewert von CreateInstanze ist TInterfacedPersistent, also eine Instanz selbiger Klasse.

Class function DialogManager.CreateInstance(AClass:TClass):TInterfacedPersistent; hat ich wohl beim C&P nicht mit kopiert.

Ich werd mal ein Minimalbeispiel zurechtzimmern

[Ghostwalker]

So...Minimal Beispiel anbei.

Edit: Hatte das falsche Beispiel drann.

[Mavarik]

Willst Du jedes mal über die RTTI den Constructor suchen?

[Ghostwalker]

Ja, da eine abgeleitet Dialogklasse auch einen eigenen Constructor haben kann.

Das Problem scheint in der Tat das finden des Richtigen Constructors zu sein.

[Ghostwalker]

Arrrggg.

Er hat tatsächlich den falschen Constructor erwischt.

Lösung:

- Basisklasse erhält einen (virtuellen) Constructor
- statt rt.GetDeclaredMethods muss es dann rt.GetMethods heißen, damit auch der "Parent"-Konstruktor gefunden wird


Danke euch für die Mühen

[Schokohase]

Zitat von Ghostwalker:

Er hat tatsächlich den falschen Constructor erwischt.

Nein, er hatte gar keinen erwischt

Änderungen:

Delphi-Quellcode:

Class function DialogManager.CreateInstance(AClass:TClass):TInterfacedPersistent;
var
  ctx : TRttiContext;
  rt  : TRttiInstanceType;
  rm  : TRttiMethod;

begin
  if not AClass.InheritsFrom(TInterfacedPersistent) then
    raise EArgumentException.Create('AClass muss von TInterfacedPersistend abgeleitet sein');

  ctx := TRttiContext.create;
  try
    rt := ctx.GetType(AClass.ClassInfo).AsInstance;
    while Assigned(rt) do
    begin
      for rm in rt.GetMethods do
      begin
        if (rm.IsConstructor) and (Length(rm.GetParameters)=0) then
        begin
          result := rm.Invoke(AClass,[]).AsObject as TInterfacedPersistent;
          Exit;
        end;
      end;
      rt := rt.BaseType;
    end;
    raise Exception.Create('Fehlermeldung');
  finally
    ctx.Free;
  end;
end;

und es läuft.

Verstehen muss man diesen Part, wie?

Delphi-Quellcode:

Class function DialogManager.CallDialog(AName: string; var value: TValue):boolean;
var
  intf : IVTDialogCall;
  dm : TDialogItem;
begin
  ...

  // Wenn es keine Instanz gibt, dann eine erzeugen und eintragen

  if (dm.Ainst = NIL) then
  begin
    dm.AInst := CreateInstance(dm.AClass);
    fdialogs.AddOrSetValue(Aname,dm);
  end;

  // Wenn es eine gibt, dann eine erzeugen und eintragen (wozu?)

  if (dm.AInst <> NIL) then
  begin
    dm.AInst := CreateInstance(dm.AClass);
    fdialogs.AddOrSetValue(Aname,dm);
  end;
  ...
end;

Wenn es keine Instanz gibt, dann eine erzeugen und eintragen, ok.
Wenn es eine gibt, dann eine erzeugen und eintragen
(wenn es keine Instanz gibt, dann wird der zweite Part auch immer durchlaufen, also eine Instanz wird entweder doppelt oder immer wieder neu erzeugt)

[Ghostwalker]

Wenn ich das so mache, erwischt er TObject....nicht gut.

Die zweite Abfrage war ein Fehler und blödsinn

[Schokohase]

Du suchst doch nach dem nächsten Konstruktor ohne Parameter, oder?

Wenn deine Klasse aber keine Konstruktor deklariert, dann wirst du in rt.GetDeclaredMethods keine Konstruktoren finden.

Wegen mir müsste man sich also durch die Vererbung wühlen und das sähe dann so aus:

Delphi-Quellcode:

function CreateInstance(AClass: TClass): TObject;
var
  ctx: TRttiContext;
  rt : TRttiInstanceType;
  rm : TRttiMethod;
begin
  ctx := TRttiContext.create;
  try
    rt := ctx.GetType(AClass.ClassInfo).AsInstance;

    while Assigned(rt) do
      begin
        for rm in rt.GetDeclaredMethods do
          begin
            if (rm.IsConstructor) and (Length(rm.GetParameters)=0)
            then
              begin
                result := rm.Invoke(AClass, [ ]).AsObject;
                Exit;
              end;
          end;

        rt := rt.BaseType;
      end;

    raise Exception.create('Fehlermeldung');

  finally
    ctx.Free;
  end;
end;

Und statt

Delphi-Quellcode:

  Supports(dm.Ainst,IVTDialogCall,intf);
  if (intf <> NIL) then
    result := intf.Call(value);

könntest du auch

Delphi-Quellcode:

  if Supports(dm.Ainst,IVTDialogCall,intf) then
    result := intf.Call(value);

schreiben (ist nur eine Kleinigkeit)