Timer während Laufzeit erstellen..

[SneakyBagels]

Zitat:

Wenn ich es so mache wie du vorgeschlagen hast kommt folgende Fehlermeldung:

Delphi-Quellcode:

unit1.pas(44,18) Error: Wrong number of parameters specified for call to "TimerEvent"
unit1.pas(33,18) Error: Found declaration: TimerEvent(TObject);

kam unter anderem dadurch auf TNotifyEvent:
property OnTimer:= TNotifyEvent

Ist mir unverständlich. Liegt vielleicht an Lazurus?

[himitsu]

Zitat von SneakyBagels:

Ist mir unverständlich. Liegt vielleicht an Lazurus?

Nee, Lazarus hatte ja bei Delphi abgeguckt und nutzt haargenau die selbe Schnittstelle/Signatur.
http://wiki.freepascal.org/TTimer > http://lazarus-ccr.sourceforge.net/d...stomtimer.html

Delphi referenziert/dereferenziert Pointer oftmals automatisch/implizit.
Lazarus FPC wrd hier aber nicht in einem "Delphi"-kompatiblen Modus betrieben, da kann es eventuell sein, daß man sowas manuell/explizit machen muß.
MyTimer.OnTimer := @TimerEvent;
Die Meldung sagt schließlich auch

Zitat:

Wrong number of parameters specified for call to "TimerEvent"

, also will der Compiler diese Methode aufrufen und nicht deren Zeiger verwenden.

Zum Aufrufen fehlt logischer Weise ein Parameter: MyTimer.OnTimer := TimerEvent(irgendwas); , aber so kann nicht das gewünschte Ergebnis bei raus kommen.

Zitat:

Delphi-Quellcode:

Form1.Caption := 'erfolgreich';

MyTimer := TTimer.Create(Form1);

Und wer dir diese Verwendung der Variable "Form1" gezeigt hat, also innerhalb der TForm1-Klasse, der gehört ausgepeitscht.

Delphi-Quellcode:

Caption := 'erfolgreich';  // oder Self.Caption := 'erfolgreich';

MyTimer := TTimer.Create(Self);

[Bryan]

@haentschman das ist mir bewusst ich benutze den Button ja nur um herauszufinden ob es überhaupt funktioniert. Später will ich das per Tastendruck machen. Dann kann ich ja auch mehrere Timer erstellen ,die ich nach einem Intervall wieder lösche.

[Bryan]

Ich habe da was Interessantes gefunden tue mich aber ber der Umsetzung schwer
https://www.delphi-treff.de/object-p...ethodenzeiger/

[SneakyBagels]

Womit genau tust du dich schwer?

[Bryan]

Zitat von SneakyBagels:

Womit genau tust du dich schwer?

Ich habe das jetzt so gemacht wie im Beispiel es wird auch fehlerfrei kompiliert jedoch tut sich immernoch nichts...

Delphi-Quellcode:

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,ExtCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { private declarations }
  TimerEvent : procedure(Sender: TObject) of object;
  public
    { public declarations }
  end;

var
  Form1: TForm1;MyTimer:TTimer;

implementation

{$R *.lfm}

{ TForm1 }

procedure TimerEvent(Sender:TObject);
begin
Form1.caption:='erfolgreich';
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
MyTimer:=TTimer.Create(Form1);
MyTimer.Interval:=100;
MyTimer.OnTimer:=TimerEvent;
MyTimer.Enabled:=True;
end;


end.

[Olli73]

Delphi-Quellcode:

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls, ExtCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { private declarations }
    procedure TimerEvent(Sender: TObject);
  public
    { public declarations }
  end;

var
  Form1: TForm1;
  MyTimer: TTimer;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.TimerEvent(Sender:TObject);
begin
  Caption := 'erfolgreich';
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  MyTimer := TTimer.Create(self);
  MyTimer.Interval := 100;
  MyTimer.OnTimer := @TimerEvent;
  MyTimer.Enabled := True;
end;


end.

[SneakyBagels]

Mach mal wieder alles rückgängig und bleib bei normalen Variablen bis du alle Grundlagen verstanden hast.

Nimm Olli73's Lösung bis du alle Grundlagen verstanden hast.
Das ist nicht böse gemeint, sondern soll einfach nur eine Hilfe sein.

[hoika]

Hallo,
wenn ich nicht weiss, wie die Timer-Methode aussehen muss,
lege ich einen Timer aufs Form, Doppelklick drauf und
voila
Methode + notwendige Parameter sind da.

Timer von Form wieder löschen und Methode habe ich im Kopf.

[himitsu]

Zitat von Bryan:

Ich habe das jetzt so gemacht wie im Beispiel es wird auch fehlerfrei kompiliert jedoch tut sich immernoch nichts...

Delphi-Quellcode:

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,ExtCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { private declarations }
  TimerEvent : procedure(Sender: TObject) of object;
  public
    { public declarations }
  end;

var
  Form1: TForm1;MyTimer:TTimer;

implementation

{$R *.lfm}

{ TForm1 }

procedure TimerEvent(Sender:TObject);
begin
Form1.caption:='erfolgreich';
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
MyTimer:=TTimer.Create(Form1);
MyTimer.Interval:=100;
MyTimer.OnTimer:=TimerEvent;
MyTimer.Enabled:=True;
end;


end.

Ob nun selbstgemacht (TimerEvent : procedure(Sender: TObject) of object; ) oder vordefiniert (TimerEvent : TNotifyEvent; ), es kommt auf das Selbe raus und du hattest das doch schonmal, wo es auch schon nicht ging.

TimerEvent (das Feld/Variable) ist leer (nil) und somit wird auch "nichts" an OnTimer übergeben.