Problem mit CreateParams und WS_EX_APPWINDOW

[iphi]

Hallo,

ich benutze CreateParams um ein zweites Fenster meiner Anwendung in der Taskbar sichtbar zu machen:

Delphi-Quellcode:

type
  TForm2 = class(TForm)
  private
    { Private declarations }
  public
    { Public declarations }
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  end;
...
procedure TForm2.CreateParams(var Params: TCreateParams);
begin
  inherited CreateParams(Params);
  Params.ExStyle := Params.ExStyle or WS_EX_APPWINDOW;
  Params.WndParent := 0;
end;

Das funktioniert auch soweit.

Nun gibt es aber einen merkwürdigen Nebeneffekt. Das Nebenfenster öffne ich aus dem Hauptfenster per Click auf ein Label, welches auch einen Hint enthält:

Delphi-Quellcode:

procedure TForm1.Label1Click(Sender: TObject);
begin
Form2.Visible:=true;
Form2.BringToFront;
end;

Click auf das Label bringt auch die Form2 wie gewünscht in den Vordergrund. Wenn man aber die Maus nicht schnell genug von dem Label entfernt, dann springt Form1 sobald der Hint angezeigt wird wieder in den Vordergrund, der Fokus bleibt aber auf Form2. Das sieht man nur, wenn die Forms überlappen. Achtung, das passiert aber erst beim zweiten Versuch, wenn man Form2 nach dem ersten Öffnen nicht wieder schließt. Ohne den CreateParams-Code passiert das überhaupt nicht. Kann man das irgendwie abstellen?

Democode ist angehängt.

[Delphi.Narium]

Dient BringToFront denn dazu, andere Formulare in den Vordergrund zu bringen?

http://docwiki.embarcadero.com/Libra...l.BringToFront

Hätte das eher so gelöst:

Delphi-Quellcode:

procedure TForm1.Label1Click(Sender: TObject);
begin
  Form2.Show;
end;

[iphi]

Delphi-Quellcode:

procedure TCustomForm.Show;
begin
  Visible := True;
  BringToFront;
end;

Das hat aber mit meinem Problem nichts zu tun.

[samso]

Ich habe versucht den Fehler zu reproduzieren. Das ist mir nicht gelungen.

Dabei habe ich folgenden Ablauf eingehalten:
- Projekt starten
- "Click me" gedrückt
- Form1 in den Vordergrund gebracht
- "Click me" gedrückt -> From2 kommt nach vorne
- gewartet bis der Hint erscheint
Es passiert nichts!

Das habe ich sowohl mit Delphi 2007 als auch mit Delphi 6 getestet (mit Windows XP und Windows 10). Anbei die Exe die ich mit Delphi 6 erzeugt habe. (Delphi 7 habe ich nicht installiert)

[Namenloser]

Kann es sein, dass deine Maus prellt? Versuch es mal mit einer anderen Maus.

[iphi]

Das Problem ist der aufpoppende Hint, der, warum auch immer, das Hauptfenster wieder in den Vordergrund holt, ohne dem Hauptfenster den Fokus zu geben.

Ein nicht sehr eleganter Work-around könnte so aussehen:

Delphi-Quellcode:

procedure TForm1.Label1Click(Sender: TObject);
begin
SetCursorPos(Left+Label1.Left-1,Top+Label1.Top+Height-Clientheight);
Form2.Visible:=true;
Form2.BringToFront;
end;

Die Maus wird soweit verschoben, dass kein Hint mehr kommt. Wenn der Nutzer aber die Maus zurück bewegt, passiert es wieder.

Eleganter wäre es, den Hint auszuschalten, wenn Form1 den Fokus verliert, und wieder einzuschalten, wenn es den Fokus wieder erlangt. Mein Problem ist, dass ich auf meinem Form1 sehr viele Objekte mit aktivierten Hints habe, und auch viele ohne.

Gibt es eine effiziente Methode, alle Hints einer Form global zu deaktivieren bzw. zu reaktivieren?

