SHChangeNotifyRegister Event

[EWeiss]

Ich möchte das Image des Papierkorb ändern abhängig vom aktuellen Status ob er leer oder voll ist.
Bisher habe ich das innerhalb eines Timers geregelt was aber einiges an CPU-Last benötigt.

Jetzt erstelle ich dafür ein EVENT.

Delphi-Quellcode:

      nEvents := SHCNE_DELETE or SHCNE_RMDIR or SHCNE_UPDATEIMAGE;
      RegID := SHChangeNotifyRegister(MainHandle, SHCNRF_ShellLevel, nEvents, WM_APP, 1, ChangeInfo);

      // Nach dem beenden der Anwendung
      if RegID > 0 then
        SHChangeNotifyDeregister(RegID);

Delphi-Quellcode:

    WM_APP:
      begin
         if gP.recyclebin <> 0 then
         begin
           if SHGetRecycleBinCount > 0 then

Jetzt das eigentliche Problem..
Das Event wird nie abgefeuert egale ob ich den Papierkorb leere oder auffülle.

Was könnte das verursachen?
Es kann ja nicht sein das ich selber noch eine SendMessage schicken muss um den Status zu prüfen
Denn dann wäre da die frage welchen Sinn hat so ein Event.

gruss

[Luckie]

Wäre nicht SHCNE_UPDATEDIR der passende Event?

[EWeiss]

Zitat von Luckie:

Wäre nicht SHCNE_UPDATEDIR der passende Event?

Das ändert aber nichts daran warum das Event nicht gefeuert wird.
Auf der anderen Seite ich möchte ja mein Image aktualisieren nicht irgendeine Directory

Delphi-Quellcode:

const
 WM_SHELL_ITEM_NOTIFY = WM_USER + 666;
//........
NotifyHandle := SHChangeNotifyRegister(MainHandle,
  SHCNRF_ShellLevel, EventMask,
  WM_SHELL_ITEM_NOTIFY, 1, NotifyEntry);

//........    
    WM_SHELL_ITEM_NOTIFY:
      begin
         if gP.recyclebin <> 0 then
         begin
           if SHGetRecycleBinCount > 0 then
           begin
             if not gP.RecycleBinFull then
             begin

Wenn ich jetzt den Papierkorb leere sollte die Message angesprungen werden.
Tut sie aber nicht.

Bei NotifyHandle kommt 1 raus. Ob das so richtig ist?

gruss

[Zacherl]

Funktioniert es für andere Verzeichnisse? Eventuell triggert der Papierkorb das Event nicht, da es sich hierbei ja technisch gesehen nicht wirklich um ein normales Verzeichnis handelt.

[EWeiss]

Zitat von Zacherl:

Funktioniert es für andere Verzeichnisse? Eventuell triggert der Papierkorb das Event nicht, da es sich hierbei ja technisch gesehen nicht wirklich um ein normales Verzeichnis handelt.

Eventuell alle RecycleBin Folder auswerten?
Vielleicht abhängig davon wo gerade etwas gelöscht wird.
Oder muss ich ein spezielles Event dafür deklarieren (NONVCL)

Hmm....
Was habe ich gewonnen wenn ich jetzt ne eigene Message aus dem Timer heraus schicke.
War eigentlich nicht der sinn des ganzen.

gruss

[Luckie]

Zitat von EWeiss:

Bei NotifyHandle kommt 1 raus. Ob das so richtig ist?

Was sagt denn die Doku zu den Rückgabewerten? Und wie sieht deine Fehlerbehandlung aus? Was sagt GetLastError oder so?

[EWeiss]

Zitat von Luckie:

Zitat von EWeiss:

Bei NotifyHandle kommt 1 raus. Ob das so richtig ist?

Was sagt denn die Doku zu den Rückgabewerten? Und wie sieht deine Fehlerbehandlung aus? Was sagt GetLastError oder so?

Hab keine Fehlerbehandlung

gruss

