Ich probiere hier schon seit Stunden mit StringListen rum wie ein Verrückter und komme nur zum Ergebnis Kopfschmerzen!
Jetzt muss ich mich an euch wenden.

Wie ist es möglich, wenn ich zwei TMemIniFile-Instanzen habe, eine komplette Section von der ersten in die zweite Instanz zu kopieren?

Hallo,

mit ReadSection holst du dir Namen der Bezeichner der Sektion,
und dann nimmst du eine kleinen Schleife mit ReadString aus der alten Ini und WriteString in die neue Ini.

Ich bin mir schon gar nicht mehr sicher was ich alles probiert habe aber das hilft glaube ich auch nicht.
Gibt es hier nix einfaches ohne Kopfschmerzen?

Weil ReadSection holt mir nur die Titel jeder Section nicht aber den Inhalt. GetStrings holt mir wirklich alles aber damit kann man auch nix anfangen da ich absolut keine Ahnung habe wie man da durchparst.

Da muss es doch was einfaches, sehr kurzes knackiges geben um eine Section von Ini-1 in Ini-2 zu bringen!

Zum Beispiel so: siehe unten, procedure kopiere( mi1, mi2 : TMemIniFile; sec : string );

[ Ich nehme an, du arbeitest ohne SubSections. Falls doch: Wenn du die Subsections von sec auch kopiert haben willst, dann müsstest du via ReadSubSections (oder ReadSections) an die in diesen SubSections gespeicherten Werte gelangen. ]


In diesem Beispiel werden die drei Wertepaare (b=1, c=2, d=3) aus Section a von m1 nach m2 kopiert.

zusammenfalten · markieren

Delphi-Quellcode:

uses IniFiles;

procedure kopiere( mi1, mi2 : TMemIniFile; sec : string );
var hs : TStringList;
    wert : string;
  i: Integer;
begin
  hs := TStringList.Create;
 try
  mi1.ReadSection( sec, hs );

  for i := 0 to hs.Count-1 do
  begin
    wert := mi1.readstring( sec, hs.Strings[i], '' );
    mi2.WriteString( sec, hs.Strings[i], wert );
  end;

 finally
  hs.free;
 end;
end;

procedure TForm87.FormCreate(Sender: TObject);
var m1, m2 : TMemIniFile;
begin
  m1 := TMemIniFile.Create( extractfilepath( application.exename) + 'tm1.txt' );
  m2 := TMemIniFile.Create( extractfilepath( application.exename) + 'tm2.txt' );
 try
  m1.AutoSave := true;
  m2.AutoSave := true;

  m1.WriteString( 'a', 'b', '1' );
  m1.WriteString( 'a', 'c', '2' );
  m1.WriteString( 'a', 'd', '3' );
  m1.WriteString( 'a\w', 'b', '1' );
  m1.WriteString( 'a\w', 'c', '2' );
  m1.WriteString( 'a\v', 'd', '3' );

  kopiere(m1,m2,'a');

 finally
  m1.Free;
  m2.Free;
 end;
end;

Du hast meinen Tag gerettet! Danke.

Hallo,

Zitat:

Weil ReadSection holt mir nur die Titel jeder Section nicht aber den Inhalt. GetStrings holt mir wirklich alles aber damit kann man auch nix anfangen da ich absolut keine Ahnung habe wie man da durchparst.

Falsch, ReadSections holt die Titel aller Sections, ReadSection (ohne s) holt die Einträge genau einer Section.

public procedure TIniFile.ReadSection(
const Section: string;
Strings: TStrings
);

Oder habe ich da was übersehen?

Zitat von SneakyBagels:

Weil ReadSection holt mir nur die Titel jeder Section nicht aber den Inhalt.

Genauer: ReadSection holt die Name-Werte der angegebenen Section.

Aber für deinen Zweck gibt es ja auch ReadSectionValues.

Die Kopiere Methode könnte dann so aussehen:

zusammenfalten · markieren

Delphi-Quellcode:

procedure kopiere( mi1, mi2 : TMemIniFile; sec : string );
var
  hs : TStringList;
  i: Integer;
begin
  hs := TStringList.Create;
  try
    mi1.ReadSectionValues( sec, hs );
    mi2.EraseSection(sec); // falls der aktuelle Inhalt nicht erhalten bleiben soll

    for i := 0 to hs.Count-1 do
    begin
      mi2.WriteString( sec, hs.Names[i], hs.ValueFormIndex[I] );
    end;

  finally
    hs.free;
  end;
end;

Zitat von hoika:

Oder habe ich da was übersehen?

Nö hast du nicht.

@TE: Ein Blick in die Dokumentation wirkt manchmal doch Wunder. TIniFile.ReadSection und TIniFile.ReadSections

Es ist genau so wie hoika es gesagt hat. Die eine Funktion liest dir alle Sections aus (ReadSections). Die andere Funktion liest dir die Keys innerhalb einer bestimmten Section aus (ReadSection). Die Funktion die du verwenden solltest wäre demzufolge ReadSection. Danach kannst du dir die einzelnen Werte auslesen und entsprechend behandeln.

Eine noch einfachere Variante wäre, dass du einfach die Funktion TIniFile.ReadSectionValues zu Hilfe nimmst. Die macht schon genau das für dich und liest dir alle Keys und Values aus einer Section in eine TStringList ein.

EDIT: Och menno. Zu langsam. Where's the red box

Zitat:

Eine noch einfachere Variante wäre, dass du einfach die Funktion TIniFile.ReadSectionValues zu Hilfe nimmst. Die macht schon genau das für dich und liest dir alle Keys und Values aus einer Section in eine TStringList ein.

ReadSection liest die "Namen"/"Identifiers",
ReadSectionValues liest nur die "Werte"



siehe Post UR

Zitat von Michael II:

Zitat:

Eine noch einfachere Variante wäre, dass du einfach die Funktion TIniFile.ReadSectionValues zu Hilfe nimmst. Die macht schon genau das für dich und liest dir alle Keys und Values aus einer Section in eine TStringList ein.

ReadSection liest die "Namen"/"Identifiers",
ReadSectionValues liest nur die "Werte"



siehe Post UR

Also in der Dokumentation steht was anderes. Es sei denn, die wäre falsch.

Zitat von Embarcadero DokWiki:

Description

Reads the values from all keys within a section of an INI file into a string list.

Call ReadSectionValues to read the keys, and the values from all keys, within a specified section of an INI file into a string list object (TStrings descendant). The key names and values are added to the string list as strings of the form:

markieren

Code:

<keyname> = <value>