[iphi]

Zitat:

Kann es sein, dass deine Maus prellt? Versuch es mal mit einer anderen Maus.

Nein, das hat damit nichts zu tun. Es passiert ja auch, wenn ich den Mauszeiger einfach über das Label bewege.

[samso]

Ich sehe gerade, bei meinem Delphi 2007 habe ich 2014 die Controls.pas modifiziert. (Irgendwie kam mir die Fehlerbeschreibung bekannt vor). Allerdings ist meine Fehlerbeschreibung etwas anders. Bei mir scheint der Fehler nur aufgetreten zu sein, wenn ich in Form2 einen Hint angezeigen lies.

Delphi-Quellcode:

procedure THintWindow.ActivateHint(Rect: TRect; const AHint: string);
type
  TAnimationStyle = (atSlideNeg, atSlidePos, atBlend);
const
  AnimationStyle: array[TAnimationStyle] of Integer = (AW_VER_NEGATIVE,
    AW_VER_POSITIVE, AW_BLEND);
var
  Animate: BOOL;
  Style: TAnimationStyle;
  Monitor: TMonitor;
begin
  FActivating := True;
  try
    Caption := AHint;
    Inc(Rect.Bottom, 4);
    UpdateBoundsRect(Rect);
    Monitor := Screen.MonitorFromPoint(Point(Rect.Left, Rect.Top));
    if Width > Monitor.Width then
      Width := Monitor.Width;
    if Height > Monitor.Height then
      Height := Monitor.Height;
    if Rect.Top + Height > Monitor.Top + Monitor.Height then
      Rect.Top := (Monitor.Top + Monitor.Height) - Height;
    if Rect.Left + Width > Monitor.Left + Monitor.Width then
      Rect.Left := (Monitor.Left + Monitor.Width) - Width;
    if Rect.Left < Monitor.Left then Rect.Left := Monitor.Left;
    if Rect.Bottom < Monitor.Top then Rect.Bottom := Monitor.Top;

    SetWindowPos(Handle, HWND_TOPMOST, Rect.Left, Rect.Top, Width, Height,
      SWP_NOACTIVATE or SWP_NOOWNERZORDER); //15.3.2014 SWP_NOOWNERZORDER hinzugefügt **
    if (GetTickCount - FLastActive > 250) and (Length(AHint) < 100) and
       Assigned(AnimateWindowProc) then
    begin
      SystemParametersInfo(SPI_GETTOOLTIPANIMATION, 0, @Animate, 0);
      if Animate then
      begin
        SystemParametersInfo(SPI_GETTOOLTIPFADE, 0, @Animate, 0);
        if Animate then
          Style := atBlend
        else
          if Mouse.GetCursorPos.Y > Rect.Top then
            Style := atSlideNeg
          else
            Style := atSlidePos;
        AnimateWindowProc(Handle, 100, AnimationStyle[Style] or AW_SLIDE);
      end;
    end;
    ParentWindow := Application.Handle;
    ShowWindow(Handle, SW_SHOWNOACTIVATE);
    Invalidate;
  finally
    FLastActive := GetTickCount;
    FActivating := False;
  end;
  // ** Bugfix für Fenster mit ExStyle = WS_EX_APPWINDOW. Dort wurde das Hauptfenster
  // nach vorne geholt, wenn das untergeordnete Fenster einen Hint anzeigte
end;

[iphi]

Eine gute Lösung könnte also in etwa so aussehen, aber eben programmatisch für alle Elemente mit Hints:

Delphi-Quellcode:

procedure TForm1.FormDeactivate(Sender: TObject);
begin
label1.showhint:=false;
end;

procedure TForm1.FormActivate(Sender: TObject);
begin
label1.ShowHint:=true;
end;

[iphi]

Zitat:

Ich sehe gerade, bei meinem Delphi 2007 habe ich 2014 die Controls.pas modifiziert. ...

Danke für den Tipp, probiere ich nachher mal aus. Muss jetzt kochen