[Luckie]

Dann solltest du mal eine machen. Ansonsten raten wir hier ewig rum.

[EWeiss]

Zitat von Luckie:

Dann solltest du mal eine machen. Ansonsten raten wir hier ewig rum.

Zitat:

Type: ULONG
Returns a positive integer registration ID. Returns 0 if out of memory or in response to invalid parameters.

1 scheint also richtig zu sein da positiv.
GetLastError einzubauen bzw. zu verwenden löst nicht das aktuelle Problem da KEIN Fehler auftritt sondern nur die Events nicht getriggert werden.

Ich habe es erstmal wieder auskommentiert bis ich eine lösung gefunden habe.
Im Moment hab ich noch anderen ärger

Danke!

gruss

[TiGü]

Ganz gute Infoquelle: https://www.codeproject.com/Articles...he-Recycle-Bin

Und hiermit funktioniert es.
Das heißt, dass der MessageHandler für WM_SHELLNOTIFY getriggert wird und der LPARAM sagt was passiert ist.
Musste natürlich noch auf NonVCL stricken...LOL!

Delphi-Quellcode:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Classes,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Winapi.ShlObj;

const
  SHCNF_ACCEPT_INTERRUPTS = $0001;
  SHCNF_ACCEPT_NON_INTERRUPTS = $0002;

  WM_SHELLNOTIFY = WM_USER + 5;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
  public
    procedure WMShellNotify(var Message: TMessage); message WM_SHELLNOTIFY;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  hr: HRESULT;
  hNotifyRBin: ULONG;
  pidlRecycleBin: PItemIDList;
  stPIDL: TSHChangeNotifyEntry;
  MainHandle: HWND;
begin
  MainHandle := Self.Handle;

  hr := SHGetSpecialFolderLocation(MainHandle, CSIDL_BITBUCKET, pidlRecycleBin);

  if Succeeded(hr) then
  begin
    stPIDL.pidl := pidlRecycleBin;
    stPIDL.fRecursive := True;

    hNotifyRBin := SHChangeNotifyRegister(
      MainHandle,
      SHCNF_ACCEPT_INTERRUPTS or SHCNF_ACCEPT_NON_INTERRUPTS,
      SHCNE_ALLEVENTS,
      WM_SHELLNOTIFY, // Message that would be sent by the Shell
      1, stPIDL);

    if 0 = hNotifyRBin then
    begin
      RaiseLastOSError(GetLastError, 'Change Register Failed for RecycleBin');
    end;
  end
  else
    RaiseLastOSError;
end;

procedure TForm1.WMShellNotify(var Message: TMessage);
begin
  case Message.LParam of
    SHCNE_RENAMEITEM, // 0x00000001L
    SHCNE_CREATE, // 0x00000002L
    SHCNE_DELETE, // 0x00000004L
    SHCNE_MKDIR, // 0x00000008L
    SHCNE_RMDIR, // 0x00000010L
    SHCNE_MEDIAINSERTED, // 0x00000020L
    SHCNE_MEDIAREMOVED, // 0x00000040L
    SHCNE_DRIVEREMOVED, // 0x00000080L
    SHCNE_DRIVEADD, // 0x00000100L
    SHCNE_NETSHARE, // 0x00000200L
    SHCNE_NETUNSHARE, // 0x00000400L
    SHCNE_ATTRIBUTES, // 0x00000800L
    SHCNE_UPDATEDIR, // 0x00001000L
    SHCNE_UPDATEITEM, // 0x00002000L
    SHCNE_SERVERDISCONNECT, // 0x00004000L
    SHCNE_UPDATEIMAGE, // 0x00008000L
    SHCNE_DRIVEADDGUI, // 0x00010000L
    SHCNE_RENAMEFOLDER, // 0x00020000L
    SHCNE_FREESPACE: // 0x00040000L
      begin
        ShowMessage(IntToStr(Message.LParam));
      end;
  end;
end;

end.